Snasui Excel Forum

Posted: **Tue May 11, 2021 11:00 pm**

รบกวนสอบถาม ว่าสามารถใช้ Function ใด ทำให้ ข้อมูลเบอร์มือถือ ที่มีหลายรูปแบบ จาก ช่อง C สามารถทำเป็นเบอร์มือถือ 10 หลัก แบบใน ช่อง E ได้ครับ และหากไม่มีเบอร์มือถือ 10 หลัก ให้เป็น "ช่องว่าง" หรือ ตัวอักษร ว่า "ไม่มีเบอร์มือถือ 10 หลัก" ครับ

Posted: **Wed May 12, 2021 7:50 am**

ตัวอย่างสูตรตามด้านล่างเป็นการใช้คอลัมน์ช่วยครับ

ที่ F2 คีย์สูตรเพื่อเปลี่ยนอักขระ -, " ", ), ( ที่ปะปนอยู่ในเบอร์โทรศัพท์ให้เป็นค่าว่าง
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(C2,"-","")," ",""),"(",""),")","")
Enter > Copy ลงด้านล่าง
ที่ G2 คีย์สูตรค้นหาตำแหน่งของตัวเลข 06, 08, 09
=MID(F2,MIN(SEARCH({"06","08","09"},F2&"060809")),10)
Enter > Copy ลงด้านล่าง
ที่ H2 คีย์สูตรเพื่อหาเลขโทรศัพท์ 10 หลัก
=IF(AND(LEN(G2)=10,ISNUMBER(G2+0)),G2,"")
Enter > Copy ลงด้านล่าง

Posted: **Wed May 12, 2021 6:05 pm**

ขอบคุณมากนะครับ คุณsnasui

Posted: **Sat May 22, 2021 11:15 am**

สืบเนื่องจากการสอบถาม การใช้ function ทำเบอร์มือถือที่มีหลากหลายแบบ ครับ ได้รับความกรุณาจากคุณ snasui
(ช่อง c เปลี่ยนอักขระ ช่อง d ค้นหาตำแหน่งของตัวเลข และช่อง e สูตรเพื่อหาเลขโทรศัพท์ 10 หลัก) แล้ว
แต่ ขอสอบถามเพิ่มเติมครับ เนืองจาก ยังมี ข้อมูลมือถือบางลำดับ ที่มี , ในเบอร์มือถือ (ช่องไฮไลท์ สีเหลือง)
เราสามารถใช้ function ใด แก้ไขได้ไหมครับ

ขอบคุณครับ

Posted: **Sat May 22, 2021 1:51 pm**

ตัวอย่างสูตรตามด้านล่างครับ

ที่ C2 คีย์
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(B2,"-","")," ",""),"(",""),")",""),",","|")
Enter > Copy ลงด้านล่าง
ที่ F2 คีย์
=IFERROR(LOOKUP(2,1/(LEN(MID(C2,ROW(INDIRECT("1:"&LEN(C2))),10))=10)/ISNUMBER(SEARCH(LEFT(MID(C2,ROW(INDIRECT("1:"&LEN(C2))),10),2),"060809"))/ISNUMBER(--MID(C2,ROW(INDIRECT("1:"&LEN(C2))),10)),MID(C2,ROW(INDIRECT("1:"&LEN(C2))),10)),"")
Enter > Copy ลงด้านล่าง

หากตรวจสอบแล้วว่าคอลัมน์ F ให้ผลลัพธ์ถูกต้อง สามารถลบคอลัมน์ C, D ทิ้งไปได้ครับ

Posted: **Sat May 22, 2021 3:11 pm**

ขอบคุณครับ