การกำหนดตัวแปร VBA

[Jirawat namrach]

สอบถามหน่อยครับ ตามไฟล์แนบ Sheet2 จะส่ง Code ไปที่ QTY B2 จากนั้นจะนำ Code ใน B2 ไปเทียบกับ Code ใน Sheet1 แล้วก๊อปปี้มาวาง แต่ติดบาง Code จะมีหลาย Revision ต้องการให้ก๊อปมาให้หมด แล้วค่อยไปค้นหา Code ต่อไป ต้องกำหนดตัวแปรยังไงครับ เพราะตอนนี้ code ที่มีหลาย Revision จะถูกก๊อปมาวางทับกัน ข้อมูลเพิ่มเติมในไฟล์แนบครับ

[snasui]

ตัวอย่าง Code ครับ

Code: Select all

Sub test0()
    Dim arr(999, 2) As Variant
    Dim rsa As Range, rsb As Range
    Dim ra As Range, rb As Range
    Dim j As Integer, k As Integer
    With Worksheets("Sheet2")
        Set rsa = .Range("a1").CurrentRegion
    End With
    With Worksheets("Sheet1")
        Set rsb = .Range("a5").CurrentRegion.Offset(0, 1).Resize(, 1)
    End With
    j = 0
    For Each ra In rsa
        arr(j, 0) = ra.Value
        k = j
        For Each rb In rsb
            If VBA.InStr(rb.Value, ra.Value) Then
                arr(j, 1) = rb.Value
                arr(j, 2) = rb.Next.Value
                j = j + 1
            End If
        Next rb
        If j = k Then
            j = j + 1
        End If
    Next ra
    If j > 0 Then
        Worksheets("QTY").Range("a2").Resize(j, 3).Value = arr
    End If
End Sub

[Jirawat namrach]

หลังจากก๊อปปี้ Code ของอาจารย์ทั้งชุดไป ทดลองใช้กับไฟล์ที่แนบในตอนแรกสามารถใช้ได้ตรงตามต้องการเลยครับ แต่ผมลองใช้กับไฟล์จริง ข้อมูลมาไม่ครบครับ ไม่ทราบว่าต้องแก้ไขตรงไหนเพิ่มเติมครับ Code ของอาจารย์รอบนี้ผมไม่เคยเห็นเลย ไม่ทราบว่าอาจารย์จะพออธิบายหน่อยได้มั้ยครับ

[snasui]

สำหรับ Code นั้นเป็นการสร้างตัวแปร Array มารับค่าที่เข้าเงื่อนไข โดยใช้ค่าใน Sheet2 คอลัมน์ A ไป Loop เพื่อเช็คว่าพบค่านั้นในเซลล์ใดของ Sheet1 โดยหาเฉพาะในคอลัมน์ B หากพบบางส่วนก็จะถือว่าพบ เมื่อพบแล้วจึงนำไปเก็บไว้ในตัวแปร arr แล้วค่อยวางทีเดียวเมื่อ Loop ไปครบทุกค่าแล้ว

ที่ไม่ได้ผลลัพธ์เพราะข้อมูลใน Sheet1 มีการเว้นช่วงทำให้ Code เดิมนำข้อมูลเพียงบางส่วนไปใช้ ให้ปรับ Code บางส่วนเป็นด้านล่างครับ

Code: Select all

'Other code
With Worksheets("Sheet1")
    Set rsb = .Range("b5", .Range("b" & .Rows.Count).End(xlUp))
End With
'Other code

[Jirawat namrach]

ได้แล้วครับ ขอบคุณมากครับ