สูตรในหาข้อมูลตัวเลขที่ซ้ำกันระหว่าง 2 คอลัมภ์แล้วแยกมาไว้อีกคอลัมภ์

[amzaazaa]

ต้องการสูตรในการหาข้อมูลตัวเลขที่ซ้ำกันระหว่าง 2 คอลัมภ์ค่ะ
ตัวอย่างตามไฟล์แนบเลยค่ะ รบกวนด้วยนะคะ ขอบคุณล่วงหน้าค่ะ
พอดีพยายามแนบไฟล์แต่แนบมาไม่ได้ค่ะ
มันขึ้น
ERROR
File too large: ไฟล์คำถาม.jpg
จะพยายามแนบไฟล์มาให้ได้ค่ะ

[DhitiBank]

แนบเป็นไฟล์ตัวอย่าง excel เลยก็ได้ครับ ซึ่งจะสะดวกกับผู้ตอบมากกว่าและมักจะมีขนาดเล็กกว่าไฟล์ภาพเมื่อจับภาพจากบริเวณกว้างครับ ขนาดต้องไม่เกิน 300 kb

[amzaazaa]

แนบไล์มาให้ดูแล้วนะคะ รบกวนด้วยค่ะ
ขอบคุณล่วงหน้าสำหรับทุกๆคำแนะนำค่ะ

[DhitiBank]

อ่านแล้วงงครับ ขอวิธีคิดแบบละเอียดขึ้นได้ไหมครับ เพราะหากดูจากตัวอย่าง เลข 100 ในคอลัมน์ A และ B มีอย่างละตัว ทำไมถึงตัองการแต่ในคอลัมน์ A ดังนั้น อยากขอให้อธิบายวิธีคิดไล่มาเลยได้ไหมครับ เท่าที่ดูรูปแบบ ขอให้อธิบายเลข
--> 60
--> 100
--> 120
--> 300

ลองอธิบายโดยอ้างอิงตำแหน่งที่มีข้อมูลด้วยครับ เช่น อ้างคอลัมน์ หรือแถว หรือเซลล์ เพื่อนๆ จะได้เข้าใจครับ

ผมถามเผื่ออาจารย์และเพื่อนๆ ท่านอื่นที่จะมาช่วยตอบ ตอนนี้ผมช่วยตอบไม่ได้ ขับรถยาวครับ

[amzaazaa]

ขอโทษด้วยค่ะ ไฟล์คำถามทำมาผิด ตอนนี้แนบมาใหม่แล้วค่ะ
แนวคิดคือ A เป็นข้อมูลที่ตั้งเบิกไว้
ส่วน B คือข้อมูลหักล้างค่ะ ตัวอย่าง

ตัวอย่าง
ถ้า A แถว 2 มียอด 60 ต้องจับคู่ กับ B แถวที่ 5
A แถว 3 มียอด 100 ต้องจับคู่ กับ B แถวที่ 8
A แถว 4 มียอด 120 ต้องจับคู่ กับ B แถวที่ 11
A แถว 10,11 มียอด 100 สองยอด แต่ B แถวที่ 19,20,21 มี 100 สามยอด แต่ถ้าจะจับคู่ตัวเลขเพื่อหักล้าง ก็จะต้องจับกับ B แถวที่ 19,20 เท่านั้น เพราะจากข้อมูล A มีแค่ สองยอด ข้อมูล B แถวที่ 21 ก็ปล่อยไว้ไม่ต้องดึงมาจับคู่กับตัวเลขตัวไหนอีก ซึ่งระหว่างแถวที่ตัวเลข A และ B จะมาจับคู่กันได้ มันจะมีเลขอื่นแทรกอยู่ ซึ่งข้อมูลตรงส่วนนั้นไม่ได้ใช้ค่ะ
จึงอยากได้สูตร การจับคู่ตัวเลขที่เหมือนกันระหว่าง A และ B โดยนำจำนวนตัวเลขที่ซ้ำของA เป็นหลักและตัดตัวเลขที่ไม่เกี่ยวข้องออกค่ะ

*ไม่แน่ใจว่า ที่อธิบายมาจะเข้าใจมากขึ้นหรือไม่ แต่ก็ขอบคุณทุกๆ คำตอบนะคะ ตอนนี้ก็พยายามตัดมือเอา ซึ่งตาลายมาก ยังไงก็รบกวนผู้มีความรู้ทุกท่านด้วยนะคะ

[DhitiBank]

ลองแบบนี้ครับ
ที่ D2 คีย์

