snasui.com ยินดีต้อนรับ
ยินดีต้อนรับสู่กระดานถามตอบ Excel and VBA และอื่น ๆ ที่เป็นมิตรกับทุกท่าน มีไฟล์แนบมหาศาล ช่วยให้ท่านค้นหาและติดตามศึกษาได้โดยง่าย สมาชิกท่านใดที่ยังไม่ได้ระบุ Version ของ Excel ที่ใช้งานจริง สามารถทำตาม Link นี้เพื่อจะได้รับคำตอบที่ตรงกับ Version ของท่านครับ ระบุ Version ของ Excel
ฟอรัมถาม-ตอบปัญหาการใช้งาน MS Excel and VBA
Forum rules
ไม่อนุญาตให้ใช้ภาษาแชทในการถามและตอบปัญหา ไม่ใช้คำว่า "คับ" หรือ "อ่ะครับ" แทนคำว่า "ครับ" ไม่ใช้คำว่า "เด๋ว" แทนคำว่า "เดี๋ยว" เป็นต้น เนื่องจากเมื่อแปลเป็นภาษาต่างประเทศแล้วจะให้ความหมายผิดไปจากที่ควรจะเป็น
ห้ามถามโดยระบุชื่อผู้ตอบและต้องตั้งชื่อกระทู้ให้สื่อถึงปัญหาที่จะถาม ไม่ตั้งชื่อว่า ช่วยด้วยครับ, มีปัญหามาปรึกษาครับ เป็นต้น
กรุณาอธิบายปัญหาและระบุคำตอบที่ต้องการมาในกระทู้ด้วยเสมอถึงแม้จะอธิบายไว้ในไฟล์แนบแล้วก็ตาม ทั้งนี้เพื่ออำนวยความสะดวกแก่เพื่อนสมาชิกในการค้นหาข้อมูล
กรุณาแนบไฟล์ตัวอย่างพร้อมแสดงคำตอบที่ถูกต้องมาในไฟล์ด้วยเพื่อให้ง่ายต่อการทำความเข้าใจและสะดวกต่อการตอบคำถาม (ขนาดไฟล์ไม่เกิน 500Kb ขนาดภาพไม่เกิน 800*600 Pixel) ไม่แนบเป็น Link มาจากแหล่งอื่นที่อาจจะถูกลบทิ้งไปโดยต้นทางในภายหลัง นอกจากนี้ไม่ควรแนบไฟล์ที่มีข้อมูลสำคัญอันก่อให้เกิดความเสียหายกับตนเองและผู้อื่น
กรณีเป็นคำถามเกี่ยวกับ Programming เช่น VBA, VB.Net, C#, SQL ฯลฯ ต้องลองเขียนมาเองก่อนเสมอ ถามเฉพาะที่ติดปัญหา ระบุ Module, Procedure ที่ติดปัญหาให้ชัดเจน กรุณาโพสต์ Code ให้แสดงเป็น Code คือเปิดด้วย [code]
และปิดด้วย [/code]
ตัวอย่างเช่น [code]dim r as range[/code]
เพื่อให้แตกต่างจากข้อความทั่วไป สะดวกในการอ่านและทดสอบ (คลิกเพื่อดูตัวอย่าง)
กรุณาแจ้งผลการใช้งานเมื่อได้รับคำตอบว่าตรงกับความต้องการหรือไม่
aniwat2011
Member
Posts: 132 Joined: Tue Mar 08, 2011 2:21 pm
Location: ขอนแก่น
Excel Ver: 2019
#1
Post
by aniwat2011 » Tue Mar 01, 2022 3:12 pm
เรียนสอบถามผู้รู้ครับ
กรณีที่ 1 ต้องการหาจำนวน โดยนำข้อมูลจาก Sheet2 Sheet3 และ Sheet4 ที่มีข้อมูล (ชื่อผลไม้/รหัส/หน่วยนับ/ราคาต่อหน่วย) ตรงกับตารางที่ 1 ทุกเงื่อนไข โดยที่ข้อมูลใน Sheet2 Sheet3 และ Sheet4 มีรายการผลไม้ไม่ครบใน Sheet1 (แต่ไม่เกินตามตารางที่กำหนด) และเรียงลำดับไม่ตรงกับ Sheet1
กรณีที่ 2 ต้องการหาชื่อผลไม้ รหัส หน่วยนับ ราคาต่อหน่วย ที่ข้อมูลไม่ซ้ำกัน และรวมจำนวนของรายการที่ไม่ซ้ำ
โดยที่ข้อมูลใน Sheet2 Sheet3 และ Sheet4 มีรายการผลไม้ รหัส หน่วยนับ ราคาต่อหน่วยแตกต่างกันไป
ตัวอย่างและคำตอบ ตามไฟล์แนบครับ
ขอบคุณครับ
สอบถามสูตรการรวมตัวเลขแบบมีเงื่อนไข.xlsx
You do not have the required permissions to view the files attached to this post.
aniwat2011
Member
Posts: 132 Joined: Tue Mar 08, 2011 2:21 pm
Location: ขอนแก่น
Excel Ver: 2019
#2
Post
by aniwat2011 » Tue Mar 01, 2022 3:22 pm
ไฟล์ที่แนบครั้งแรกข้อมูลไม่ครบครับ ขอภัยด้วยครับ
สอบถามสูตรการรวมตัวเลขแบบมีเงื่อนไข.xlsx
You do not have the required permissions to view the files attached to this post.
snasui
Site Admin
Posts: 30751 Joined: Sun Jan 24, 2010 12:33 pm
Location: Songkhla, Thailand
Excel Ver: 2010, 365
Contact:
#3
Post
by snasui » Tue Mar 01, 2022 9:06 pm
ตัวอย่างสูตรตามด้านล่างครับ
ที่ G5 คีย์สูตรรวมค่าจากทุกชีต
=SUMPRODUCT(SUMIFS(INDIRECT("'"&{"Sheet2","Sheet3","Sheet4"}&"'!G5:G10"),INDIRECT("'"&{"Sheet2","Sheet3","Sheet4"}&"'!D5:D10"),D5))
Enter > Copy ลงด้านล่าง
ที่ D17 คีย์สูตรแสดงรหัสจากหลายชีตที่ไม่ซ้ำกัน
=INDEX(FILTERXML("<t><s>"&SUBSTITUTE(TEXTJOIN(",",TRUE,Sheet2!$D$15:$D$20,Sheet3!$D$14:$D$19,Sheet4!$D$14:$D$19),",","</s><s>")&"</s></t>","//s[not(preceding::*=.)]"),B17)
Enter > Copy ลงด้านล่าง
ที่ I17 คีย์สูตรแสดงรายชื่อชีตที่พบรหัสตามข้อ 2
=INDEX({"Sheet2","Sheet3","Sheet4"},MATCH(TRUE,COUNTIFS(INDIRECT("'"&{"Sheet2","Sheet3","Sheet4"}&"'!D14:D1000"),$D17)>0,0))
Enter > Copy ลงด้านล่าง
ที่ C17 คีย์สูตรแสดงรายการที่เกี่ยวข้อง
=INDEX(INDIRECT("'"&$I17&"'!C14:H1000"),MATCH($D17,INDIRECT("'"&$I17&"'!D14:D1000"),0),COLUMNS($C16:C16))
Enter > Copy ลงด้านล่าง > คัดลอกไปใช้ที่คอลัมน์ E:F
ที่ G17 คีย์สูตรรวมยอดจากหลายชีต
=SUMPRODUCT(SUMIFS(INDIRECT("'"&{"Sheet2","Sheet3","Sheet4"}&"'!G14:G1000"),INDIRECT("'"&{"Sheet2","Sheet3","Sheet4"}&"'!D14:D1000"),D17))
Enter > Copy ลงด้านล่าง
aniwat2011
Member
Posts: 132 Joined: Tue Mar 08, 2011 2:21 pm
Location: ขอนแก่น
Excel Ver: 2019
#4
Post
by aniwat2011 » Tue Mar 01, 2022 10:00 pm
ขอบพระคุณครับอาจารย์ ที่กรุณา ผมเห็นสูตรแล้วผมท้อเลยครับแบบนี้อีกกี่ปีผมถึงจะคิดเองได้
aniwat2011
Member
Posts: 132 Joined: Tue Mar 08, 2011 2:21 pm
Location: ขอนแก่น
Excel Ver: 2019
#5
Post
by aniwat2011 » Tue Mar 01, 2022 10:14 pm
ผมได้คัดลอกสูตรไปวางในไฟล์แล้วทึ่งมากครับอาจารย์ อย่างกับเนรมิต ได้ผลลัพธ์ตรงตามที่กำหนดไว้เลยครับ
ภาพ2.jpg
สุดยอดมากครับ
You do not have the required permissions to view the files attached to this post.
aniwat2011
Member
Posts: 132 Joined: Tue Mar 08, 2011 2:21 pm
Location: ขอนแก่น
Excel Ver: 2019
#6
Post
by aniwat2011 » Wed Mar 02, 2022 2:11 pm
สูตรข้างบนสามารถใช้ได้กับ Excel 2010 หรือ เวอร์ชั่นต่ำกว่า 2019 ไหมครับอาจารย์
snasui
Site Admin
Posts: 30751 Joined: Sun Jan 24, 2010 12:33 pm
Location: Songkhla, Thailand
Excel Ver: 2010, 365
Contact:
#7
Post
by snasui » Wed Mar 02, 2022 8:13 pm
ไม่สามารถใช้กับ Version ที่น้อยกว่า 2019 ได้ครับ
aniwat2011
Member
Posts: 132 Joined: Tue Mar 08, 2011 2:21 pm
Location: ขอนแก่น
Excel Ver: 2019
#8
Post
by aniwat2011 » Wed Mar 02, 2022 9:58 pm
อาจารย์เมตตาให้สูตรที่ใช้ร่วมกันได้กับ Excel2010 -2019 ด้วยนะครับ
ขอบคุณครับ
snasui
Site Admin
Posts: 30751 Joined: Sun Jan 24, 2010 12:33 pm
Location: Songkhla, Thailand
Excel Ver: 2010, 365
Contact:
#9
Post
by snasui » Thu Mar 03, 2022 12:17 am
snasui wrote: ↑ Tue Mar 01, 2022 9:06 pm
ที่ D17 คีย์สูตรแสดงรหัสจากหลายชีตที่ไม่ซ้ำกัน
=INDEX(FILTERXML("<t><s>"&SUBSTITUTE(TEXTJOIN(",",TRUE,Sheet2!$D$15:$D$20,Sheet3!$D$14:$D$19,Sheet4!$D$14:$D$19),",","</s><s>")&"</s></t>","//s[not(preceding::*=.)]"),B17)
Enter > Copy ลงด้านล่าง
ตัวอย่างสูตรสำหรับแทนสูตรเฉพาะที่ยกมาด้านบน ส่วนสูตรอื่น ๆ ใช้ของเดิมครับ
เซลล์ P16, Q16, R16, R17, R18, R19, R20 คีย์ ListCode, ListSheet, UniqueCount:, Total:, Sheet2, Sheet3, Sheet4 เพื่อเป็นชื่อคอลัมน์หรือชื่อรายการตามลำดับ
ที่ S17 คีย์สูตรเพื่อนับจำนวนของทุกชีต
=SUMPRODUCT(COUNTIFS(INDIRECT("'"&R18:R20&"'!D14:D100"),"<>"))
Enter
ที่ S18 คีย์สูตรแสดงลำดับเริ่มของชีตนั้น ๆ ที่นับต่อมาจากชีตก่อนหน้า
=SUMPRODUCT(COUNTIFS(INDIRECT("'"&R$18:R18&"'!D14:D100"),"<>"))-SUMPRODUCT(COUNTIFS(INDIRECT("'"&R18&"'!D14:D100"),"<>"))+1
Enter > Copy ลงด้านล่าง
ที่ Q17 คีย์สูตรเพื่อแสดงรายชื่อชีต
=IF(ROWS(Q$17:Q17)>$S$17,"",LOOKUP(ROWS(Q$17:Q17),$S$18:$S$20,$R$18:$R$20))
Enter > Copy ลงด้านล่าง
ที่ P17 คีย์สูตรเพื่อแสดงรหัสของทุกชีต
=IF(ROWS(Q$17:Q17)>$S$17,"",INDIRECT("'"&Q17&"'!R"&13+COUNTIFS(Q$17:Q17,Q17)&"C4",0))
Enter > Copy ลงด้านล่าง
ที่ S16 คีย์สูตรเพื่อนับค่าที่ไม่ซ้ำ
=COUNT(AGGREGATE(15,6,ROW($P$17:$P$27)/ISNUMBER(--RIGHT($P$17:$P$27))/(0<FREQUENCY(MATCH($P$17:$P$27,$P$17:$P$27,0),ROW($P$17:$P$27)-ROW($P$17)+1)),INDEX(ROW(INDIRECT("1:"&S17)),0)))
Enter > Copy ลงด้านล่าง
ที่ D17 คีย์สูตรเพื่อแสดงรายการรหัสเฉพาะที่ไม่ซ้ำ
=IF(B17>$S$16,"",INDEX(P:P,AGGREGATE(15,6,ROW($P$17:$P$27)/ISNUMBER(--RIGHT($P$17:$P$27))/(0<FREQUENCY(MATCH($P$17:$P$27,$P$17:$P$27,0),ROW($P$17:$P$27)-ROW($P$17)+1)),B17)))
Enter > Copy ลงด้านล่าง
aniwat2011
Member
Posts: 132 Joined: Tue Mar 08, 2011 2:21 pm
Location: ขอนแก่น
Excel Ver: 2019
#10
Post
by aniwat2011 » Thu Mar 03, 2022 11:55 am
ขอบคุณอาจารย์มาก ๆ ครับ