การใช้ Data Consolidate รสรุปผลแต่ละsheet/วัน โดยรวมยอดไว้ในsheet สุดท้าย

[Thani]

รบกวนช่วยแนะนำด้วยครับ ว่าผมต้องการ เอาแต่ละวันเบิกอะไรไปใช้บ้าง เราเก็บไว้แต่ละวัน วันละsheet พอสิ้นเดือนได้ยอดว่าแต่ละวัน เอาอะไรไปเท่าไร รวมอยู่ในsheet สุดท้าย(สรุปสิ้นเดือน)จะได้รู้ว่าเดือนนี้ใช้ ปลา...ไปเท่าไร? ขอบคุณฯมากครับ

[Supachok]

Sheet summary

=SUM('1 May:3 May'!cell)

[Thani]

ขอบคุณมากครับ

[Thani]

ได้ยอดรวมทั้งเดือนว่า แต่ละรายการเท่าไร แต่ชื่อรายการมันไม่ได้มาด้วยครับ อยากให้มาด้วยเพื่ออ้างอิงกับจำนวน รวมทั้งเดือนครับ
รบกวนด้วยครับ
ขอบคุณมาก

[snasui]

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ I1:J1, L1:N1 คีย์ Description, Sheet, Sheet, CountItem, Start ตามลำดับเพื่อเป็นหัวคอลัมน์
2. ที่ L2:L4 คีย์ '1 May, '2 May, '3 May ซึ่งเป็นชื่อชีต สังเกตว่าคีย์ให้เป็น Text โดยมีเครื่องหมาย ' นำหน้า หรือจะกำหนดคอลัมน์นั้นให้เป็น Text เสียก่อนแล้วค่อยคีย์ข้อความก็ได้เช่นกัน
3. ที่ M2 คีย์
   =COUNTA(INDIRECT("'"&L2&"'!E4:E1000"))
   Enter > Copy ลงด้านล่างถึง M4
4. ที่ N2 คีย์
   =SUM(M$2:M2)-M2+1
   Enter > Copy ลงด้านล่างถึง N4
5. ที่ M5 คีย์
   =SUM(M2:M4)
   Enter
6. ที่ J2 คีย์
   =IF(ROWS(J$2:J2)>$M$5,"",LOOKUP(ROWS(J$2:J2),$N$2:$N$4,$L$2:$L$4))
   Enter > Copy ลงด้านล่างจนเห็นเป็นค่าว่าง
7. ที่ I2 คีย์
   =IF(J2="","",OFFSET(INDIRECT("'"&J2&"'!A3"),COUNTIF(J$2:J2,J2),0))
   Enter > Copy ลงด้านล่างจนเห็นเป็นค่าว่าง
8. ที่ A2 คีย์
   =IFERROR(INDEX($I$2:$I$1000,SMALL(IF(FREQUENCY(IF($I$2:$I$1000<>0,MATCH($I$2:$I$1000,$I$2:$I$1000,0)),ROW($I$2:$I$1000)-ROW($I$2)+1),ROW($I$2:$I$1000)-ROW($I$2)+1),ROWS(A$2:A2))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
9. ที่ B2 คีย์
   =SUMPRODUCT(SUMIF(INDIRECT("'"&$L$2:$L$4&"'!A4:A1000"),A2,INDIRECT("'"&$L$2:$L$4&"'!D4:D1000")))
   Enter > Copy ลงด้านล่าง

!

Note: Ctrl+Shift+Enter เป็นการสร้างสูตร Array โดยสามารถเลือกดำเนินการตามข้อ 1 หรือ 2 ด้านล่าง กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน จากนั้นกดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วตามด้วย Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้ไม่สามารถคีย์เข้าไปเอง จะต้องมาด้วยการกดแป้น Ctrl+Shift+Enter เท่านั้น ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง

[Thani]

ขอบพระคุณอย่างสูงครับ ผมใช้หลักฯของอาจารย์ ได้ผลอย่างมากครับ.