vba Importfile Text File UTF-8

[OOjaoQQ]

ขออนุญาตสอบถามอาจารย์ครับ ผมใช้โค๊ดนี้ในการอิมพอร์ต utf-8 text file ปรากฎว่าภาษาที่ออกมาเป็นภาษาต่างดาว จะเขียนโค๊ดอย่างไรให้สามารถเป็นภาษาไทยได้ครับ อีก 1 ประการ คือต้องการ import เฉพาะบรรทัดสุดท้าย ครับ ขอบคุณครับ

Code: Select all

Sub test()
Dim myfilepath As String
        myfilepath = "C:\Users\Administrator\Desktop\test.txt"
        Open myfilepath For Input As #1
        Do Until EOF(1)
        counter = counter + 1
        Line Input #1, CurLine
        ThisWorkbook.Sheets("Sheet1").Cells(counter, 1).Value = CurLine
        Loop
        Close #1
End Sub

[snasui]

ลองแนบ TextFile พร้อมไฟล์ Excel ตัวอย่างจะได้ช่วยทดสอบให้ได้ครับ

หากแนบ Text File ไม่ผ่าน ให้ Zip เสียก่อนครับ

[OOjaoQQ]

ไฟล์ตัวอย่างครับอาจารย์

[snasui]

ตัวอย่าง Code ตามด้านล่างครับ

Code: Select all

Public Sub Read_UTF_8_Text_File()
    Dim adoStream As Object
    Dim var_String As Variant
    Set adoStream = CreateObject("ADODB.Stream")
    adoStream.Charset = "UTF-8"
    adoStream.Open
    adoStream.LoadFromFile "C:\Users\Administrator\Desktop\test.txt"
    var_String = Split(adoStream.ReadText, vbCrLf)
    Range("A1").Resize(UBound(var_String) - LBound(var_String) + 1).Value _
        = Application.Transpose(var_String)
End Sub

ลองศึกษาเพิ่มเติมจาก Link นี้ครับ https://www.ozgrid.com/forum/forum/tip- ... e-with-vba

[OOjaoQQ]

ได้ตามที่ต้องการครับ ขอบคุณอาจารย์เป็นอย่างสูงครับ