combobox 1 ทำงานช้า

[liveday]

เรียนอาจารย์ทุกท่าน
Sheet(ต้นฉบับ) Combobox 1 Cell (O28) ตอนใส่ข้อมูลจะช้ามาก ผมจะปรับปรุงสูตรหรือแก้ไขยังไงบ้างครับ
การทำงานคือคีย์ใน Combobox แล้วให้รายการเลื่อนลงและเลือกข้อมูลมาใช้ครับ
ที่ Sheet Province Cell G2

Code: Select all

=--ISNUMBER(IFERROR(SEARCH($F$2,B2,1),""))

,Cell H2

Code: Select all

=IF(G2=1,COUNTIF($G$2:G2,1),"")

,Cell I2

Code: Select all

=IFERROR(INDEX($B$2:$B$7538,MATCH(ROWS($H$2:H2),$H$2:$H$7538,0)),"")

และที่ Sheet(ต้นฉบับ) Cell (O28) Combobox1 สูตร VBA ที่ใช้ครับ

Code: Select all

Private Sub ComboBox1_GotFocus()
    ComboBox1.ListFillRange = "DropDownList"
    Me.ComboBox1.DropDown
End Sub

[logic]

แบบนี้น่าจะเร็วขึ้นครับ

G1 กรอกเลข 0
G2 =IF(COUNT(SEARCH($F$2,B2,1)),LOOKUP(9.99999999999999E+307,G$1:G1)+1,"") คัดลอกลง
H1 =LOOKUP(9.99999999999999E+307,G:G)
I2 =IF(ROWS($I$2:I2)>$H$1,"",LOOKUP(ROWS($H$2:H2),$G$2:$G$7538,$B$2:$B$7538)) คัดลอกลง

Name
DropdownList =OFFSET(Province!$I$2,0,0,Province!$H$1)

ถ้าใช้ Excel 365 มีฟังก์ชัน filter ให้ใช้ ลัดขั้นตอนสูตรได้เยอะครับ

[liveday]

ได้ลองแล้วนะครับ ยังช้าอยู่เลยครับ เลยไม่แน่ใจว่าเป็นที่เครื่องหรือเป็นที่สูตรครับ

[Bo_ry]

สูตรช้า ลบออกให้หมด

Code: Select all

Private Sub ComboBox1_Change()
Dim a
    a = Filter(Application.Transpose(Sheets("Province").[B2:B7538]), ComboBox1.Value)
    If UBound(a) > 0 Then
        Sheets("Province").[I2:I7538] = Application.Transpose(a)
        ComboBox1.ListFillRange = "DropDownList"
    Else
        ComboBox1.ListFillRange = ""
    End If
            Me.ComboBox1.DropDown
End Sub

Range name
DropDownList
=Province!$I$2:INDEX(Province!$I$2:$I$7537,MATCH("ๆ",Province!$I$2:$I$7538))

[liveday]

ลองใช้ดูแล้วใช้ได้ครับ ผมลองปรับสูตรใหม่พอดีไปใช้กับ combobox แต่ติด Error ครับ จะแก้ยังไงครับ

Code: Select all

Private Sub ComboBox1_Change()
Dim i As Long
    With Me.ComboBox1
        If Not IsArrow Then .List = Range("customerlist").Value 'ติดบรรทัดนี้ครับ
        If .ListIndex = -1 And Len(.Text) Then
            For i = .ListCount - 1 To 0 Step -1
                If InStr(1, .List(i), .Text, 1) = 0 Then .RemoveItem i
            Next i
            .DropDown
        End If
    End With
End Sub

Private Sub ComboBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    IsArrow = KeyCode = vbKeyUp Or KeyCode = vbKeyDown
    If KeyCode = vbKeyReturn Then Me.ComboBox1.List = Range("customerlist").Value
End Sub

ต้องปรับอย่างไรบ้างครับ

[snasui]

ตัวอย่างการปรับ Code ครับ

Code: Select all

Dim custList As Range
Dim IsArrow As Boolean

Private Sub ComboBox1_Change()
    Dim i As Long
    With Sheets("Customers")
        Set custList = .Range("d3", .Range("d" & .Rows.Count).End(xlUp))
    End With
    If Not IsArrow Then
        With Me.ComboBox1
            .List = custList.Value
            .ListRows = Application.WorksheetFunction.Min(custList.Count, .ListCount)
            .DropDown
            If Len(.Text) Then
                For i = .ListCount - 1 To 0 Step -1
                    If InStr(1, .List(i), .Text, 1) = 0 Then .RemoveItem i
                Next i
                .DropDown
            End If
        End With
    End If
End Sub

Private Sub ComboBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, _
    ByVal Shift As Integer)
    IsArrow = (KeyCode = vbKeyUp) Or (KeyCode = vbKeyDown)
    If KeyCode = vbKeyReturn Then Me.ComboBox1.List = custList.Value
End Sub

[liveday]

ขอบคุณมากครับ ได้ตามต้องการเลยครับ