Excel Forum

ยกตัวอย่างนะคะ ข้อมูลใน sheet 1
งานรุ่น A จำนวน 100 ประกอบด้วย
XXX ฝา 100
XXY แก้ว 100

งานรุ่น B จำนวน 100 ประกอบด้วย
YYX แก้ว 100
YYY ฝา 100

งานรุ่น C จำนวน 100 ประกอบด้วย
YYY ฝา 100
XXX ฝา 100
XXY แก้ว 100
YYX แก้ว 100

ส่วน sheet 2 อยากให้แสดงชื่อ แก้วที่ใช้ทั้งหมด และถ้ารุ่นซ้ำกันให้แสดงผลแค่ 1 แต่จำนวนใช้เป็นยอดรวม ดังนี้
แก้ว
XXY 200
YYX 200

ค่อย ๆ ถามตอบกันไปนะครับ

การอ้างอิงชีทและเซลล์ ให้อ้างอิงตามไฟล์แนบ มีชีทชื่อใดบ้างที่เกี่ยวข้องให้อ้างถึงชื่อนั้น เพื่อเข้าใจตรงกันและเข้าถึงข้อมูลได้โดยเร็ว สำหรับการนำ Database มาทำรายงานในมุมมองต่าง ๆ สามารถใช้ PivotTable แทนการสรุปด้วยสูตรครับ

จากที่ถามมานั้น ชีท Glassware เซลล์ B5 มีค่า 6000 นำมาจากชีทไหน เซลล์ไหน หรือมีวิธีการคำนวณอย่างไร ลองแจกแจงมาเป็นข้อ ๆ ครับ

ขอบคุณค่ะ
รบกวนดูรายละเอียดที่ไฟล์แนบอีกครั้งค่ะ อธิบายไว้ให้ใหม่แล้ว
แต่ไม่รู้ว่าจะเพียงพอหรือเปล่า ถ้าไม่พอถามเพิ่มได้ค่ะ
ขอบคุณค่ะ

จากที่อธิบายมาใหม่ สามารถเข้าใจได้ง่ายขึ้นอย่างเห็นได้ชัดครับ

ที่ชีท Glassware ลองตามนี้ครับ

1. เซลล์ C3 คีย์สูตรเพื่อนับรายการเฉพาะที่ไม่ซ้ำ
   =SUM(IF(FREQUENCY(IF(ISNUMBER(Plan!$G$8:$G$257),MATCH(Plan!$C$8:$C$257,Plan!$C$8:$C$257,0)),ROW(Plan!$C$8:$C$257)-ROW(Plan!$C$8)+1),1))
   Ctrl+Shift+Enter คำตอบจะได้ 19 รายการ
2. เซลล์ A5 คีย์สูตรเพื่อ List รายการที่ไม่ซ้ำออกมาทั้งหมด
   =IF(ROWS(A$5:A5)>$C$3,"",INDEX(Plan!$C$8:$C$257,SMALL(IF(FREQUENCY(IF(ISNUMBER(Plan!$G$8:$G$257),MATCH(Plan!$C$8:$C$257,Plan!$C$8:$C$257,0)),ROW(Plan!$C$8:$C$257)-ROW(Plan!$C$8)+1),ROW(Plan!$C$8:$C$257)-ROW(Plan!$C$8)+1),ROWS(A$5:A5))))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
3. เซลล์ G5 คีย์สูตรเพื่อหายอดรวมของแต่ละรายการ
   =IF(A5<>"",SUMIF(Plan!$C$8:$C$257,A5,Plan!$G$8:$G$257),"")
   Enter > Copy ลงด้านล่าง

Note: Ctrl+Shift+Enter หมายถึงเมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl+Shift ค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะแสดงเครื่องหมายปีกกาครอบ ปีกกานี้คีย์เข้าไปเองไม่ได้ ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง

ขอบคุณมากๆ เลยค่ะ แม้จะไม่เข้าใจที่มาของสูตร แต่ทำดูแล้วได้ตามต้องการเลยค่ะ
แต่สงสัยเล็กน้อยค่ะ ตรงสูตร Match ทำไมต้องใส่ข้อมูลที่เหมือนกัน 2 ครั้งคะ

เป็นการใช้งานแบบ Array ครับ สังเกตได้ว่าปกติ Match จะเป็นการนำ เซลล์เดี่ยว ไป Match กับ ช่วงเซลล์ แต่จากสูตรนี้ เป็นการนำ ช่วงเซลล์ ไป Match กับ ช่วงเซลล์ การทำงานจึงมีลักษณะเป็น

นำค่าที่ 1 ในช่วงเซลล์แรก ไปหาว่าอยู่ในลำดับที่เท่าไรในช่วงเซลล์ที่ 2
นำค่าที่ 2 ในช่วงเซลล์แรก ไปหาว่าอยู่ในลำดับที่เท่าไรในช่วงเซลล์ที่ 2
นำค่าที่ 3 ในช่วงเซลล์แรก ไปหาว่าอยู่ในลำดับที่เท่าไรในช่วงเซลล์ที่ 2
...

ไปจนครบทุกค่าในช่วงเซลล์แรก

ค่ะ ขอบคุณนะคะ จะลองทำความเข้าใจอีกทีค่ะ