การบันทึกข้อมูลจาก UserForm อัตโนมัติ

[san02551]

เรียนท่าน อาจารย์ที่เคารพ ผมติดปัญที่ กรอกข้อมูล ที่ UserForm3 แล้ว ข้อมูลจะบันทึกที่ Data 3 ทุกแถว เลย จุดประสงค์ที่ผมทำ Form ขึ้นมา คือ1 . ถ้ากรอกข้อมูล 3 รายการ ก็ บันทึก 3 แถว
2. แต่ เลขที่จัดซื้อ จะต้องนำมาบันทึกคู่กันรายการไปทุกๆ แถว

[snasui]

ตัวอย่างการปรับ Code ตามด้านล่างครับ

Code: Select all

Private Sub CommandButton1_Click()
    Dim r As Long
    Dim i As Integer
    Dim iCount As Integer
    For i = 1 To 14
        r = Range("a" & Rows.Count).End(xlUp).Row + 1
        If Controls("Textbox" & iCount + 2) <> "" Or _
            Controls("TextBox" & iCount + 3) <> "" Or _
            Controls("TextBox" & iCount + 4) <> "" Or _
            Controls("TextBox" & iCount + 5) <> "" Then
            Range("a" & r) = TextBox1.Text
            Range("b" & r) = Controls("TextBox" & iCount + 2).Text
            Range("c" & r) = Controls("TextBox" & iCount + 3).Text
            Range("d" & r) = Controls("TextBox" & iCount + 4).Text
            Range("e" & r) = Controls("TextBox" & iCount + 5).Text
        End If
        iCount = iCount + 4
    Next i
 End Sub

[san02551]

ถ้ากรณ๊ที่ผมต้องการให้ไปบันทึกที่ Sheet อื่นครับ ต้องใส่ Code อย่างไรครับ
Private Sub CommandButton1_Click()
Dim r As Long
With Sheets("data3")
r = .Range("a" & Rows.Count).End(xlUp).Row + 1

[snasui]

ลองปรับมาเองก่อน ติดตรงไหนค่อยถามกันต่อครับ

[san02551]

ติดตามไฟล์แนบครับ ไม่ทราบว่าจะวาง ไว้บรรทัด ไหน ของ Code

[snasui]

ตัวอย่างการปรับ Code ครับ

Code: Select all

...
With Sheets("data3")
    For i = 1 To 14
        r = .Range("a" & Rows.Count).End(xlUp).Row + 1
        If Controls("Textbox" & iCount + 2) <> "" Or _
            Controls("TextBox" & iCount + 3) <> "" Or _
            Controls("TextBox" & iCount + 4) <> "" Or _
            Controls("TextBox" & iCount + 5) <> "" Then
            .Range("a" & r) = TextBox1.Text
            .Range("b" & r) = Controls("TextBox" & iCount + 2).Text
            .Range("c" & r) = Controls("TextBox" & iCount + 3).Text
            .Range("d" & r) = Controls("TextBox" & iCount + 4).Text
            .Range("e" & r) = Controls("TextBox" & iCount + 5).Text
        End If
        iCount = iCount + 4
    Next i
End With
...

[san02551]

Code: Select all

Private Sub CommandButton1_Click()
   Dim r As Long
    Dim i As Integer
    Dim iCount As Integer
        With Sheets("data3")
    For i = 1 To 14
          r = Range("a" & Rows.Count).End(xlUp).Row + 1
        If Controls("Textbox" & iCount + 2) <> "" Or _
            Controls("TextBox" & iCount + 3) <> "" Or _
            Controls("TextBox" & iCount + 4) <> "" Or _
            Controls("TextBox" & iCount + 5) <> "" Then
            Range("a" & r) = TextBox1.Text
            Range("b" & r) = Controls("TextBox" & iCount + 2).Text
            Range("c" & r) = Controls("TextBox" & iCount + 3).Text
            Range("d" & r) = Controls("TextBox" & iCount + 4).Text
            Range("e" & r) = Controls("TextBox" & iCount + 5).Text
        End If
        iCount = iCount + 4
    Next i
    End With
End Sub

ไม่รู้ผมปรับ Code ถูกหรือเปล่าครับ ยังไม่บันทึกไปที่ Data3 เลย ครับ
ยังติดที่ End Sub ครับ

[snasui]

ผิดที่ Range ที่ผมตอบไปจะเป็น .Range ทางที่ดีควรจะ Copy ไปใช้เลย

ต้องศึกษาการใช้ With ให้เข้าใจครับ โดยคร่าว ๆ คือ เมื่อใช้ With แล้วแสดงว่า Code ภายใน With และ End With จะเขียนย่อลง

เช่นเดิมเขียนเป็น

Code: Select all

Sheets("Sheet1").Range("A1").Value = 10
Sheets("Sheet1").Range("B10").Value = 5
Sheets("Sheet1").Range("B3").Value = 2

หากอยู่ในรูปแบบ With จะเขียนเป็น

Code: Select all

With Sheets("Sheet1")
   .Range("A1").Value = 10
   .Range("B10").Value = 5
   .Range("B3").Value = 2
End With