สอบถาม เรื่องสูตร แสดงผลหน่อยครับ

[niprohenry]

ไม่ค่อยมีความรู้ เรื่องการใช้สูตร Excel ถ้าผมต้องการให้แสดงผล ชื่อพนักงาน โดยใส่วันที่ในช่องสีแดง แล้วให้แสดงชื่อ พนักงานและ บริษัทสามารถทำด้วยวิธีใช้สูตร แบบใดได้บ้างครับ (ผมเพิ่งหัด ไม่เก่งเลยครับ)

[snasui]

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ AJ4 คีย์
   =IFERROR(INDEX($B$3:$B$61,SMALL(IF(ISTEXT(INDEX($C$3:$AG$61,0,$AJ$2)),ROW($B$3:$B$61)-ROW($B$3)+1),ROWS(AJ$4:AJ4))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง กรุณาอ่าน Note ด้านล่างอย่างละเอียดไม่เช่นนั้นจะไม่ได้คำตอบครับ
2. ที่ AK4 คีย์
   =IF(AJ4="","",INDEX(INDEX($C$3:$AG$61,0,$AJ$2),SMALL(IF(ISTEXT(INDEX($C$3:$AG$61,0,$AJ$2)),IF($B$3:$B$61=$AJ4,ROW($B$3:$B$61)-ROW($B$3)+1)),COUNTIF(AJ$4:AJ4,AJ4))))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง

!

Note: Ctrl+Shift+Enter เป็นการสร้างสูตร Array โดยสามารถเลือกดำเนินการตามข้อ 1 หรือ 2 ด้านล่าง กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน จากนั้นกดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วตามด้วย Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้ไม่สามารถคีย์เข้าไปเอง จะต้องมาด้วยการกดแป้น Ctrl+Shift+Enter เท่านั้น ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง

[linzhengli]

เรียน ท่านสมาชิกที่นับถือ
ขอความอนุเคราะห์สูตรข้างต้นดังกล่าวสำหรับ Excel 2003 เพื่อประยุกต์ใช้ในงาน และขอบคุณมา ณ โอกาสนี้
ขอแสดงความนับถือ
林正利

[snasui]

เรียน ท่านสมาชิกที่นับถือ
ขอความอนุเคราะห์สูตรข้างต้นดังกล่าวสำหรับ Excel 2003 เพื่อประยุกต์ใช้ในงาน และขอบคุณมา ณ โอกาสนี้
ขอแสดงความนับถือ
林正利

ที่ผ่านมาผมประยุกต์สูตรลักษณะนี้เป็น Version 2003 ให้กับคุณ linzhengli หลายรอบแล้ว ลองปรับมาเอง ติดตรงไหนค่อยถามกันต่อครับ

[niprohenry]

กราบขอบพระคุณมากครับ อาจารย์ที่กรุณา เบื้องต้นทำตาม สูตรได้ผลครับ ขอรบกวนอีกครับ คือผม ส่งพนักงานไป 10 ที่ (ในวงกลมสีแดงคือชื่อบริษัท )ผมอยากหาวิธีที่ คีย์วันที่แล้วแสดงผล ว่าพนักงานคนไหน อยู่ที่ บริษัทไหนครับ พอจะทำด้วยวิธีไหนได้บ้างครับ

[snasui]

ตัวอย่างสูตรตามด้านล่างครับ

1. เติมตัวเลขในคอลัมน์ A ให้ครบทุกช่อง ไม่ควรเว้นว่างไว้ครับ
2. ที่ AH2 คีย์คำว่า Com เพื่อเป็นหัวคอลัมน์
   Enter
3. ที่ AH3 คีย์สูตรเพื่อเป็นคอลัมน์ช่วยในการแสดงชื่อบริษัทให้กับแต่ละบรรทัด
   =IF(N(A3),LOOKUP(2,1/($A$2:A3=""),B$2:B3),"")
   Enter > Copy ลงด้านล่าง
4. ที่ AK4 คีย์
   =IF(AJ4="","",INDEX($AH$3:$AH$61,SMALL(IF(ISTEXT(INDEX($C$3:$AG$61,0,$AJ$2)),IF($B$3:$B$61=$AJ4,ROW($B$3:$B$61)-ROW($B$3)+1)),COUNTIF(AJ$4:AJ4,AJ4))))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง

[niprohenry]

ขอบคุณครับ ขะลองค่อยๆศึกษาดูครับ

[March201711]

สูตร small if เห็นในกระทู้ใช้กันบ่อยมาก จุดประสงค์ใช้เพื่ออะไรคะ เช่น
=IFERROR(INDEX($B$3:$B$61,SMALL(IF(ISTEXT(INDEX($C$3:$AG$61,0,$AJ$2)),ROW($B$3:$B$61)-ROW($B$3)+1),ROWS(AJ$4:AJ4))),"")

[snasui]

Small(If(...)) หมายถึง หาค่าที่น้อยที่สุดตามลำดับที่กำหนดครับ

เช่น
หาค่าที่น้อยที่สุดในลำดับที 1
หาค่าที่น้อยที่สุดในลำดับที่ 2
ฯลฯ

ในร่วมกับ Index เพื่อจะนำค่าในช่วงของ Index ลำดับที่ได้จากสูตร Small มาแสดง ยกตัวอย่างจากสูตรด้านล่าง

=Index(A1:A3,2)

โดย 2 คือผลลัพธ์ที่ได้จากฟังก์ชั่น Small(if(...)) จะหมายถึงจากช่วง A1:A3 ให้แสดงค่าในลำดับที่ 2 ซึ่งหมายถึงค่าในเซลล์ A2 นั่นเอง

สูตรพวกนี้เป็นสูตร Array ทำความเข้าใจยากมาก ค่อย ๆ ศึกษาไปเรื่อย ๆ ครับ

[March201711]

ขอบคุณอาจารย์มากๆค่ะ