Snasui Excel Forum

คือผมมีข้อมูลอยู่ชุดหนึ่ง
ต้องการแยกออกมาแสดงเฉพาะแถวที่เกิน 100.- ผมจะต้องใช้สูตรอะไรครับ
ตามตัวอย่างแนบครับ

ขอบคุณครับ

**ที่ C2 =IF(B2-100>0,B2-100,"") copyลง
ที่ G2 =IFERROR(INDEX($A$2:$A$9,SMALL(IF($C$2:$C$9<>"",ROW($C$2:$C$9)-ROW($C$2)+1),
ROWS($G$2:G2))),"") +Ctrl+Shift+Enter copy ลง
ที่ H2=IFERROR(INDEX(B$2:B$9,MATCH($G2,$A$2:$A$9,0)),"") copyลง และ copy ไปทางขวา ครับ

puriwutpokin wrote:**ที่ C2 =IF(B2-100>0,B2-100,"") copyลง
ที่ G2 =IFERROR(INDEX($A$2:$A$9,SMALL(IF($C$2:$C$9<>"",ROW($C$2:$C$9)-ROW($C$2)+1),
ROWS($G$2:G2))),"") +Ctrl+Shift+Enter copy ลง
ที่ H2=IFERROR(INDEX(B$2:B$9,MATCH($G2,$A$2:$A$9,0)),"") copyลง และ copy ไปทางขวา ครับ

ทำไมของผมใส่สูตรแล้วไม่เห็นได้เลย

**ดูตามไฟล์แนบครับ

puriwutpokin wrote:**ดูตามไฟล์แนบครับ

จากสูตรในไฟล์แนบ หากคุณ baipan14 ไม่ได้ใช้ Excel 2007+ จะทำให้แสดงผลเป็นค่าผิดพลาด เนื่องจาก Iferror มีใช้ใน Excel 2007+ ครับ

สำหรับ Excel 2003 ปรับสูตรใหม่เป็น

1. เซลล์ G2
   =LOOKUP(CHAR(255),CHOOSE({1,2},"",INDEX($A$2:$A$9,SMALL(IF($C$2:$C$9<>"",ROW($C$2:$C$9)-ROW($C$2)+1),ROWS($G$2:G2)))))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
2. เซลล์ H2
   =IF(G2="","",INDEX(B$2:B$9,MATCH($G2,$A$2:$A$9,0)))
   Enter > Copy ลงด้านล่าง
3. เซลล์ I2
   =IF(G2="","",INDEX(C$2:C$9,MATCH($G2,$A$2:$A$9,0)))
   Enter > Copy ลงด้านล่าง

!

Note: Ctrl+Shift+Enter หมายถึง กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl+Shift ค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน จากนั้นกดแป้น Ctrl+Shift ค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้คีย์เข้าไปเองไม่ได้ ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง