สอบถามเกี่ยวข้องกับ Drop Down List Address ครับ

[lifelove]

เรียนทุกท่าน

ผมต้องการสร้างตารางข้อมูลที่อยู่ ตำบล อำเภอ จังหวัด โดยทำเป็น Drop Down List ครับ

ปัญหาคือ ผมต้องการให้ผู้ที่กรอกข้อมูลเลือก drop down list จังหวัด (column L2) หลังจากนั้นพอมาเลือกว่าอยู่ในอำเภอใดโดยให้ drop down list แสดงเฉพาะอำเภอที่อยู่ในจังหวัดที่เลือก (column L3) Coloumn L4 ก้อเช่นกันครับ

[snasui]

สามารถทำตามด้านล่างครับ

1. ที่ N3 แสดง Distric คีย์สูตร
   =IFERROR(INDEX(Distric,SMALL(IF(LEFT($C$2:$C$929,2)=LOOKUP(2,1/(province=$L$2),$A$2:$A$78),ROW(Distric)-MIN(ROW(Distric))+1),ROWS(N$3:N3))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่างจนเห็นว่าเพียงพอที่จะครอบคลุมข้อมูลที่จะมีได้
2. ที่ O3 แสดง SubDistric คีย์สูตร
   =IFERROR(INDEX($F$2:$F$7456,SMALL(IF(LEFT($E$2:$E$7456,4)=LOOKUP(2,1/(Distric=$L$3),$C$2:$C$929),ROW($E$2:$E$7456)-ROW($E$2)+1),ROWS(O$3:O3))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่างจนเห็นว่าเพียงพอที่จะครอบคลุมข้อมูลที่จะมีได้
3. คลิก L3 เข้าเมนู Data > Data Validation > เลือกแถบ Setting ตรง Allow: เลือก List > ตรง Source: คีย์สูตร
   =OFFSET($N$3,0,0,COUNTIF($N$3:$N$1000,"*?"))
   แล้วคลิก OK
4. คลิก L4 เข้าเมนู Data > Data Validation > เลือกแถบ Setting ตรง Allow: เลือก List > ตรง Source: คีย์สูตร
   =OFFSET($O$3,0,0,COUNTIF($O$3:$O$1000,"*?"))
   แล้วคลิก OK

!

Note: Ctrl+Shift+Enter หมายถึง กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl+Shift ค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน จากนั้นกดแป้น Ctrl+Shift ค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้คีย์เข้าไปเองไม่ได้ ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง