เทียบข้อมูล และแยกข้อมูล

[Xcelvba]

ในไฟล์ประกอบไปด้วย 3 ชีท
ชีท 1 คือ ชีท ออเดอร์ที่จัดส่งเสร็จแล้ว
ชีท 2 คือ ชีท ที่มีการโอนเงินสำเร็จแล้ว
ชีท 3 คือ ชีท เปรียบเทียบข้อมูล

(1) Column "หมายเลขการสั่งซื้อ" เทียบ (2) Column "Order ID"

--> ถ้าหมายเลขตรงกัน ให้แสดงข้อมูลใน (3) Column A:F
--> ถ้าไม่ตรง ให้แสดงข้อมูล (3) Column I:N

โดย ชีท (1) และ (2) จะมีการเพิ่มข้อมูลตลอดครับ สอบถามสูตรที่สามารถ เปรียบเทียบข้อมูล แล้วแยกไปยังชีท 3 ได้ครับ
(ข้อมูลมีมากกว่า 2000 แถวครับ)

[snasui]

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ A4 คีย์
   =XLOOKUP(B4,'2'!$B$2:$B$3,'2'!$A$2:$A$3,"")
   Enter > Copy ลงด้านล่าง
2. ที่ B4 คีย์
   =IFERROR(INDEX(FILTER('1'!$A$2:$E$4,ISNUMBER(MATCH('1'!$A$2:$A$4,'2'!$B$2:$B$3,0))),ROWS(B$4:B4),{1,2,5,3,4}),"")
   Enter > Copy ลงด้านล่าง
3. ที่ I4 คีย์
   =XLOOKUP(J4,'2'!$B$2:$B$3,'2'!$A$2:$A$3,"")
   Enter > Copy ลงด้านล่าง
4. ที่ J4 คีย์
   =IFERROR(INDEX(FILTER('1'!$A$2:$E$4,1-ISNUMBER(MATCH('1'!$A$2:$A$4,'2'!$B$2:$B$3,0))),ROWS(J$4:J4),{1,2,5,3,4}),"")
   Enter > Copy ลงด้านล่าง

[Xcelvba]

ขอบคุณครับ สอบถามเพิ่มเติมครับ
กรณี excel version เก่า ที่ไม่มี xlookup กับ filter สามารถใช้สูตรใดแทนบ้างครับ โดยที่ยังคำนวณเร็ว เมื่อข้อมูลมีมากกว่า 2,000 แถวครับ

[snasui]

ใช้ในรูปแบบด้านล่างได้สำหรับการเลือกข้อมูลตามเงื่อนไขครับ

=Iferror(Index(range,Aggregate(15,6,Row(range)/(Isnumber(Match(range,range,0)),Rows(range))),"")

กรณีเลือกข้อมูลตรงกันข้ามใช้ 1-Isnumber เข้าไปช่วยได้ ซึ่งรูปแบบนี้มีอยู่จำนวนมากในฟอรัมนี้ครับ

ส่วน Xlookup สามารถใช้ Index และ Match ใน Form ด้านล่างเข้ามาช่วยได้เช่นกันครับ

=Index(range,Match(range,range,0))

[Xcelvba]

ขอบคุณมากครับ อ.

=Iferror(Index(range,Aggregate(15,6,Row(range)/(Isnumber(Match(range,range,0)),Rows(range))),"")

สอบถามเพิ่มในลักษณะการประมวลผลครับ

ระหว่าง
=Iferror(Index(range,Aggregate(15,6,Row(range)/(1-Isnumber(Match(range,range,0)),Rows(range))),"")
กับ
=Iferror(Index(range,Aggregate(15,6,Row(range)/(Isna(Match(range,range,0)),Rows(range))),"")

แบบไหนประมวลผลได้รวดเร็วกว่ากันครับ

[snasui]

โดยหลักการ จำนวณทอดในการคำนวณน้อยกว่าจะทำงานเร็วกว่า

หากใช้ Isna จะมีจำนวนทอดที่คำนวณน้อยกว่าอยู่ 1 ขั้นตอนจึงน่าจะทำงานเร็วกว่า ส่วนการทำงานจริงจะเร็วกว่าแค่ไหน อย่างไร ต้องลองกับงานจริงครับ

[Xcelvba]

ขอบคุณอีกครั้งครับ