ปกติสามารถเก็บ macro ใน personal ได้ แต่ถ้าโค้ดที่อยู่ใน sheet นี่ต้องทำอย่างไรให้อยุ่ที่เดียวกันครับ

[10idlnw]

คือผมมีไฟล์อยู่ประมาณ 50 ไฟล์ (และจะสร้างเรื่อยๆ) แต่ละไฟล์มี 6 sheets แต่ละ sheet จะมี code vba
ในนั้นจำนวนหนึ่ง มี 1 module เหมือนกันทุกไฟล์ เพราะ code ในนั้นจะเหมือนกันเป๊ะทุกอย่างครับ
เวลาจะแก้ตอนนี้ผมต้องเปิดแก้ทีละตัว ซึ่งถ้าเฉพาะ module ผมพอเข้าใจได้ว่าสร้างใน personal.xslb ได้เลย
แต่ Code ที่อยู่ในแต่ละ sheet 6 sheets จะทำอย่างไรให้มันอยู่ที่เดียวกันครับ จะได้แก้ทีเดียวจบเลยครับ

[snasui]

ถ้าจะตอบให้ตรงประเด็นก็ต้องอธิบายสิ่งที่ทำว่ามีเหตุจำเป็นใดที่ต้องเก็บ Macro ไว้ในแต่ละชีตครับ

แต่ละชีตทำงานอะไร งานนั้นสามารถเรียกใช้ Macro ที่ Module ได้หรือไม่ ฯลฯ

[10idlnw]

คือไฟล์นี้เป็นไฟล์รับรถเข้าซ่อม แต่ละชีตประกอบด้วย
sheet1 ใบรับรถเข้าซ่อม
sheet2 ใบรถซ่อมเสร็จ
sheet3 ใบเสนอราคา
sheet4 ใบเสร็จรับเงิน
โดย code vba แต่ละชีต จะต้องใช้ Worksheet_Change เพื่อใช้ target.address ผมคิดว่าจึงจำเป็นต้องใส่ code ลงใน sheet มันถึงจะทำงานครับ เช่นโค้ดนี้เป็นต้น ยอมรับครับว่าตอนทำไฟล์รับข้อมูลนี้แต่แรกไม่มีความรู้พอ เลยทำแบบ รถมาซ่อม 1 ครั้ง ก็สร้างให้ไปเลยต่อ 1 ไฟล์ครับ ทุกอย่างในไฟล์นี้เลยเหมือนกันหมดทุกอย่าง ยกเว้นข้อมูลการซ่อมครับ เวลาจะแก้ไขโค้ด เลยต้องแก้ทุกไฟล์ เวลา user ใช้จะได้เหมือนกันหมดน่ะครับอาจารย์ เลยเกิดปัญหาขึ้นตามนี้ครับ

Code: Select all

Private Sub Worksheet_Change(ByVal Target As Range)

On Error Resume Next

Application.EnableEvents = False

If Target.Address = Range("AI_Model").Address Then Range("AI_Model") = UCase(Range("AI_Model"))

If Target.Address = Range("AI_Name").Address Then
        Dim Vlu_tel As String
        Vlu_tel = [Vlookup_Inlist_Tel]
        Range("G5").Value = Vlu_tel
End If

Application.EnableEvents = True

End Sub

[snasui]

ตัวอย่างการใช้ Change Event ส่งค่าไป Module ปกติครับ

ที่ Worksheet

Code: Select all

Private Sub Worksheet_Change(ByVal Target As Range)
    
    On Error Resume Next
    
    Application.EnableEvents = False
    
    Call Abcdef(r:=Target, sh:=Me)
    
    Application.EnableEvents = True

End Sub

ที่ Module ปกติ

Code: Select all

Sub Abcdef(r As Range, sh As Worksheet)
    If r.Address = sh.Range("AI_Model").Address Then sh.Range("AI_Model") = UCase(sh.Range("AI_Model"))

    If r.Address = sh.Range("AI_Name").Address Then
        Dim Vlu_tel As String
        Vlu_tel = [Vlookup_Inlist_Tel]
        sh.Range("G5").Value = Vlu_tel
    End If

End Sub

เมื่อเกิดการเปลี่ยนแปลงที่เซลล์ใด ๆ ก็จะส่งเซลล์นั้น ชีตนั้นไปทำงานที่ Module ปกติตามเงื่อนไขที่กำหนดครับ

[10idlnw]

ขอบคุณมากครับอาจารย์