เลือกเงื่อนไขแล้วหาผลรวมจาก sheet ต่างๆ

[Jancha]

สิ่งที่ต้องการคือ
- เมื่อเลือกช่วงวันที่ใดๆใน B4:D4 to B5:D5
- แล้วให้ทำการคำนวณผลใน H8:H10, I8:I10 จาก sheet เดือนต่างๆได้อย่างอัตโนมัติ

ลองทำเองตอนนี้ได้แค่อยากรู้ข้อมูลช่วงใดก็เขียนสูตรดูเป็นช่วงๆไปครับ

[puriwutpokin]

ลองดูจากไฟล์แนบนะครับ อธิบายไม่ถูกครับลองดูครับ

[Jancha]

ผมลองเปลี่ยนช่วงเงื่อนไขดูปรากฏว่าผลรวมที่ได้ไม่ตรงกับข้อมูลจริงครับ แต่ขอบคุณครับสำหรับความช่วยเหลือครับ

[snasui]

ตัวอย่างสูตร ซึ่งเป็นการสร้าง Database ใหม่ในชีท Report เพื่อสะดวกต่อการใช้งาน โดยทำตามด้านล่างตามลำดับครับ

1. K1:O1 คีย์ข้อความ Sheet, Columns, Line, Rows, StartLine ตามลำดับเพื่อเป็นหัวคอลัมน์ของข้อมูลช่วยคำนวณแสดงมิติของข้อมูล
2. K6:P6 คีย์ข้อความ No, Sheet, Day, Date, Category และ Data เพื่อเป็นหัวคอลัมน์ของ Database
3. K2:K4 คีย์ชื่อชีตทั้งหมดในที่นี้คือ Jan, Feb และ Mar
4. L2 คีย์สูตร
   =COUNT(INDIRECT("'"&K2&"'!C4:AG4"))
   Enter > Copy ลงด้านล่างถึง L4
5. M2 คีย์สูตร
   =COUNTA(INDIRECT("'"&K2&"'!B5:B100"))
   Enter > Copy ลงด้านล่างถึง M4
6. N2 คีย์สูตร
   =L2*M2
   Enter > Copy ลงด้านล่างถึง N4
7. N5 คีย์สูตร
   =SUM(N2:N4)
   Enter
8. O2 คีย์สูตร
   =SUM(N$2:N2)-N2+1
   Enter > Copy ลงด้านล่างถึง O4
9. K7 คีย์สูตร
   =IF(ROWS(K$7:K7)>$N$5,"",ROWS(K$7:K7))
   Enter > Copy ลงด้านล่างจนเห็นเซลล์ว่าง
10. L7 คีย์สูตร
    =IF(N(K7),LOOKUP(K7,$O$2:$O$4,$K$2:$K$4),"")
    Enter > Copy ลงด้านล่างจนเห็นเซลล์ว่าง
11. M7 คีย์สูตร
    =IF(N(K7),INDEX(INDIRECT("'"&L7&"'!C4:AG4"),MOD(COUNTIF(L$7:L7,L7)-1,LOOKUP(K7,$O$2:$O$4,$L$2:$L$4))+1),"")
    Enter > Copy ลงด้านล่างจนเห็นเซลล์ว่าง
12. N7 คีย์สูตร
    =IF(N(K7),(M7&L7&2017)+0,"")
    Enter > Copy ลงด้านล่างจนเห็นเซลล์ว่าง
13. O7 คีย์สูตร
    =IF(N(K7),INDEX(INDIRECT("'"&L7&"'!B5:B7"),COUNTIFS(L$7:L7,L7,$M$7:M7,M7)),"")
    Enter > Copy ลงด้านล่างจนเห็นเซลล์ว่าง
14. P7 คีย์สูตร
    =IF(N(K7),INDEX(INDIRECT("'"&L7&""'!C5:AG7""),COUNTIFS(L$7:L7,L7,$M$7:M7,M7),M7),"")
    Enter > Copy ลงด้านล่างจนเห็นเซลล์ว่าง
15. H8 คีย์สูตรเพื่อหาคำตอบ
    =COUNTIFS($N$7:$N$276,">="&$B$4&$C$4&$D$4,$N$7:$N$276,"<="&$B$5&$C$5&$D$5,$O$7:$O$276,$G8,$P$7:$P$276,LEFT(H$7))
    Enter > Copy ไปทางขวาและลงด้านล่างจนเต็มตาราง

[Jancha]

ติดการวางสูตรในข้อ 4,5,11,13,14 ครับ

[snasui]

ผมแก้ไขเครื่องหมาย " ที่เกินมาในสูตรให้แล้ว ลองทดสอบดูใหม่ครับ

[Jancha]

ทำได้แล้วครับ ตอนนี้กำลังทำความเข้าใจสูตรอาจารย์อยู่ครับว่าใช้ตรรกะอย่างไรในการคิด การจัดข้อมูลผมคงมีส่วนให้คิดลำบาก แต่อาจารย์นำมาจัดใหม่และใช้สูตรพลิกแพลงขั้นเทพ ซูฮกเลยครับ ขอบคุณสำหรับความช่วยเหลือครับ