ใช้สูตรอะไรในการดึงข้อมูลจาก Sheetหนึ่ง ไปยังSheetอื่น โดยที่มีจำนวนsheet, ตำแหน่งcellไม่แน่นอนได้คะ?

[koong_heq]

สวัสดีค่ะ หลังจากหาความรู้ในเว็บไซต์มานาน วันนี้ขอมาสอบถามค่ะ เป็นตัวอย่างไฟล์ของเอกสาร Shipping ซึ่งต้องมีการระบุจำนวนกล่อง, ขนาด, น้ำหนัก และต้องทำ Tag ติดแต่ละกล่อง

อยากให้ Tag สามารถ run auto ได้ว่าถ้าเป็น package no.1 ให้ลิงค์ข้อมูลขนาด,น้ำหนัก net, น้ำหนัก gross ขึ้นมาให้เลย ถ้าเพิ่ม sheet tag ใหม่ แต่จนปัญญาว่าถ้ามี package sheet มากกว่า 1 sheet (Packing (1), Packing (2), ++) จะ lookup ยังไงให้ครบและทั่วถึงคะ





ขอบคุณทุกท่านนะคะ คิดมาหลายวันแล้วจริงๆค่ะ จนไม่รู้จะไปทางไหนต่อแล้วค่ะ

[norkaz]

...

ท่านเจ้าของคำถาม ช่วยระบุผลลัพธ์ ที่ต้องการให้แสดงผล ในไฟล์ แนบมาด้วยครับ


*** สนับสนุนฟอรั่ม กรุณา คลิกโฆษณาที่หน้าเพจ ***

แมวใหญ่ Bigcat9
RCA พระราม9 กรุงเทพฯ

...

[koong_heq]

แนบไฟล์ผลลัพธ์ (file name Trial 1.1) ที่ต้องการให้เรียบร้อยค่ะ รบกวนด้วยนะคะ

[norkaz]

...

ฐานข้อมูล ควรนำมาไว้ในชีทเดียวกัน

ชีท Packing (1)

A11
=IF(ISTEXT(B11),"",IF(C11="","",MAX($B$11:B11)))
Copy ลงไป


ชีท Tag แต่ละชีท

ฺB2 สูตรเดิมให้ + 0 เข้าไป


B4
=VLOOKUP(B2,'Packing (1)'!A:F,4,0)

B6
=VLOOKUP(B2,'Packing (1)'!A:F,6,0)

B8
=SUMIFS('Packing (1)'!E:E,'Packing (1)'!A:A,B2)




*** สนับสนุนฟอรั่ม กรุณา คลิกโฆษณาที่หน้าเพจ ***

แมวใหญ่ Bigcat9
RCA พระราม9 กรุงเทพฯ

...

[koong_heq]

สวัสดีค่ะ link กันได้แล้วค่ะ ขอบคุณมากๆเลยค่ะ แต่ว่าติดปัญหาตรงที่บางครั้งฐานข้อมูลนำมาไว้ในชีทเดียวกันไม่ได้จริงๆค่ะ เช่นถ้าหน้า (1) เต็ม ก็ต้องขึ้นหน้าใหม่ค่ะ และรัน package no. ต่อจากหน้าเดิม vlookup มีวิธีให้ look up ได้หลายชีทไหมคะ ซึ่งจะมีกี่ชีท (อาจจะมีแค่ 1 ชีท) ก็จะแปรผันตามรายการส่งออกเลยค่ะ

[snasui]

ตัวอย่างสูตรตามด้านล่าง โดยมีพื้นที่สำหรับช่วยคำนวณดังด้านล่่างครับ

ที่ชีต input

1. ที่ I21:I22 คีย์
   Packing (1), Packing (2) ตามลำดับ และหากมีมากกว่านี้ก็ให้คีย์ลงด้านล่างไปเรื่อย ๆ
2. ที่ J21 คีย์
   =COUNTA(INDIRECT("'"&I21&"'!C11:C21"))
   Enter > Copy ลงด้านล่าง
3. ที่ K21 คีย์
   =SUM(J21:J$21)-J21+1
   Enter > Copy ลงด้านล่าง
4. ที่ J28 คีย์
   =SUM(J21:J27)
   Enter
5. ที่ G21 คีย์
   =IF(ROWS(G$20:G20)>$J$28,"",LOOKUP(ROWS(G$21:G21),$K$21:$K$27,$I$21:$I$27))
   Enter > Copy ลงด้านล่าง
6. ที่ B21 คีย์
   =IF($G21="","",INDIRECT("'"&$G21&"'!R"&11+COUNTIFS($G$21:$G21,$G21)-1&"C"&2+COLUMNS($B21:B21)-1,0))
   Enter > Copy ไปด้านขวาถึง F21 แล้ว Copy ลงด้านล่าง
7. ที่ A21 คีย์
   =IF(G21="","",LOOKUP(2,1/(B$21:B21>0),B$21:B21))
   Enter > Copy ลงด้านล่าง

ที่ชีต Tag (1)

1. ที่ B4 คีย์
   =VLOOKUP(--B2,input!$A$21:$G$34,4,0)
   Enter
2. ที่ B6 คีย์
   =SUMIFS(input!$F$21:$F$34,input!$A$21:$A$34,B2)
   Enter
3. ที่ B8 คีย์
   =SUMIFS(input!$E$21:$E$34,input!$A$21:$A$34,B2)
   Enter
4. Copy สูตรข้างต้นไปใช้กับชีต Tag(x) ที่เหลือ

อย่าลืม Update Version ของ Excel ที่ใช้จริงตาม Link นี้ https://snasui.com/viewtopic.php?p=103177#p103177

ดูไฟล์แนบประกอบ