rankข้อมูล จากสามคอลัมล์ ต้องเขียนสูตรอย่างไรครับ

[naritg]

พยายามหาทาง แต่ทำไม่เป็นจริงๆครับ

rank.xls

[Totem]

สูตรครับ

ที่ เซลล์ J3 = COUNTIF($D$4:$F$7,">="&LARGE($D$4:$F$7,COUNTA(D4:F7)))

ที่ เซลล์ I4 = IF(ROWS(I$4:I4)<=$J$3,LARGE(($D$4:$F$7),ROWS(I$4:I4)),"")

Enter > Copy ลงด้านล่าง

[naritg]

ขอบคุณเป็นอย่างสูงครับที่สละเวลาให้คำแนะนำครับ
มีคำถามอีกนิดครับ ถ้าคอลัมล์ไม่ติดกันทำไงครับ

[Totem]

ขอบคุณเป็นอย่างสูงครับที่สละเวลาให้คำแนะนำครับ
มีคำถามอีกนิดครับ ถ้าคอลัมล์ไม่ติดกันทำไงครับ

J3 = COUNTIF($D$4:$F$7,">="&LARGE($D$4:$F$7,COUNTA(D4:F7)))

ส่วน COUNTIF($D$4:$F$7,">="&LARGE($D$4:$F$7, คลุมพื้นทั้งหมดเลยครับ

I4 = IF(ROWS(I$4:I4)<=$J$3,LARGE(($D$4:$F$7),ROWS(I$4:I4)),"")

ใส่ช่วงข้อมูลที่ต้องการบริเวณที่ระบายสีไว้ตามคอลัมน์ที่ต้องการ

[naritg]

ขอบคุณมากอีกครั้งครับ อันนี้ขอไปศึกษาต่ออีกหน่อยครับ

[Totem]

ขอบคุณมากอีกครั้งครับ อันนี้ขอไปศึกษาต่ออีกหน่อยครับ

ได้ตามต้องการหรือเปล่าครับ ถ้ายังไม่ได้ช่วยแนบไฟล์ที่ต้องการมาด้วยครับ เพื่อให้เพื่อนสมาชิกได้ช่วยตอบครับ

[naritg]

rank.xls

ทำไม่ได้จริงๆด้วยครับ

[Totem]

สูตร

ที่เซลล์ M3 = COUNTIF($C$4:$H$7,">="&LARGE($C$4:$H$7,COUNTA($D$4:$D$7,$F$4:$F$7,$H$4:$H$7)))

ที่เซลล์ L4 = IF(ROWS(L$4:L4)<=$M$3,LARGE(($D$4:$D$7,$F$4:$F$7,$H$4:$H$7),ROWS(L$4:L4)),"")

Enter > Copy ลงด้านล่าง

ส่วนที่ เซลล์ K4 : K7 ต้องให้อาจารย์หรือเพื่อนสมาชิกมาช่วยตอบครับ
คือทำได้ถ้าหากข้อมูลคอลัมน์ C , E , F อยู่ในคอลัมน์ C เดียวกัน และข้อมูลคอลัมน์ D , F , H อยู่ในคอลัมน์ D เดียวกัน
ขอโทษทีครับ
ต้องรออาจารย์หรือเพื่อนสมาชิกมาช่วยตอบครับ ในส่วนนี้ครับ

[naritg]

ครับ ขอบคุณมากครับ แค่นี้ก็เป็นประโยชน์อย่างมากสำหรับผมแล้วครับ

[snasui]

อีกตัวอย่างครับ

1. L4 คีย์สูตร
   =LARGE($C$4:$H$7,J4)
   Enter > Copy ลงด้านล่าง
2. K4 คีย์สูตร
   =INDEX($C$4:$H$7,MIN(IF($C$4:$H$7=$L4,ROW($C$4:$C$7)-ROW($C$4)+1)),MATCH(1,MMULT(TRANSPOSE(ROW($C$4:$C$7)^0),--($C$4:$H$7=L4)),0)-1)
   Ctrl+Shift+Enter > Copy ลงด้านล่าง

[naritg]

สมบูรณ์แบบเลยครับ ขอขอบพระคุณทุกท่านเป็นอย่างสูงที่สละเวลา
แต่ละสูตรขอนำไปศึกษาก่อนครับ ที่แน่ๆใช้งานได้ตรงตามความต้องการเลยครับ

[Totem]

เรียนอาจารย์คร้บ

หากข้อมูลในคอลัมน์ A , F , H มีตัวเลขซ้ำกัน เช่น D6 = 120 , G7 = 120 , G5 = 110 , G6 = 110

การเรียงลำดับช่วง K4 : K7 จะได้ข้อมูลที่ไม่ถูกต้อง ให้ได้ ช่อง K4 = s , K5 = j , K6 = r , K7 = q , K8 = o
จะปรับสูตรให้ครอบคลุมในลักษณะนี้อย่างไร อยากทราบเพิ่มเติมมีข้อสงสัยครับ

ขอบคุณครับ

rank ซ้ำ.xls

[naritg]

รอฟังด้วยคนครับ

[snasui]

เรียนอาจารย์คร้บ

หากข้อมูลในคอลัมน์ A , F , H มีตัวเลขซ้ำกัน เช่น D6 = 120 , G7 = 120 , G5 = 110 , G6 = 110

การเรียงลำดับช่วง K4 : K7 จะได้ข้อมูลที่ไม่ถูกต้อง ให้ได้ ช่อง K4 = s , K5 = j , K6 = r , K7 = q , K8 = o
จะปรับสูตรให้ครอบคลุมในลักษณะนี้อย่างไร อยากทราบเพิ่มเติมมีข้อสงสัยครับ

ขอบคุณครับ

rank ซ้ำ.xls

กรณีมีค่าซ้ำสามารถปรับสูตรใหม่เพื่อลดความซับซ้อนลงโดยใช้พื้นที่ช่วยตามด้านล่างครับ

1. เซลล์ A8 คีย์สูตรเพื่อนับว่ามีตัวเลขทั้งหมดที่ตัว
   =COUNT(C4:H7)
   Enter
2. เซลล์ A9 คีย์สูตรเพื่อเรียงตัวอักษรลงด้านล่าง
   =IF(ROWS(A$9:A9)>$A$8,"",OFFSET(C$4,MOD(ROWS(A$9:A9)-1,COUNTA($C$4:$C$7)),2*(INT((ROWS(A$8:A8)-1)/COUNTA($C$4:$C$7)))))
   Enter > Copy ไป B9 แล้ว Copy ลงด้านล่าง
3. เซลล์ L4 คีย์สูตรเพื่อแสดงค่าจากมากไปน้อย
   =LARGE($B$9:$B$20,J4)
   Enter > Copy ลงด้านล่าง
4. เซลล์ K4 คีย์สูตรเพื่อเรียงตัวอักษรที่สัมพันธ์กับ L4
   =INDEX($A$9:$A$20,SMALL(IF($B$9:$B$20=L4,ROW($A$9:$A$20)-ROW($A$9)+1),COUNTIF(L$4:L4,L4)))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง

[Totem]

ขอบคุณครับ

[naritg]

ขอบคุณมากครับ ความรู้จริงๆ