COPY สูตรแบบเป็นชุดๆ ได้มั้ยครับ

[taweewat]

TVE.JPG

จากรูป;
E3=IF(EXACT(E$2,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74),'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$D$9)
E4=IF(EXACT(E$2,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74),'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$E$9)
E5=IF(EXACT(E$2,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74),'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$F$9)
E6=IF(EXACT(E$2,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74),'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$G$9)
E7=IF(EXACT(E$2,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74),'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$H$9)

ต้องการ copy ลงมา ประณ 70 ชุดครับ;(โดยที่เปลี่ยนเฉพาะเลขท้าย เพิ่มทีละ 1)
E8=IF(EXACT(E$2,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74),'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$D$10)
E9=IF(EXACT(E$2,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74),'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$E$10)
E10=IF(EXACT(E$2,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74),'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$F$10)
E11=IF(EXACT(E$2,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74),'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$G$10)
E712IF(EXACT(E$2,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74),'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$H$10)

ขอบคุณครับ

[snasui]

ลอง Copy ตัวอย่างสูตรมาให้ดูหน่อยครับ ในภาพที่แนบมานั้นสูตรตัวเล็กมากมองไม่ถนัดครับ

[taweewat]

ขออนุญาตอธิบายเพิ่มเติมนะครับ คือว่าสูตรนี้อ้างอิงมาจากอีกไฟล์นึง ประมาณว่าพอพนักงานแต่ละคนของแต่ละแผนกกรอกแบบสอบถามเสร็จ แล้วไฟล์ถูก save มาไว้ที่ folder เดียวกันข้อมูลของแต่ละคนจะถูกนำมาเก็บไว้ column ของใครของมันครับ....ขอบคุณอีกครั้งครับ

จากรูป D3=IF(EXACT($D$2,'F:\Duangdee\A&G Controller, Accounting\[B1.xlsx]StarVoice2010'!$C$49),'F:\Duangdee\A&G Controller, Accounting\[B1.xlsx]StarVoice2010'!$D$9)

[snasui]

การจะให้ Link ในลักษณะนี้ไม่สามารถ Link แบบปกติได้ครับ ต้องใช้การประยุกต์เพื่อให้ Run ค่าคอลัมน์ ออกมาเป็นชุด ๆ และแต่ละชุดเพิ่มบรรทัดแบบเว้นบรรทัด

ลองตามนี้ครับ

1. ที่เซลล์ใด ๆ ในที่นี่สมมุติเป็น D1 คีย์สูตร

="=IF(EXACT($D$2,'F:\Duangdee\A&G Controller, Accounting\[B1.xlsx]StarVoice2010'!$C$49),'F:\Duangdee\A&G Controller, Accounting\[B1.xlsx]StarVoice2010'!$"

Enter

2. ในเซลล์ D3 คีย์สูตร

=$D$1&INDEX({"D","E","F","G","H"},MOD(ROWS($D$3:D3)-1,5)+1)&"$"&INT((ROWS($D$3:D3)-1)/5)*2+9

Enter > Copy ลงด้านล่างเท่าที่ต้องการ

3. Copy สูตรที่ได้ในข้อ 2 แล้ววางแบบ Value โดยคลุมข้อมูลทั้งหมดที่ได้ตามข้อ 2 > คลิกขวา > Copy > คลิกขวา > Paste Special > Value > OK

4. เข้าเมนู Edit > Replace > ช่องบนและช่องล่างคีย์เครื่องหมาย = > Replace All

แนวคิดการทำงานเหมือน Link นี้ครับ http://snasui.blogspot.com/2010/06/blog-post.html

[taweewat]

ขอบคุณมากครับ...เดี๋ยวลองทำดูก่อนนะครับ

[taweewat]

ขออนุญาตอธิบายเพิ่มนะครับ คือสูตรนี้มันอ้างอิงมากอีกไฟล์นึงครับ ประมาณว่า พอพนักงานแต่ละคนของแต่ละแผนกกรอกแบบสอบถามไฟล์ดังกล่าวเสร็จแล้ว ข้อมูลนั้นมันจะวิ่งมาที่นี่เลยครับ....ขอบคุณอีกครั้งครับ

D3=IF(EXACT($D$2,'F:\Duangdee\A&G Controller, Accounting\[B1.xlsx]StarVoice2010'!$C$49),'F:\Duangdee\A&G Controller, Accounting\[B1.xlsx]StarVoice2010'!$D$9)

[taweewat]

ต้องขอโทษสามชิกทุกท่านด้วยนะครับ พอดีดึงกระทู้เก่าของตัวเองมา แล้วเผลอกด"ตั้งกระทู้" เลยตัองมา edit คำถามใหม่ กอรปกับอันเก่า เมื่อปีที่แล้ว ทำไม่สำเร็จ ปีนี้ก็เลยลองแบบใหม่ แต่ก็คล้ายๆแบบเก่าครับ

[snasui]

ลองตามนี้ครับ

จากภาพด้านบน

1. ที่เซลล์ E1 คีย์

="=IF(E$2='F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$C$74,'F:\StarVoice 2011\A & G Executive\[A4.xlsx]questions'!$"

Enter

2. ที่เซลล์ E3 คีย์

=$E$1&INDEX({"D","E","F","G","H"},MOD(ROWS($D$3:D3)-1,5)+1)&"$"&INT((ROWS($D$3:D3)-1)/5)+9&","""")"

Enter > Copy ลงด้านล่าง

3. Copy เซลล์ E3:En (n คือเซลล์สุดท้าย) > วางที่เดิมเป็น Value

4. คลุมข้อ 3 > Ctrl+H > ช่อง Find what: คีย์ = ช่อง Replace with คีย์ = จากนั้นกดปุ่ม Replace All

[taweewat]

ขอบคุณมากครับ เดี๋ยวลองนั่งทำความเข้าใจก่อนครับ แล้วจะรายงานความคืบหน้า

[snasui]

ถ้าจะให้ง่ายขึ้นก็ต้องเปิดไฟล์ทั้งสองขึ้นมาพร้อมกันครับ

จากนั้นที่ไฟล์เป้าหมายตามภาพด้านบน เซลล์ E3 คีย์

=IF(E$2=[A4.xlsx]Questions!$C$74,INDEX([A4.xlsx]Questions!$D$9:$H$1000,INT((ROWS(E$3:E3)-1)/5)+1,MOD(ROWS(E$3:E3)-1,5)+1),"")

Enter > Copy ลงด้านล่าง

[taweewat]

ทดลองทำดูแล้วครับ work มากเลยครับ
ขอถามอีกหน่อยว่า ช่อง F3 พิมพ์ =SUMPRODUCT(B3:E3+0) ค่ามันไม่มาครับ
แล้วที่ G3 ต้องการคำนวณเป็น Percentage มันต้องทำอะไรเพิ่มมั้ยครับ

[snasui]

ต้องเห็นไฟล์ตัวอย่างครับ จะได้ไม่ต้องเดา ทั้งจะได้เห็นว่าค่าปัจจุบันเป็นอะไร ค่าที่ต้องการคืออะไร จะได้คำนวณเปรียบเทียบได้ ส่วนค่าเปอร์เซ็นต์ก็ต้องทราบว่าเป็นเปอร์เซ็นต์วัดจากค่าไหน ฯลฯ

[taweewat]

TVE2.JPG

ขออภัยครับ...ส่งรูปมาให้ครับ

[snasui]

B3:E3 เป็นสูตรใดหรือไม่ครับ ถ้าเป็นสูตร ช่วย Copy สูตรมาด้วยครับ

[taweewat]

หลังจากที่ วางแบบ value แล้ว เป็นตามนี้ครับ(ขออภัยชื่อ file อาจไม่ตรงกัน เพราะต้องทำหลายแผนกครับ แต่ก็ประมาณนี้ครับ)

B3=IF(B$2='F:\StarVoice 2011\A&G Controller - Accounting(B)\[B1.xlsx]questions'!$C$74,'F:\StarVoice 2011\A&G Controller - Accounting(B)\[B1.xlsx]questions'!$D$9,"")
C3=IF(C$2='F:\StarVoice 2011\A&G Controller - Accounting(B)\[B2.xlsx]questions'!$C$74,'F:\StarVoice 2011\A&G Controller - Accounting(B)\[B2.xlsx]questions'!$D$9,"")
D3=IF(D$2='F:\StarVoice 2011\A&G Controller - Accounting(B)\[B3.xlsx]questions'!$C$74,'F:\StarVoice 2011\A&G Controller - Accounting(B)\[B3.xlsx]questions'!$D$9,"")
E3=IF(D$2='F:\StarVoice 2011\A&G Controller - Accounting(B)\[B3.xlsx]questions'!$C$74,'F:\StarVoice 2011\A&G Controller - Accounting(B)\[B3.xlsx]questions'!$D$9,"")

[taweewat]

แก้ไขครับ

E3=IF(E$2='F:\StarVoice 2011\A&G Controller - Accounting(B)\[B4.xlsx]questions'!$C$74,'F:\StarVoice 2011\A&G Controller - Accounting(B)\[B4.xlsx]questions'!$D$9,"")

[snasui]

สูตรที่ได้จากค่า IF นี้หากไม่ตรงตามเงื่อนไขมันจะแสดงอักขระที่แทนค่าว่างถือเป็นตัวหนังสือตัวหนึ่ง ดังนั้น ในสูตร Sumproduct(B3:E3+0) จึงเกิดค่าเผิดพลาดเพราะไม่สามารถเอาตัวหนังสือมาบวกกับเลข 0 แล้วให้ค่าเป็นตัวเลขได้ หากต้องการนำไปคำนวณต่อต้องปรับสูตรใหม่ให้เป็นเช่นด้านล่างครับ

B3=IF(B$2='F:\StarVoice 2011\A&G Controller - Accounting(B)\[B1.xlsx]questions'!$C$74,'F:\StarVoice 2011\A&G Controller - Accounting(B)\[B1.xlsx]questions'!$D$9,0)

หากจะแก้ด้วยวิธีตามด้านล่างนี้

ลองตามนี้ครับ
...
2. ที่เซลล์ E3 คีย์

=$E$1&INDEX({"D","E","F","G","H"},MOD(ROWS($D$3:D3)-1,5)+1)&"$"&INT((ROWS($D$3:D3)-1)/5)+9&","""")"

Enter > Copy ลงด้านล่าง
...

ให้เปลี่ยนสูตรเป็น

=$E$1&INDEX({"D","E","F","G","H"},MOD(ROWS($D$3:D3)-1,5)+1)&"$"&INT((ROWS($D$3:D3)-1)/5)+9&",0)"

[taweewat]

สุดยอดมากเลยครับ
ขอบคุณมากๆเลยครับ