Excel Forum

Posted: **Fri Aug 15, 2014 10:00 pm**

แจกไฟล์การค้นหาข้อมูลจากหลายชีทด้วยสูตรพร้อมแสดงทุกข้อมูลที่พบ ลองดาวน์โหลดไปศึกษาได้ตามไฟล์แนบครับ

สูตรตามด้านล่างครับ

ที่ F6 คีย์
=COUNTIF(INDIRECT("'"&$E6&"'!A:A"),$B$2)
Enter > Copy ลงด้านล่าง
ที่ F9 คีย์
=SUM(F6:F8)
Enter
ที่ G6 คีย์
=SUM(F$6:F6)-F6+1
Enter > Copy ลงด้านล่าง
ที่ A6 คีย์
=IF(ROWS(A$6:A6)>$F$9,"",LOOKUP(ROWS(A$6:A6),$G$6:$G$8,$E$6:$E$8))
Enter > Copy ลงด้านล่าง
ที่ B6 คีย์
=IF(ROWS(B$6:B6)>$F$9,"",INDEX(INDIRECT("'"&$A6&"'!b2:b10000"),SMALL(IF(INDIRECT("'"&$A6&"'!a2:a10000")=$B$2,ROW(INDIRECT("'"&$A6&"'!a2:a10000"))-MIN(ROW(INDIRECT("'"&$A6&"'!a2:a10000")))+1),COUNTIF($A$6:$A6,$A6))))
Ctrl+Shift+Enter > Copy ไป C6 > ลงด้านล่าง

!

Note: Ctrl+Shift+Enter
เป็นการสร้างสูตร Array โดยสามารถเลือกดำเนินการตามข้อ 1 หรือ 2 ด้านล่าง

กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น
Ctrl และ Shift พร้อมกันค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array
กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน
จากนั้นกดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วตามด้วย Enter เพื่อสร้างเป็นสูตร Array
หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)}
ปีกกานี้ไม่สามารถคีย์เข้าไปเอง จะต้องมาด้วยการกดแป้น Ctrl+Shift+Enter เท่านั้น
ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง
การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง

Posted: **Sat Aug 16, 2014 9:11 pm**

ขอบคุณมากมายครับอาจารย์

Posted: **Fri Sep 15, 2017 3:37 pm**

ขอบคุณครับ

Posted: **Sat Dec 09, 2017 11:00 am**

ขอบคุณคะ อาจารย์

Posted: **Sat Jan 05, 2019 8:53 am**

ขอนำไปศึกษาครับอาจารย์ ขอบคุณครับ

แจกไฟล์การค้นหาข้อมูลจากหลายชีทพร้อมแสดงทุกข้อมูลที่พบ