อยากได้วิธีคิด 7% ของพื้นเซลล์ที่เป็นสีเหลืองทุกเซลล์ครับ

[yangkodza]

อยากได้วิธีคิด 7% ของพื้นเซลล์ที่เป็นสีเหลืองทุกเซลล์ครับ แล้วเอาผลลัพธ์ทั้งหมดมาบวกกัน
มีสูตรวิธีคิดง่ายๆบ้างไหมครับ

คำนวณ.xlsx

[puriwutpokin]

ใช้คอลัมน์​ช่วยดูครับที่
bg4=IF(A4="",0,LOOKUP(9^9,A4:BF4))*7% ลากลงมาถึง bg62
แล้วที่ bg63=SUM(BG4:BG62)

[snasui]

อีกตัวอย่างครับ

เซลล์ใด ๆ คีย์

=SUMPRODUCT(--(A4:A63>0),--(SUBTOTAL(9,OFFSET(C4,ROW(A4:A63)-ROW(A4),A4:A63))*7%))

[Bo_ry]

อีกแบบ E1
=SUMPRODUCT(($D$3:$BF$62="")*($D$4:$BF$63>0),$D$4:$BF$63)*7%

[yangkodza]

อีกแบบ E1
=SUMPRODUCT(($D$3:$BF$62="")*($D$4:$BF$63>0),$D$4:$BF$63)*7%

อีกตัวอย่างครับ

เซลล์ใด ๆ คีย์

=SUMPRODUCT(--(A4:A63>0),--(SUBTOTAL(9,OFFSET(C4,ROW(A4:A63)-ROW(A4),A4:A63))*7%))

สุดยอดทั้ง 2 สูตรครับ
รบกวนอาจาร์ยอธิบายสูตรที่ครับว่ามีที่มาที่ไปอย่างไร จะได้สามารถนำไปประยุกต์ใช้ได้ครับ

Code: Select all

=SUMPRODUCT(--(A4:A63>0),--(SUBTOTAL(9,OFFSET(C4,ROW(A4:A63)-ROW(A4),A4:A63))*7%))

[Bo_ry]

ย่อเหลือ 4 Rows x 2 Columns D3:E6 และ D4:E7 จะได้อธิบายง่าย
=SUMPRODUCT((D3:E6="")*(D4:E7>0),D4:E7)*7%

True = 1, False =0
=(D3:E6="")*(D4:E7>0)
A =(D3:E6="")*1
{1,1; __D3:D4 =""
0,1; ___E5=""
0,1; ___E6=""
0,0;}

B =(D4:E7>0)*1
{1,0; __D4 = 36 > 0
1,0; ___D5 = 2.88 >0
1,1; ___D6:E6 >0
1,1;} __D7:E7 >0

A*B คูณตำแหน่งเดียวกัน * D4:E7
{1,0; x {36,0;
0,0; x 2.88,0;
0,1; x 5.76,29.76;
0,0} x 2.88,2.3808}

Sumproduct(A*B, D4:E7)*7% = (1*36 + 1* 29.76 + 0+…+0)*7% = 4.60

[snasui]

บกวนอาจาร์ยอธิบายสูตรที่ครับว่ามีที่มาที่ไปอย่างไร จะได้สามารถนำไปประยุกต์ใช้ได้ครับ
CODE: SELECT ALL

=SUMPRODUCT(--(A4:A63>0),--(SUBTOTAL(9,OFFSET(C4,ROW(A4:A63)-ROW(A4),A4:A63))*7%))

เป็นการหาข้อมูลที่สืบเนื่องมาจากความสามารถของ Offset เป็นหลักครับ

ลักษณะการทำงานคือให้หาตำแหน่งที่ห่างจาก C4 ไปในแนวบรรทัด (ห่างลงไปด้านล่าง) ตามค่าของ ROW(A4:A63)-ROW(A4) และห่างจาก C4 ไปในแนวคอลัมน์ (ห่างไปทางขวา) ตามค่าของ A4:A63 จากนั้นนำค่าที่ได้มาคูณด้วย 7% แล้วนำไปเป็นส่วนประกอบที่สองของ Sumproduct

สูตรลักษณะนี้จะหาค่าเป็นสามเหลี่ยมได้โดยไม่ได้รับผลกระทบจากเซลล์แวดล้อม ลองดูตัวอย่างการใช้งานแบบอื่นได้ที่นี่ครับ wordpress/calculating-triangle-data/