รบกวนสอบถามเรื่องการใช้ excel ส่ง email

[Chennai2017]

สวัสดีครับ
ผมต้องการส่ง email จาก Excel file ซึ่งไปหาจาก web ก็สามารถรับส่ง email ได้ ไม่ติดปัญหา แต่ผมมีความต้องการเพิ่มเติมซึ่งหาพยายามแก้ใน VBA แต่ยังไม่สามารถแก้ได้จึงอยากขอความช่วยเหลือดังนี้ครับ

1. ต้องการให้ส่ง email ไปถึงผู้รับโดยอ้างอิง email ผู้รับ จาก cell "J2"
2.ต้องการให้ Subject ของ email อ้างอิงจาก cell "J1"

ผมต้องแก้ข้อมูลใน VBA ตรงไหนครับ

Code: Select all

Sub Mail_Range()
    Dim Source As Range
    Dim Dest As Workbook
    Dim wb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim OutApp As Object
    Dim OutMail As Object

    Set Source = Nothing
    On Error Resume Next
    Set Source = Range("b1:g22").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If Source Is Nothing Then
        MsgBox "The source is not a range or the sheet is protected, please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set wb = ActiveWorkbook
    Set Dest = Workbooks.Add(xlWBATWorksheet)

    Source.Copy
    With Dest.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial Paste:=xlPasteValues
        .Cells(1).PasteSpecial Paste:=xlPasteFormats
        .Cells(1).Select
        Application.CutCopyMode = False
    End With

    TempFilePath = Environ$("temp") & "\"
    TempFileName = wb.Name

    If Val(Application.Version) < 12 Then
        'You use Excel 97-2003
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        'You use Excel 2007-2016
        FileExtStr = ".xlsx": FileFormatNum = 51
    End If

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Dest
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .to = "xxx@xxx.co.th"
            .CC = ""
            .BCC = ""
            .Subject = "Payment Advise"
            .Body = "FYI"
            .Attachments.Add Dest.FullName
            'You can add other files also like this
            '.Attachments.Add ("C:\test.txt")
            .Send   'or use .Display
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

ขอบคุณมากครับ
ชัยสิทธิ์

[snasui]

ตัวอย่างการปรับ Code ครับ

Code: Select all

With OutMail
    .to = Range("j2").Value '"xxx@xxx.co.th"
    .CC = ""
    .BCC = ""
    .Subject = Range("j1").Value '"Payment Advise"
    .Body = "FYI"
    .Attachments.Add Dest.FullName
    'You can add other files also like this
    '.Attachments.Add ("C:\test.txt")
    .Send   'or use .Display
End With