อยากทราบวิธีการนับตัวอักษร ที่มีมากที่สุด

[sommor]

อยากทราบวิธีการนับตัวอักษร ที่มีมากที่สุด แล้วก็ให้แสดงเป็นตัวนั้น ครับ


ด ด ผ มผ มผ ใ ห้เป็น ด
ด ด ผ ผ ผผ ให้เป็น ผ
ด ด ผ ดย ดย ให้เป็น ดย
ด ด ผ ด มผ ให้เป็น ด

ลักษณะนี้ครับ

Book3.xlsx

19-12-2556 17-21-33.jpg

[bank9597]

ลองตามนี้ครับ

ที่ K4 คีย์ ด
ที่ L4 คีย์ ผ
ที่ M4 คีย์ ย

ที่ J5 คีย์ =SUM(IF(LEN(D5:H5)=2,1)) กด ctrl+shift+enter คัดลอกลงมา
ที่ K5 คีย์ =SUM(IF($D5:$H5=K$4,1))+$J5 กด ctrl+shift+enter คัดลอกลงมา
ที่ L5 คีย์ =SUM(IF($D5:$H5=L$4,1)) กด ctrl+shift+enter คัดลอกลงมา
ที่ M5 คีย์ =SUM(IF($D5:$H5=M$4,1))+$J5 กด ctrl+shift+enter คัดลอกลงมา

ที่ i5 คีย์ =INDEX($K$4:$M$4,MATCH(MAX($K5:$M5),$K5:$M5,0)) คัดลอกลงมา

[sommor]

ขอบคุณ ครับ ที่ช่วยคิดให้ แต่ยังยากไป ครับที่ต้องการทราบแบบว่า ให้อ้างอิง มาจาก ตัวอักษร เลย ครับ

[apirak2455]

ลองแบบนี้ครับ

I5=IF(SUMPRODUCT(--ISNUMBER(SEARCH("ด",D5:H5)))>SUMPRODUCT(--ISNUMBER(SEARCH("ผ",D5:H5))),"ด","ผ")

enter แล้ว copy ลงล่าง

[sommor]

ขอโทษทีครับ ผมผิด เอง แบบว่า I5 มี ดย ดย ด ผ ผ ต้องให้เป็น ดย ครับ (เพราะว่า ดย ด ผ และ มผ ดย มีค่าความหมาย แยอะกว่า)

ที่ทดลอง นำไปใช้ มี แค่ ด กะ ผ เอง ครับ

[apirak2455]

บอกเงื่อนไขให้ครบทั้งหมดครับ

เช่น มี มผ (หรืออย่างอื่น)เข้ามาด้วย

หรือถ้า ด และ ผ มีเท่ากัน อันใหนสำคัญกว่า

[apirak2455]

ตอบตามที่เข้าใจนะครับ

คือมี มผ ด้วย และ ลำดับความสำคัญดังนี้ ดย ด ผ มผ (ถ้ามีจำนวนเท่ากัน)

ที่ I5 เป็น
=INDEX({"ดย","ด","ผ","มผ"},MATCH(MAX(COUNTIF(D5:H5,{"ดย","ด","ผ","มผ"})),COUNTIF(D5:H5,{"ดย","ด","ผ","มผ"}),0))

[snasui]

แถมอีกสูตร เป็นการอ้างอิงค่าในเซลล์ครับ

เซลล์ I5 คีย์สูตร

=INDEX(D5:H5,MATCH(MAX(COUNTIF(D5:H5,D5:H5)),COUNTIF(D5:H5,D5:H5),0))

Ctrl+Shift+Enter > Copy ลงด้านล่าง

!	Note: Ctrl+Shift+Enter หมายถึงเมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl+Shift ค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้คีย์เข้าไปเองไม่ได้ ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง

[sommor]

ถ้า มี ด ผ เท่ากัน ก็แสดงว่า ด ครับ

ดย ดีเยี่ยม
ด ดี
ผ ผ่าน
มผ ไม่ผ่าน

ถ้า ทั้ง สี่ ตัวเท่ากันหมด ก็ให้ค่าที่มี ความหมายและค่าสูงสด คือ ดย
แต่ถ้า ทั้งหมด สี่ ตัวนี้ มีค่าไหนแยอะกว่า ก็ให้เป็นค่า นั้น ครับ เช่น มี ด แยอะ ก็ออกมา ด

ขอบคุณครับที่แนะนำ จะนำควารู้ที่ได้ นำไปใช้ให้เกิด ประโยชน์ สูงสุด

[snasui]

แนบไฟล์ตัวอย่างที่ถูกต้องมาใหม่โดยให้มีทุกตัวอย่างที่กล่าวมาครับ

ถ้าเป็นไปได้ให้ทำตามคำตอบด้านบนแล้วชี้ให้เห็นว่าคำตอบไหนไม่เป็นไปตามที่ต้องการ คำตอบที่ต้องการเป็นค่าใด จะได้ช่วยปรับปรุงสูตรต่อไปจากนั้นครับ

[sommor]

ขอบคุณ ครับอาจารย์ จะทดสอบดู

[sommor]

ขอบคุณ ครับ อาจารย์ ที่แนะนำ ผมพยายามใช้ลักษณะ นี้ รู้แต่หลัการ แต่ไม่รู้วิธี ทำ

ขอบคุณสำหรับสุตรต่างๆ ที่ให้มา ครับ ผมต้องการนำไปพัฒนาการเรียนการสอน ช่วยครู ประจำชั้น ช่วย งานวิชาการ ธุรการ ถึงเขาจะไม่มีคุณค่าเรา แต่เราก็ทำเพื่อให้เขาได้ทำงานสบายขึ้น ไม่ต้องไปนั่งปวดสมอง อย่างที่เรานั่งคิดนั่งเขียนโปรแกรม

ที่ I5 เป็น
=INDEX({"ดย","ด","ผ","มผ"},MATCH(MAX(COUNTIF(D5:H5,{"ดย","ด","ผ","มผ"})),COUNTIF(D5:H5,{"ดย","ด","ผ","มผ"}),0))

=INDEX(D5:H5,MATCH(MAX(COUNTIF(D5:H5,D5:H5)),COUNTIF(D5:H5,D5:H5),0))

ขอขอบคุณทั่งสูตร นี้ ครับ

[sommor]

ทดสอบ เปรียบเทียมแล้ว ครับ อาจารย์ สูตรนี้ ผ่าน

=INDEX({"ดย","ด","ผ","มผ"},MATCH(MAX(COUNTIF(D5:H5,{"ดย","ด","ผ","มผ"})),COUNTIF(D5:H5,{"ดย","ด","ผ","มผ"}),0)) apirak2455