การบวกเลขในคอลัมน์เดียวกันโดยมีคอมม่าคั่น

[linzhengli]

เรัียน สมาชิกที่นับถือ
ขอความอนุเคราะห์ผูกสูตร การบวกเลขในคอลัมน์เดียวกันและมีเครื่องหมาย comma คั่น รายละเอียดดังไฟล์แนบ และขอบคุณมา ณ โอกาสนี้

[Bo_ry]

B1
=SUMPRODUCT(--MID(SUBSTITUTE(A1,",",REPT(" ",99)),ROW(A$1:INDEX(A:A,LEN(A1)-LEN(SUBSTITUTE(A1,",",))+1))*99-98,99))

A3 เป็นตัวเลข 4.4ล้านๆ ต้องพิมพ์ ' Single quote หน้าต้วเลข

[linzhengli]

โปรดยกตัวอย่างใน a3ให้บ้างครับ และแนบไฟล์ครับ

[menem]

ให้ลองดูใน
viewtopic.php?f=3&t=15997

หรือ

จาก Cell B2 ที่มีข้อมูลตัวอย่างนะครับ

ให้ไปที่ Ribbon Formula เลือก Name Manager
สั่ง NEW แล้วกำหนดชื่อตามที่เราต้องการ (และไม่ซ้ำกับชื่อในระบบ)
ในที่นี้ผมจะใช้คำว่า EV นะครับ
และในช่อง Refers to ให้พิมพ์ว่า
=EVALUATE("="&SUBSTITUTE(Sheet1!B2,",","+"))
แล้วกด Close

จากนั้นที่ D2 (หรือคอลัมน์อื่น ๆ ที่อยู่ในแถวเดียวกัน)
ให้พิมพ์ =EV (หรือชื่อที่เรากำหนดขึ้น)

[linzhengli]

ขอบคุณครับ

[Bo_ry]

ไม่ต้องแก้ละ
A1
=SUMPRODUCT(--MID(SUBSTITUTE(TEXT(A1,"0,0"),",",REPT(" ",99)),ROW(A$1:INDEX(A:A,LEN(TEXT(A1,"0,0"))-LEN(SUBSTITUTE(TEXT(A1,"0,0"),",",))+1))*99-98,99))

ยกต้วอย่างคือ ใส่ตามนี้

'4,442,657,441,450

[puriwutpokin]

อีกตัวอย่างครับ ที่ B2=SUMPRODUCT(--TEXT(MID(SUBSTITUTE(TEXT(I1,"0,0"),",",REPT(" ",99)),COLUMN(A$1:Z$1)*99-98,99),"0;;;\0"))

[linzhengli]

ที่ B2=SUMPRODUCT(--TEXT(MID(SUBSTITUTE(TEXT(I1,"0,0"),",",REPT(" ",99)),COLUMN(A$1:Z$1)*99-98,99),"0;;;\0")) สำหรับ
excel 2003 ไม่อ่านค่าครับ ขอความอนุเคราะห์ท่านแก้ไขให้บ้างครับ และขอบคุณมา ณ โอกาสนี้

[snasui]

แนบไฟล์ 2003 มาด้วยจะได้ช่วยดูได้ครับ

[linzhengli]

รายละเอียดดังไฟล์ที่แนบครับ

[Bo_ry]

B1
=SUMPRODUCT(--TEXT(MID(SUBSTITUTE(TEXT(A1,"0,0"),",",REPT(" ",80)),ROW($A$1:$A$20)*80-79,80),"0;;;\0"))

[linzhengli]

ขอบคุณท่านมา ณ โอกาสนี้
ขอแสดงความนับถือ
林正利