Snasui Excel Forum

รบกวนด้วยนะคะ จากไฟล์แนบ
1.จากรายงานSheet 1 อยากทำสูตรดึงข้อมูลให้แสดงออกมาแบบSheetนี้
2.ช่อง IN และช่อง OUT ให้Formatเป็นเวลา เพื่อทำให้รวมชั่วโมงการทำงานได้
3.11 วันมาจากวันที่มี IN, OUT ทั้งสองขา

ตัวอย่างสูตรครับ

ที่ Sheet1

1. เซลล์ AO13:AV13 คีย์ข้อความเพื่อเป็นหัวคอลัมน์ด้วย Code:, Name :, Type :, Shift :, Dept :, Sect :, Unit sect :, 0 ตามลำดับ
2. ที่ AO15 คีย์
   =IF(OR(COUNT(FIND("/",$B15)),$A15="Total"),LOOKUP(2,1/(A$13:A15=AO$13),C$13:C15),"")
   Enter > Copy ลงด้านล่าง
3. ที่ AP15 คีย์
   =IF(OR(COUNT(FIND("/",$B15)),$A15="Total"),LOOKUP(2,1/(F$13:F15=AP$13),J$13:J15),"")
   Enter > Copy ลงด้านล่าง
4. ที่ AQ15 คีย์
   =IF(OR(COUNT(FIND("/",$B15)),$A15="Total"),LOOKUP(2,1/(P$13:P15=AQ$13),T$13:T15&" "&U$13:U15),"")
   Enter > Copy ลงด้านล่าง
5. ที่ AR15 คีย์
   =IF(OR(COUNT(FIND("/",$B15)),$A15="Total"),LOOKUP(2,1/(Y$13:Y15=AR$13),AB$13:AB15),"")
   Enter > Copy ลงด้านล่าง
6. ที่ AS15 คีย์
   =IF(OR(COUNT(FIND("/",$B15)),$A15="Total"),LOOKUP(2,1/(A$13:A15=AS$13),C$13:C15),"")
   Enter > Copy ลงด้านล่าง
7. ที่ AT15 คีย์
   =IF(OR(COUNT(FIND("/",$B15)),$A15="Total"),LOOKUP(2,1/(I$13:I15=AT$13),L$13:L15&""),"")
   Enter > Copy ลงด้านล่าง
8. ที่ AU15 คีย์
   =IF(OR(COUNT(FIND("/",$B15)),$A15="Total"),LOOKUP(2,1/(Q$13:Q15=AU$13),T$13:T15&""),"")
   Enter > Copy ลงด้านล่าง
9. ที่ AV15 คีย์
   =IF(AS15<>"",LOOKUP(9.99999999999999E+307,$AV$13:AV14)+1,"")
   Enter > Copy ลงด้านล่าง
10. ที่ AW13 คีย์
    =LOOKUP(9.99999999999999E+307,AV:AV)
    Enter

ที่ชีต รายงานที่ต้องการ

1. ที่ A3 คีย์
   =IF(ROWS(A$3:A3)>Sheet1!$AW$13,"",LOOKUP(ROWS(A$3:A3),Sheet1!$AV:$AV,Sheet1!AO:AO))
   Enter > Copy ไปด้านขวาถึง G3 > Copy ลงด้านล่าง
2. ที่ H3 คีย์
   =IF(ROWS(A$3:A3)>Sheet1!$AW$13,"",LOOKUP(ROWS(H$3:H3),Sheet1!$AV:$AV,Sheet1!A:A))
   Enter > Copy ลงด้านล่าง > ปรับใช้กับคอลัมน์ด้านขวาที่เหลือโดยเปลี่ยนช่วงเซลล์ที่ระบายสีให้เป็นช่วงเซลล์ต้นทางที่ต้องการนำมาแสดงผล

ขอบคุณมากนะคะ

ดีใจมากๆทีได้เห็นการตอบกลับ เดี๋ยวกลับไปลองทำค่ะ