snasui.com ยินดีต้อนรับ
ยินดีต้อนรับสู่กระดานถามตอบ Excel and VBA และอื่น ๆ ที่เป็นมิตรกับทุกท่าน มีไฟล์แนบมหาศาล ช่วยให้ท่านค้นหาและติดตามศึกษาได้โดยง่าย สมาชิกท่านใดที่ยังไม่ได้ระบุ Version ของ Excel ที่ใช้งานจริง สามารถทำตาม Link นี้เพื่อจะได้รับคำตอบที่ตรงกับ Version ของท่านครับ ระบุ Version ของ Excel
ฟอรัมถาม-ตอบปัญหาการใช้งาน MS Excel and VBA
Forum rules
ไม่อนุญาตให้ใช้ภาษาแชทในการถามและตอบปัญหา ไม่ใช้คำว่า "คับ" หรือ "อ่ะครับ" แทนคำว่า "ครับ" ไม่ใช้คำว่า "เด๋ว" แทนคำว่า "เดี๋ยว" เป็นต้น เนื่องจากเมื่อแปลเป็นภาษาต่างประเทศแล้วจะให้ความหมายผิดไปจากที่ควรจะเป็น
ห้ามถามโดยระบุชื่อผู้ตอบและต้องตั้งชื่อกระทู้ให้สื่อถึงปัญหาที่จะถาม ไม่ตั้งชื่อว่า ช่วยด้วยครับ, มีปัญหามาปรึกษาครับ เป็นต้น
กรุณาอธิบายปัญหาและระบุคำตอบที่ต้องการมาในกระทู้ด้วยเสมอถึงแม้จะอธิบายไว้ในไฟล์แนบแล้วก็ตาม ทั้งนี้เพื่ออำนวยความสะดวกแก่เพื่อนสมาชิกในการค้นหาข้อมูล
กรุณาแนบไฟล์ตัวอย่างพร้อมแสดงคำตอบที่ถูกต้องมาในไฟล์ด้วยเพื่อให้ง่ายต่อการทำความเข้าใจและสะดวกต่อการตอบคำถาม (ขนาดไฟล์ไม่เกิน 500Kb ขนาดภาพไม่เกิน 800*600 Pixel) ไม่แนบเป็น Link มาจากแหล่งอื่นที่อาจจะถูกลบทิ้งไปโดยต้นทางในภายหลัง นอกจากนี้ไม่ควรแนบไฟล์ที่มีข้อมูลสำคัญอันก่อให้เกิดความเสียหายกับตนเองและผู้อื่น
กรณีเป็นคำถามเกี่ยวกับ Programming เช่น VBA, VB.Net, C#, SQL ฯลฯ ต้องลองเขียนมาเองก่อนเสมอ ถามเฉพาะที่ติดปัญหา ระบุ Module, Procedure ที่ติดปัญหาให้ชัดเจน กรุณาโพสต์ Code ให้แสดงเป็น Code คือเปิดด้วย [code]
และปิดด้วย [/code]
ตัวอย่างเช่น [code]dim r as range[/code]
เพื่อให้แตกต่างจากข้อความทั่วไป สะดวกในการอ่านและทดสอบ (คลิกเพื่อดูตัวอย่าง)
กรุณาแจ้งผลการใช้งานเมื่อได้รับคำตอบว่าตรงกับความต้องการหรือไม่
blepuviput
Member
Posts: 44 Joined: Sat Apr 24, 2021 1:16 pm
Excel Ver: 365
#1
Post
by blepuviput » Thu Apr 20, 2023 5:22 pm
เรียนท่านผู้รู้
จะเขียนสูตรในคอลัมน์ AH4 อย่างไร เพื่อแสดงให้เห็นว่ามีหรือไม่มีค่านับจากคอลัมน์ C4 ถึง AG4 ที่รวมกันมากกว่า 6 หรือไม่
ซึ่งคำตอบที่ต้องการมีวัตถุประสงค์เพื่อนำไปประยุกต์ใช้ในการ Audit ในส่วนของการเข้าทำงานเกิน 6 วันทำงานต่อเนื่องหรือไม่ครับ
และสามารถใช้ Conditional Formatting ระบายสีเหลืองกรณีที่มีค่าตรวจนับเกิน 6 วันหรือไม่ ในคอลัมน์ดังตาราง
ขอบคุณครับ
You do not have the required permissions to view the files attached to this post.
Bo_ry
Gold
Posts: 1245 Joined: Sun Aug 12, 2018 12:11 am
Excel Ver: MS 365
Contact:
#2
Post
by Bo_ry » Thu Apr 20, 2023 9:41 pm
AH4
=IF(MAX(LEN(TEXTSPLIT(CONCAT(IF(C4:AG4,1,0)),0)))<7,"ไม่",)&"มี"
Conditional Formatting
=LEN(TEXTAFTER(CONCAT(IF($C4:C4,1,)),0,-1,,1)&TEXTBEFORE(CONCAT(IF(C4:$AG4,1,)),0,,,1))>7
You do not have the required permissions to view the files attached to this post.
blepuviput
Member
Posts: 44 Joined: Sat Apr 24, 2021 1:16 pm
Excel Ver: 365
#3
Post
by blepuviput » Fri Apr 21, 2023 10:05 am
เรียน K.Bo_ry
ขอบคุณมากครับสำหรับคำตอบสามารถนำมาใช้กับเครื่องที่ผมใช้ Microsoft 365 ได้
แต่ถ้าใน Excel ของเครื่องที่ใช้ทางริษัทเป็น Version เก่าค่าที่ได้เป็น#NAME? สามารถเขียนสูตรได้ไหมครับ
ขอบคุณครับ
snasui
Site Admin
Posts: 30917 Joined: Sun Jan 24, 2010 12:33 pm
Location: Songkhla, Thailand
Excel Ver: 2010, 365
Contact:
#4
Post
by snasui » Sat Apr 22, 2023 9:26 am
blepuviput wrote: Fri Apr 21, 2023 10:05 am
Excel ของเครื่องที่ใช้ทางริษัทเป็น Version เก่าค่าที่ได้เป็น#NAME? สามารถเขียนสูตรได้ไหมครับ
เขียนได้ครับ
เพื่อประโยชน์ในการทำ Conditional Formatting ได้ง่ายขึ้นให้แทรก 2 คอลัมน์คือ C และ AI จากนั้นเขียนสูตรที่ AJ เพื่อแสดงว่ามีหรือไม่มีค่าตามเงื่อนไขดังด้านล่าง
=IF(MAX(FREQUENCY(IF(D4:AH4=1,COLUMN(D4:AH4)),IF(D4:AH4=0,COLUMN(D4:AH4))))>6,"มี","ไม่มี")
Ctrl+Shift+Enter
จากนั้นทำ Conditional Formatting โดยการคลุม D4:AH13 โดยใช้สูตรด้านล่าง
=AND(D4<>"",COUNTIFS(OFFSET($C4,0,MATCH(2,INDEX(1/($C4:C4=""),0)),1,COLUMNS($D4:D4)-MATCH(2,INDEX(1/($C4:C4=""),0))+MATCH(1,INDEX(1/(D4:$AI4=""),0),0)),1)>6)
Bo_ry
Gold
Posts: 1245 Joined: Sun Aug 12, 2018 12:11 am
Excel Ver: MS 365
Contact:
#5
Post
by Bo_ry » Sat Apr 22, 2023 1:09 pm
AI4
=IF(OR(FREQUENCY(IF(C4:AG4,$C$3:$AG$3),IF(C4:AG4=0,$C$3:$AG$3))>6),,"ไม่")&"มี"
Conditional Formatting
=IFNA(MATCH(0,-C4:$AG4,)-1,COLUMNS(C4:$AG4))+COLUMNS($C4:C4)-IFERROR(MATCH(2,1/($C4:C4=0)),)
You do not have the required permissions to view the files attached to this post.
blepuviput
Member
Posts: 44 Joined: Sat Apr 24, 2021 1:16 pm
Excel Ver: 365
#6
Post
by blepuviput » Sat Apr 22, 2023 5:31 pm
เรียนท่านอาจารย์ snasui และ ท่านBo_ry
ได้คำตอบตามที่ต้องการเลยครับ ขอบคุณมากครับผม