คลังคำตอบแห่งความรู้จากคนไทย เพื่อโลกที่ต้องการเข้าใจในสิ่งเล็ก ๆ อย่างลึกซึ้ง
https://snasui.com/
ลองแนบไฟล์พร้อม Code ที่ลองเขียนเองแล้วมาดูกันครับ หากเป็นเช่นนั้นคงช่วยไม่ได้มาก เนื่องจากว่าการใช้ VBA จำเป็นต้องเขียนมาก่อนตามกฎการใช้บอร์ดด้านบนครับ 
ควรแนบไฟล์ตัวอย่างมาด้วย Code ที่เขียนจำเป็นต้องมุ่งหมายที่จะใช้กับ Chart ครับ ติดตรงไหนจะได้ช่วยกันปรับปรุงแก้ไขต่อไปจากนั้น ลองตามนี้ครับ
Code: Select all
Private Declare Function GetDC Lib "user32" _
(ByVal hwnd As Long) As Long
Private Declare Function GetDeviceCaps Lib "gdi32" _
(ByVal hDC As Long, ByVal nIndex As Long) As Long
Private Declare Function ReleaseDC Lib "user32" _
(ByVal hwnd As Long, ByVal hDC As Long) As Long
Private Const LOGPIXELSX = 88 'Pixels/inch in X
'A point is defined as 1/72 inches
Private Const POINTS_PER_INCH As Long = 72
'The size of a pixel, in points
Public Function PointsPerPixel() As Double
Dim hDC As Long
Dim lDotsPerInch As Long
hDC = GetDC(0)
lDotsPerInch = GetDeviceCaps(hDC, LOGPIXELSX)
PointsPerPixel = POINTS_PER_INCH / lDotsPerInch
ReleaseDC 0, hDC
End FunctionCode: Select all
Private Sub Chart_MouseMove(ByVal Button As Long, _
ByVal Shift As Long, ByVal X As Long, ByVal Y As Long)
Dim dZoom As Double
Dim dXVal As Double
Dim dYVal As Double
Dim dPixelSize As Double
On Error Resume Next
Set mchtChart = Charts(1)
'The active window zoom factor
dZoom = ActiveWindow.Zoom / 100
'The pixel size, in points
dPixelSize = PointsPerPixel
'Mouse coordinates to (XY) Data coordinates
With mchtChart
dXVal = .Axes(xlCategory).MinimumScale + _
(.Axes(xlCategory).MaximumScale - _
.Axes(xlCategory).MinimumScale) * _
(X * dPixelSize / dZoom - _
(.PlotArea.InsideLeft + .ChartArea.Left)) / _
.PlotArea.InsideWidth
dYVal = .Axes(xlValue).MinimumScale + _
(.Axes(xlValue).MaximumScale - _
.Axes(xlValue).MinimumScale) * _
(1 - (Y * dPixelSize / dZoom - _
(.PlotArea.InsideTop + .ChartArea.Top)) / _
.PlotArea.InsideHeight)
End With
Application.StatusBar = "(" & Application.Round(dXVal, 2) _
& ", " & Application.Round(dYVal, 2) & ")"
'Mouse coordinates to Drawing Object Points
'We'll only move the oval if the Shift key is pressed
If Shift = 1 Then
With mchtChart
dXVal = (X * dPixelSize / dZoom - .ChartArea.Left)
dYVal = (Y * dPixelSize / dZoom - .ChartArea.Top)
With .Shapes("ovlPointer")
.Left = dXVal - .Width / 2
.Top = dYVal - .Height / 2
End With
End With
End If
End Sub! | Note: ปรับปรุง Code เล็กน้อย จาก "Professional Excel development" Chapter 15 By Stephen Bullen, Rob Bovey, John Green |
tuidento wrote:ลองทำดูแล้วครับ วงกลมไม่ขยับเลย แต่เห็นค่าแกนx,yแปลงเปลี่ยนที่status barครับ แต่ค่าไม่ตรงกับแกนครับ
ที่ไม่ตรงแกนเพราะไม่ได้ดูที่เมาส์ แต่เป้าหมายคือให้ดูที่วงกลมที่วาดขึ้น ลองทดสอบใหม่ตามไฟล์ที่ผมแนบมา ซึ่งผมได้เปลี่ยนให้ดูที่ Shapes(2) แทนShapes("ovalPointer") ซึ่งจริง ๆ แล้วต้องไม่ต่างกันการทำเช่นนั้นผมคิดว่าไม่น่าจะมีปัญหาใด เพียงแต่เปลี่ยนจาก MouseMove เป็น MouseDown และปรับการแสดงผลที่ Status bar เป็นแสดงที่เซลล์เป้าหมายแทน ซึ่งควรเขียนมาเอง ติดตรงไหนแล้วค่อยถามกันครับtuidento wrote:และถ้าอยาก ให้กดครั้งที่1 ค่าx บันทึกที่ ("sheet1").range("d1") ค่าyบันทึกที่("sheet1").range("E1")
และกดครั้งที่2 ค่าx บันทึกที่ ("sheet1").range("d2") ค่าyบันทึกที่("sheet1").range("E2")
ประมาณนี้ได้ไหมครับ
ลองปรับ Code เป็นตามด้านล่างCode: Select all
Dim dXVal As Double
Dim dYVal As Double
Dim dXVal1 As Double
Dim dYVal1 As Double
Dim dZoom As Double
Dim dPixelSize As Double
Dim mchtChart As Chart
Private Sub Chart_MouseMove(ByVal Button As Long, _
ByVal Shift As Long, ByVal x As Long, ByVal y As Long)
Set mchtChart = Charts(1)
On Error Resume Next
'The active window zoom factor
dZoom = ActiveWindow.Zoom / 100
'The pixel size, in points
dPixelSize = PointsPerPixel
'Mouse coordinates to (XY) Data coordinates
With mchtChart
dXVal = .Axes(xlCategory).MinimumScale + _
(.Axes(xlCategory).MaximumScale - _
.Axes(xlCategory).MinimumScale) * _
(x * dPixelSize / dZoom - _
(.PlotArea.InsideLeft + .ChartArea.Left)) / _
.PlotArea.InsideWidth
dYVal = .Axes(xlValue).MinimumScale + _
(.Axes(xlValue).MaximumScale - _
.Axes(xlValue).MinimumScale) * _
(1 - (y * dPixelSize / dZoom - _
(.PlotArea.InsideTop + .ChartArea.Top)) / _
.PlotArea.InsideHeight)
End With
Application.StatusBar = "(" & Round(dXVal, 2) & "," & Round(dYVal, 2) & ")"
'Mouse coordinates to Drawing Object Points
If Shift = 1 Then
With mchtChart
dXVal1 = (x * dPixelSize / dZoom - .ChartArea.Left)
dYVal1 = (y * dPixelSize / dZoom - .ChartArea.Top)
With .Shapes(1)
.Left = dXVal1 - .Width / 2
.Top = dYVal1 - .Height / 2
End With
End With
End If
End Sub
Private Sub Chart_MouseDown(ByVal Button As Long, ByVal Shift As Long, ByVal x As Long, ByVal y As Long)
With Worksheets("Sheet1")
If .Range("d1") = "" Then
.Range("d1") = Round(dXVal, 2)
.Range("e1") = Round(dYVal, 2)
Else
.Range("d65536").End(xlUp).Offset(1, 0) = Round(dXVal, 2)
.Range("e65536").End(xlUp).Offset(1, 0) = Round(dYVal, 2)
End If
End With
End Sub
Code ไหนที่ทำงานเมื่อคลิกอันนี้จำเป็นต้องทราบหรือไม่ก็ต้องลองผิดลองถูกมาเอง และเราสามารถแทรก Code ที่ Procedure นั้น การใช้ Code VBA จำเป็นต้องปรับเองได้บ้าง หากปรับเองไม่ได้เลยไม่ควรใช้ VBA หากจำเป็นที่จะต้องใช้จริง ๆ ก็ต้องพึ่งผู้ที่เขียนเป็นเขียนให้ ติดตรงไหนค่อยถามกัน ผมเน้นการแก้ปัญหาเป็นหลักครับ 
ไม่เข้าใจครับ ผมคลิกแล้วไม่มีอะไรเกิดขึ้น ผมต้องทำอะไรก่อนคลิกหรือไม่ ค่าจะไปบันทึกที่ใด ได้เขียน Code การดักจับมาแล้วหรือไม่ว่าหากครบ 3 ครั้งแล้วจะไม่บันทึกอีก Code นั้นชื่อว่าอะไร ติดขัดบรรทัดใดครับ 