ดึงค่าข้อมูลแต่ละลำดับ (มีเงื่อนไขเล็กน้อย)

[zixnutz]

ต้องการดึงค่าจาก Sheet Foam
โดยที่เรียงลำดับข้อมูล จำแนกตาม Detail แต่ละ Sheet ข้อมูล

ที่ต้องจะมีสองอย่างครับ
1 ช่อง C3 ของทุก Sheet ให้ดึงค่าจาก Sheet Foam ในช่อง C3-C20
และต้องเป็นค่าลำดับที่ 1,2,.. ของแต่ละ Detail (Sheet Foam ช่อง E3-E20)
เช่น Sheet Pic1 ให้ดึงค่า ลำดับที่ 1 ของ Detail = Pic ใน Sheet Foam
Sheet Pic2 ให้ดึงค่า ลำดับที่ 2 ของ Detail = Pic ใน Sheet Foam
Sheet Nopic1 ให้ดึงค่า ลำดับที่ 1 ของ Detail = Nopic ใน Sheet Foam
Sheet Nopic2 ให้ดึงค่า ลำดับที่ 2 ของ Detail = Nopic ใน Sheet Foam

2 ช่อง C6-C17 ต้องการดึงค่าจาก Sheet Foam ช่อง D3-D20
โดยให้ดึงเฉพาะค่าของข้อมูลช่อง C3 (ข้อ1)

โดยตัวอย่างค่าที่ต้องการ จะกรอกในช่องสีเหลืองทุก Sheet ครับ
ขออภัยด้วยครับ ถ้าอธิบายไม่ค่อยเข้าใจครับ

[snasui]

ในแต่ละชีตที่ต้องการการคำตอบ ช่อง C3 และ F3 ดึงมาได้เพียงค่าเดียวเท่านั้นครับ ยกเว้นจะเขียนด้วย VBA เพื่อกำหนด Validation ส่วน C6 เป็นต้นไปสามารถดึงมาได้เท่ากับจำนวนข้อมูลที่มีครับ

[zixnutz]

ดึงช่อง C3 อย่างเดียวก็ได้ครับ พอมีวิธีไหมครับ

[snasui]

ผมคิดว่าคุณ zixnutz เข้าใจคลาดเคลื่อน

ผมหมายถึงว่าในเซลล์ C3 และ F3 สามารถดึงมาได้เซลล์ละค่า ไม่ทราบว่าที่ต้องการเป็นการดึงมาเพียงค่าเดียวเท่านั้นใช่หรือไม่ ถ้าไม่ใช่กรุณาอธิบายเพิ่มอย่างละเอียดครับ

[zixnutz]

อ๋อ ผมพอเข้าใจแล้วครับ

ผมสื่อสารผิดพลาดเอง จริงๆแล้ว ช่อง F3 ผมกะจะ Vlookup จาก Database หลังจากได้ค่า C3 ที่จำแนกแล้วครับ

ขออภัยอีกครั้งครับ

[snasui]

ตัวอย่างสูตรครับ

ที่ชีต Foam

1. เซลล์ H2:J2 คีย์หัวคอลัมน์ Customer, Detail และ Sheet ตามลำดับ
2. เซลล์ H3 คีย์สูตร
   =IFERROR(INDEX($B$3:$B$20,SMALL(IF(FREQUENCY(MATCH($B$3:$B$20,$B$3:$B$20,0),ROW($B$3:$B$20)-ROW($B$3)+1),ROW($B$3:$B$20)-ROW($B$3)+1),ROWS(H$3:H3))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
3. เซลล์ I3 คีย์สูตร
   =IFERROR(INDEX($E$3:$E$20,SMALL(IF(FREQUENCY(MATCH($B$3:$B$20,$B$3:$B$20,0),ROW($B$3:$B$20)-ROW($B$3)+1),ROW($B$3:$B$20)-ROW($B$3)+1),ROWS(I$3:I3))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
4. เซลล์ J3 คีย์สูตร
   =IF(I3="","",I3&COUNTIF(I$3:I3,I3))
   Enter > Copy ลงด้านล่าง

ชีต Pic1

1. เซลล์ C3 คีย์สูตร
   =IFERROR(INDEX(Foam!$H$3:$H$100,MATCH(MID(CELL("filename",A1),FIND("]",CELL("filename",A1))+1,31),Foam!$J$3:$J$100,0)),"")
   Enter > Copy ไปยังเซลล์เดียวกันของชีตอื่น ๆ

[zixnutz]

ขอรบกวนอีกสักนิดครับ ช่อง C6-C17 ต้องใช้สูตรไหนหรอครับ ผมคิดไม่ออกจริงๆ

ส่วนสูตรด้านบนใช้ได้ตามที่ต้องการเลยครับ

[snasui]

ตัวอย่างสูตรที่ C6 ครับ

=IFERROR(INDEX(Foam!$C$3:$C$20,SMALL(IF(Foam!$B$3:$B$20=$C$3,ROW(Foam!$C$3:$C$20)-ROW(Foam!$C$3)+1),ROWS(C$6:C6))),"")

Ctrl+Shift+Enter > Copy ลงด้านล่าง

[zixnutz]

ขอบพระคุณมากๆครับ ได้แล้วครับ