=IFERROR(SMALL(IF(COUNTIF($A$2:$A$22,$B$2:$B$25),$B$2:$B$25),ROWS(D$2:D2)),"")

แล้วกด Ctrl+Shift ค้างไว้แล้วกด Enter

ที่ E2 คีย์
=d2
enter

แล้วคัดลอกสูตรทั้งสองลงล่างครับ

[DhitiBank]

ตาลายไปหน่อย ขอปรับสูตรครับ

=IFERROR(SMALL(IF(COUNTIF($B$2:$B$25,$A$2:$A$22),$A$2:$A$22),ROWS(D$2:D2)),"")

[amzaazaa]

ขอบคุณมากค่ะ แต่ งง.ตรง แล้วกด Ctrl+Shift ค้างไว้แล้วกด Enter กดแล้วมันไม่เกิดอะไรขึ้น หรือว่าหนูกดไม่ถูก

[DhitiBank]

ถ้าอย่างนั้น ลองปรับสูตรที่ D2 เป็น

=IFERROR(index($a$2:$a$22,SMALL(IF(COUNTIF($B$2:$B$25,$A$2:$A$22),row($A$2:$A$22)-row($a$2)+1),ROWS(D$2:D2))),"")

แล้วกด ctrl+shift ค้างแล้วกด enter ครับ
หากกดรับสูตรถูก จะเห็นเครื่องหมายปีกกา { } คร่อมสูตรอยู่ครับ มันจะขึ้นมาเอง
แต่หากยังไม่ได้คำตอบก็ขออภัยด้วยครับ ตอนนี้ผมไม่มีคอมฯ

[amzaazaa]

ทำได้แล้วค่ะ ขอบคุณมาก ที่นี้ก็เหลือแค่ดึงข้อมูลที่ไม่ซ้ำออกมา ขอบคุณอีกครั้งค่ะ

[DhitiBank]

หากต้องการตัวที่ไม่ซ้ำ ลองคีย์ที่ F2 ว่า

=IFERROR(index($a$2:$a$22,SMALL(IF(COUNTIF($B$2:$B$25,$A$2:$A$22)=0,row($A$2:$A$22)-row($a$2)+1),ROWS(F$2:F2))),"")

กดรับสูตรเหมือนกันครับ

--ยกเลิกครับ สูตรนี้ใช้ไม่ได้--
ลืมคิดไปว่ามีกรณีเกินด้วย เช่น 300 ในคอลัมน์ A มี 2 เซลล์ คอลัมน์ B มี 3 เซลล์ ที่เกินมา 1 เซลล์ในคอลัมน์ B ก็จัดเป็นไม่ซ้ำ ใช่ไหมครับ

[amzaazaa]

ลืมคิดไปว่ามีกรณีเกินด้วย เช่น 300 ในคอลัมน์ A มี 2 เซลล์ คอลัมน์ B มี 3 เซลล์ ที่เกินมา 1 เซลล์ในคอลัมน์ B ก็จัดเป็นไม่ซ้ำ ใช่ไหมครับ

ใช่แล้วค่ะ ถือว่าไม่ซ้ำค่ะ

[DhitiBank]

ลองแบบนี้ครับ

1. เรียกรายการไม่ซ้ำในคอลัมน์ A
ที่ G2 คีย์

=IFERROR(INDEX($A$2:$A$22,SMALL(IF(COUNTIF($B$2:$B$25,$A$2:$A$22)=0,ROW($A$2:$A$22)-ROW($A$2)+1),ROWS(G$2:G2))),"")

Ctrl+Shift+Enter
แล้วคัดลอกลงจนเห็นค่าว่าง


2. สร้างรายการไม่ซ้ำในคอลัมน์ B
2.1 ที่ C2 คีย์

=IF(COUNTIF($A$2:$A$22,B2)=0,1,IF(COUNTIF($A$2:$A$22,B2)<COUNTIF(B$2:B2,B2),1,0))

enter --> คัดลอกลงครับจนถึงเซลล์ C25


2.2 ที่ H2 คีย์

=IFERROR(INDEX($B$2:$B$25,SMALL(IF($C$2:$C$25,ROW($C$2:$C$25)-ROW($C$2)+1),ROWS(H$2:H2))),"")

กด Ctrl+Shift+Enter -> คักลอกลงล่างจนเห็นค่าว่างครับ

[amzaazaa]

อันสุดท้าย ดูจะงงๆ หน่อยนะคะ จะพยายามทำความเข้าใจ แล้วทำตามดูค่ะ
ขอบคุณจริงๆ ไม่ได้คนมีความรู้ของเว็บนี้ช่วยแย่แน่