ดึงข้อมูลที่มีจำนวนเท่ากับ 0 มาแสดงโดยไม่ใช้ฟิลเตอร์

[RS.TOP]

เรียนสอบถามอาจารย์และผู้เชี่ยวชาญครับ,

ผมมีชีทงานที่ต้องการขอความช่วยเหลือจากอาจารย์และผู้เชี่ยวชาญ ในด้านการใส่สูตรตามเงื่อนไขครับ

ไฟล์งานจะประกอบด้วย 2 ชีท
- Sheet 'Service-Pull SL Kit' เป็นในส่วนของข้อมูล
- Sheet 'Service-Pull Zero SOH' เป็นส่วนแสดงข้อมูลตามเงื่อนไข

เงื่อนไขของการนำข้อมูลมาแสดง
- ค่าใน Column G จากชีท 'Service-Pull SL Kit' จะต้องมาค่าเท่ากับ 0
- ข้อมูลที่ดังมาแสดงในชีท 'Service-Pull Zero SOH' จะดึงข้อมูลมาจาก Cell ตามด้านล่าง
Cell B3 นำค่ามาจาก Column A
Cell C3 นำค่ามาจาก Column B
Cell D3 นำค่ามาจาก Column C
Cell E3 นำค่ามาจาก Column G
Cell F3 นำค่ามาจาก Column D
Cell G3 นำค่ามาจาก Column H
Cell H3 นำค่ามาจาก Column E

ขอขอบพระคุณล่วงหน้าสำหรับการชี้แนะสูตรครับ

Excel ดึงข้อมูลที่มีค่า 0.xlsx

[norkaz]

...

สูตรแต่ละคอลัมน์ เหมือนๆกัน ต่างกันตรง INDEX ตามคอลัมน์ ที่ต้องการ

B3
=IFERROR(INDEX('Service-Pull SL Kit'!A:A,AGGREGATE(15,6,ROW('Service-Pull SL Kit'!$G$2:$G$550)/(--('Service-Pull SL Kit'!$G$2:$G$550)=0),ROWS(B$3:B3))),"")

C3
=IFERROR(INDEX('Service-Pull SL Kit'!B:B,AGGREGATE(15,6,ROW('Service-Pull SL Kit'!$G$2:$G$550)/(--('Service-Pull SL Kit'!$G$2:$G$550)=0),ROWS(C$3:C3))),"")

D3
=IFERROR(INDEX('Service-Pull SL Kit'!C:C,AGGREGATE(15,6,ROW('Service-Pull SL Kit'!$G$2:$G$550)/(--('Service-Pull SL Kit'!$G$2:$G$550)=0),ROWS(D$3:D3))),"")

E3
=IFERROR(INDEX('Service-Pull SL Kit'!G:G,AGGREGATE(15,6,ROW('Service-Pull SL Kit'!$G$2:$G$550)/(--('Service-Pull SL Kit'!$G$2:$G$550)=0),ROWS(E$3:E3))),"")

G3
=IFERROR(INDEX('Service-Pull SL Kit'!H:H,AGGREGATE(15,6,ROW('Service-Pull SL Kit'!$G$2:$G$550)/(--('Service-Pull SL Kit'!$G$2:$G$550)=0),ROWS(G$3:G3))),"")

H3
=IFERROR(INDEX('Service-Pull SL Kit'!E:E,AGGREGATE(15,6,ROW('Service-Pull SL Kit'!$G$2:$G$550)/(--('Service-Pull SL Kit'!$G$2:$G$550)=0),ROWS(H$3:H3))),"")

Norkaz

[RS.TOP]

ได้รับแล้วครับ นำไปประยุกต์ และใช้งานได้ดีครับ
ขอบคุณมากๆครับ