เรียงลำดับแต่ไม่ได้ตามต้องการ

[March201711]

ต้องการเรียงข้อมูลจาก น้อยไปมากแต่ใช้สูตรแล้วไม่ได้ตามที่ต้องการค่ะ

เช่น ควรจะเรียงเลขที่น้อยกว่า เป็น 2 -10 แต่ ใช้สูตรแล้ว ขึ้นต้นเป็นเลข 10 ก่อน ปรับสูตรอย่างไรค่ะ

[snasui]

ตัวอย่างสูตรครับ

เซลล์ M224 คีย์

=IFERROR(INDEX($L:$L,MOD(AGGREGATE(15,6,--LEFT($L$224:$L$500,FIND("-",$L$224:$L$500)-1)+(ROW($L$224:$L$500)/1000),ROWS(M$224:M224)),1)*1000),"")

Enter > Copy ลงด้านล่าง

[March201711]

ได้แล้วค่ะ ขอบคุณมากค่ะ

[March201711]

มีปัญหานิดนึงค่ะ ทำไมใช้สูตรให้เรียงลำดับน้อยไปมาก
แต่ใช้สูตรแล้ว =IFERROR(SMALL($P2:$P$898,ROWS(U$2:U2)),"") แล้วแสดงเป็นค่าวาง ต้องปรับแก้อย่างไรคะ

[puriwutpokin]

ไม่พบสูตรที่ใช้ ถ้าใช้อยู่ให้ระบุตำแหน่งที่ใช้นั้นด้วยครับ จะได้ไวต่อการแก้ไขครับ

[March201711]

แนบผิดไฟล์ อยู่ที่ cell U2 ค่ะ

[puriwutpokin]

ที่ U2=IFERROR(INDEX($P$2:$P$898,MATCH(SMALL(IF(ISERR(CODE($P$2:$P$898)),"",CODE($P$2:$P$898)+COUNTIF($P$2:$P$898,"<"&$P$2:$P$898)),ROWS(C$2:C2)),CODE($P$2:$P$898)+COUNTIF($P$2:$P$898,"<"&$P$2:$P$898),0)),"") กด Ctrl+Shift+Enter
ที่ V2:W2=VLOOKUP($U2,$P$1:$R$898,COLUMNS($U2:V2),0)

[March201711]

ได้แล้วค่ะ ขิบคุณมากค่ะ

[norkaz]

อีกซักตัวอย่าง อ้างอิงสูตรที่ อาจารย์ คนควน สร้างไว้ด้านบนในลักษณะเดียวกัน
U2
=IFERROR(INDEX($P$1:$P$898,MOD(AGGREGATE(15,6,CODE($P$2:$P$898)+ROW($P$2:$P$898)/100000,ROW(P1)),1)*100000),"")
Enter -> Copy ลงล่าง

การ +ROW/100000 เพื่อไม่ให้ค่า CODE ที่ได้ซ้ำกัน และตำแหน่ง ROW คือตำแหน่งเดียวกับ CODE ที่ต้องการ เรียง น้อยไปมาก (Aggregate(15,6..

MOD เพื่อตัดเลขให้เหลือแต่ค่า ROW ในรูปทศนิยม

คูณด้วย 100000 เพื่อบังคับค่า แสดงค่า ROW จริงของรายการที่ถูก เรียงน้อยไปมาก จาก Aggregate(15,6... แล้ว INDEX ดึงรายการขึ้นมาแสดง ( INDEX จำเป็นต้องเริ่มที่แถวที่ 1 เนื่องจากได้ค่า ROW มาตรงๆ ไม่ได้ปรับค่า ROW เป็นค่าอื่นๆ ตามช่วง Range ของ Data)

การ + (ROW / เลขมากๆ ) เพื่อป้องกันค่าซ้ำ และการ ใช้ MOD ไปบังคับแล้วคูณกลับด้วยเลขเดียวกันที่นำไปหาร เพื่อได้ค่าตำแหน่งของ ROW ของตัวที่ถูกเรียงน้อยไปมาก ซึ่งเป็นตำแหน่งเดียวกันเป๊ะ และไม่เกิดตำแหน่งซ้ำกันแน่นอน เนื่องจาก ROW ต่างกัน โดยที่ไม่จำเป็นต้อง MATCH เพื่อหาตำแหน่งหลังจาก AGGREGATE อีกรอบ (หรือ SMALL กรณีทำแบบ Array) ทั้งหมดที่อาจารย์คนควนได้แสดงเป็นแนวทางนี้ คลาสสิคมากจริงๆ -- นับถือ / Norkaz


ที่ V2:W2=VLOOKUP($U2,$P$1:$R$898,COLUMNS($U2:V2),0) ไม่มีเพิ่มเติม ยึดตามท่าน puriwutpokin --นับถือ / Norkaz

[March201711]

มีปัญหานิดนึงค่ะ
ต้องการเปรียบเทียบ 2 ข้อมูล แต่ข้อมูลแสดงรายการไม่ครบ เช่น ข้อมูลที่ sheet : Auto ดึงแล้วไม่มีที่ sheet : Main ให้แสดงที่ column L พอจะเรียงลำดับจากน้อยไปมาก ที่ column H แสดงรายการ ID ของคนอื่นหมด แต่กลับไม่แสดงข้อมูลของ ID 884047 ที่ cell L76 ไม่ทราบว่าเกิดจากสาเหตุใดคะ

[puriwutpokin]

ไม่ได้ล็อค ตำแหน่งครับ
M5=IFERROR(SMALL($L$5:$L$500,ROWS(M$5:M5)),"")

[March201711]

ได้แล้วค่ะ ขอบคุณมากค่ะ

[March201711]

ใช้สูตรเรียงตามตัวอักษรจากน้อยไปมาก ทำไมขึ้น blank ค่ะ

[snasui]

สูตรในคอลัมน์ T ไม่ใช่สูตรเรียงตัวอักษรครับ

[March201711]

แล้วต้องปรับอย่างไรคะ

[snasui]

จะปรับแต่งได้อย่างน้อยก็ต้องทราบว่าต้องการคำตอบอย่างไรเสียก่อนครับ

[March201711]

อยากให้เรียง โดยที่ column L จะเป็นการดึงข้อมูลบรรทัดเว้นบรรทัด และไม่ต่อเนื่องกัน เป็นข้อมูลต่อๆกันค่ะ

ให้เรียงตามตัวอักษร A ไปถึง Z ตรงcolumn P high light สีเหลืองค่ะ

[snasui]

ตัวอย่างสูตรครับ

เซลล์ T4 คีย์

=IFERROR(INDEX($L$4:$L$984,MATCH(ROWS($T$4:T4),INDEX(COUNTIF($L$4:$L$984,"<="&$L$4:$L$984)-COUNTIF($L$4:$L$984,""),0),0)),"")

Enter > Copy ลงด้านล่าง

[March201711]

ใช้สูตรที่ column N แล้วทำไมเป็นค่าว่าง ???

[puriwutpokin]

เปลี่ยนที่ N5=IFERROR(LOOKUP(2,1/($H$5:$J$100=$L5)/($I$5:$I$100=$M5),$J$5:$J$1000),"")