ไม่รู้จะใช้สูตรอะไรแสดงค่าตามเงื่อนไข

[okeetee]

ไม่รู้จะใช้สูตรอะไรครับ งานของแฟนมาให้ช่วยทำครับ
(ตาม file แนบนะครับ)
คอลัมน์ AQ ต้องการค่ามากที่สุดของ แถว K2:AP2 โดยให้แสดงค่า แถว 1 ครับ
คอลัมน์ AR ต้องการค่าลำดับ 2 ของ แถว K2:AP2 โดยให้แสดงค่า แถว 1 ครับ
คอลัมน์ AS ต้องการค่าลำดับ 3 ของ แถว K2:AP2 โดยให้แสดงค่า แถว 1 ครับ
คอลัมน์ AT ต้องการค่ามากที่สุดของ แถว C2:J2 โดยให้แสดงค่า แถว 1 ครับ

ขอบคุณครับ

ตอนแรกพยายามใช้ Hlookup แต่มันไม่ได้ครับ
เลยจนปัญญา

[snasui]

ค่าที่มากที่สุดใช้ Max ครับ เช่น

=Max(K2:AP2)

ส่วนค่าที่มากที่สุดเป็นลำดับที่ใด ๆ สามารถใช้ Large ครับ เช่นต้องการค่ามากที่สุดเป็นลำดับ 2 สามารถเขียนสูตรเป็น

=Large(K2:AP2,2)

สามารถเปลี่ยนเลข 2 เป็นค่าลำดับที่ต้องการ

[okeetee]

แต่ค่าที่ผมต้องการมันเป็นแถวที่ 1 นะครับ

[snasui]

ต้องการแถวใด ๆ ก็เปลี่ยนค่าใน K2:AP2 เป็นช่วงเซลล์นั้นครับ

เช่น Max(K10000:AP10000) เป็นต้น

[okeetee]

ไม่ใช่ครับ (ตาม file แนบนะครับ)
เช่น ช่อง AQ 2 ต้องการค่ามากสุดของ k2:ap2 ซึ่งก็คือ "5" แต่ให้แสดงค่า "12" (คอลัมน์ O1) แทนครับ

[snasui]

ลองตามนี้ครับ

1. ที่ AT2 คีย์
   =INDEX($C$1:$J$1,MATCH(MAX($C2:$J2),IF($C2:$J2="",0,$C2:$J2),0))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
2. ที่ AQ2 คีย์
   =INDEX($K$1:$AP$1,MATCH(LARGE($K2:$AP2,COLUMNS($AQ2:AQ2)),$K2:$AP2,0))
   Enter > Copy ไปด้านขวาและลงด้านล่าง

Note: Ctrl+Shift+Enter หมายถึงกดแป้น Ctrl+Shift ค้างไว้ก่อนแล้วตามด้วย Enter เนื่องจากเป็นสูตร Array หากกดแป้นถูกต้องจะเห็นเครื่องหมายปีกกาครอบสูตรเช่น {=Formula(...)} หากยังไม่เห็นเครื่องหมายปีกกาครอบสูตรแสดงว่ายังกดแป้นให้รับสูตรไม่ถูกต้องครับ

[okeetee]

ได้แล้ว ขอบคุณครับ

ช่วยอธิบายความหมายด้วยก็ดีครับ

=INDEX($K$1:$AP$1,MATCH(LARGE($K2:$AP2,COLUMNS($AQ2:AQ2)),$K2:$AP2,0))
=INDEX($C$1:$J$1,MATCH(MAX($C2:$J2),IF($C2:$J2="",0,$C2:$J2),0))

ขอบพระคุณมากครับ

[snasui]

จากสูตร INDEX($K$1:$AP$1,MATCH(LARGE($K2:$AP2,COLUMNS($AQ2:AQ2)),$K2:$AP2,0)) หมายความว่า จากช่วง $K$1:$AP$1 ให้นำตำแหน่งที่เป็นผลลัพธ์ของสูตร MATCH(LARGE($K2:$AP2,COLUMNS($AQ2:AQ2)),$K2:$AP2,0) มาแสดง

จากสูตร MATCH(LARGE($K2:$AP2,COLUMNS($AQ2:AQ2)),$K2:$AP2,0) หมายถึงให้หาว่า LARGE($K2:$AP2,COLUMNS($AQ2:AQ2)) อยู่ในลำดับที่เท่าไรของ K2:$AP2

จากสูตร LARGE($K2:$AP2,COLUMNS($AQ2:AQ2)) หมายถึง ให้หาค่าที่ใหญ่ในลำดับที่เป็นผลลัพธ์ของ COLUMNS($AQ2:AQ2) จากช่วงข้อมูล $K2:$AP2

จากสูตร INDEX($C$1:$J$1,MATCH(MAX($C2:$J2),IF($C2:$J2="",0,$C2:$J2),0)) หมายถึง จากช่วง $C$1:$J$1 ให้นำตำแหน่งที่เป็นผลลัพธ์ของ MATCH(MAX($C2:$J2),IF($C2:$J2="",0,$C2:$J2),0) มาแสดง

จากสูตร MATCH(MAX($C2:$J2),IF($C2:$J2="",0,$C2:$J2),0) หมายถึง ให้หาว่าผลลัพธ์ของ MAX($C2:$J2) อยู่ในลำดับที่เท่าไรในผลลัพธ์ของ IF($C2:$J2="",0,$C2:$J2)

จากสูตร IF($C2:$J2="",0,$C2:$J2) หมายถึง หาก $C2:$J2 เท่ากับค่าว่าง ("") แล้ว ให้แสดงค่า 0 ถ้าไม่ว่างให้แสดงค่าในช่วง $C2:$J2