Snasui Excel Forum

ต้องการดึงข้อมูรหัสจากคอลัมน์ B3 มาวางที่ C2
และคอลัมน์ B4 มาวางที่ D2
ตามลำดับ มีวิธีไหนที่ทำได้รวดเร็วกว่าการคัดลอกและวางแบบสลับคอลัมน์บ้างครับ
เนื่องจากข้อมูลมีจำนวนมาก

copy > paste special > transpose

ขอบพระคุณครับ มีวิธีอื่นอีกไหมครั เนืองจากข้อมูลมีจำนวนมาก จะ copy > paste special > transpose หมดนานมากครับ

ตัวอย่างสูตรครับ

เซลล์ C2 คีย์

=IFERROR(INDEX($B$2:$B$13,2*(ROWS(C$2:C2)-1)+COLUMNS($C2:C2)),"")

Enter > Copy ไป D2 แล้ว Copy ลงด้านล่าง

ขอบพระคุณมากๆเลยครับ ผม copy > paste special > transpose มานานมากๆ

รบกวนอีกครั้งครับอาจารย์ เนื่องจากใส่สูตร =IFERROR(INDEX($B$2:$B$13,2*(ROWS(C$2:C2)-1)+COLUMNS($C2:C2)),"") แล้วไม่เรียงตามที่ต้องการครับ เลยแนบรูปเพื่ออธิบายประกอบครับ จุดประสงค์ของงานนี้คือจัดฟอร์มเพื่อพิมพ์ใบประกาศ ผมเลยสร้างฟอร์มเพื่อพิมพ์จดหมายเวียนใน Microsoft Word ครับ หากมีคำแนะนำอื่นที่จะทำให้งานเสร็จรวดเร็วกว่าวิธีนี้โปรดชี้แนะได้เลยครับ

เข้าใจว่าเริ่มเรียงจาก B3

ปรับ index เป็นแบบนี้ครับ =IFERROR(INDEX($B$3:$B$13 ที่เหลือจากนั้นก็เหมือนเดิม

F2:Ixxx
=INDEX($A$2:$B$999,ROWS(F$2:F2)*3-MOD(4-COLUMNS($F2:F2),3),1+(COLUMNS($F2:F2)>1))&""

ขอบพระคุณมากๆครับทุกท่าน ได้ตามความต้องการแล้วครับ

รบกวนอธิบายสูตรช่วง ROWS(F$2:F2)*3-MOD(4-COLUMNS($F2:F2),3),1+(COLUMNS($F2:F2)>1))&"" ได้ไหมครับ พยายามแกะแล้ว มึนมากครับจะเอาไปปรับใช้กับข้อมูลชุดอื่นๆครับ ขอบพระคุณครับ

ROWS(F$2:F2)*3 row เพิ่มขึ้น 1 ค่าเพิ่มขึ้น 3 เพราะข้อมูลมีชุดละ 3 แถว
ลบด้วย
MOD(4-COLUMNS($F2:F2),3) Mod( ,3) จะได้เลข 0,1,2 ไปเรื่อยๆ
เอา 4 ตั้งเพื่อให้เริมจาก 0,2,1,0 เมื่อเปลี่ยน column
3-0 = 3 คือเอา A ตัวที่ 3
3-2 = 1 คือเอา A ตัวที่ 1
3-1 = 2 คือเอา A ตัวที่ 2

ด้านบนคือเลข Row ของ Index

1+(COLUMNS($F2:F2)>1)
ได้ 1 ที่ column F
ได้ 2 ที่ Column G:I
ใช้เป็นเลข column ของ Index


&"" ให้ค่าว่างแสดงเป็น text ว่าง
ถ้าไม่ใส่เห็นเลข 0

ขอบพระคุณมากๆครับ อธิบายละเอียดมากๆ

ขออนุญาตถามเพิ่มครับ เนื่องจากข้อมูลจริง มีจำนวน column เพิ่มแล้วจะปรับสูตรตาม อ่านคำอธิบายแล้วแต่ก็ไม่ได้ผลครับ

Upload file

ข้อมูลที่ต้องการดึงคือที่ใส่สีไว้ครับ ขอถามเผื่อว่าถ้ามีชื่อซ้ำกันเป็น 4 หรือ 5 หรือ 6 จะปรับสูตรตรงไหนด้วยครับ ขอบพระคุณครับ

AG2:AKxx
=IFERROR(INDEX($K:$K,TEXT(AGGREGATE(15,6,ROW($A$2:$A$99)/($A$1:$A$98<>$A$2:$A$99),ROWS(AG$2:AG2))-1+COLUMNS($AG2:AG2),"[<"&AGGREGATE(15,6,ROW($A$2:$A$99)/($A$1:$A$98<>$A$2:$A$99),ROWS(AG$2:AG2)+1)&"]0;")),"")

AM2:AQxx
=IFERROR(INDEX($P:$P,TEXT(AGGREGATE(15,6,ROW($N$2:$N$99)/($N$1:$N$98<>$N$2:$N$99),ROWS(AM$2:AM2))-1+COLUMNS($AM2:AM2),"[<"&AGGREGATE(15,6,ROW($N$2:$N$99)/($N$1:$N$98<>$N$2:$N$99),ROWS(AM$2:AM2)+1)&"]0;")),"")

อยากทราบว่า กรณีใช้ร่วมกับสูตร Vlookup ต้องทำอย่างไรครับ

ตัวอย่างสูตรครับ

เซลล์ B2 คีย์

=IFERROR(INDEX(database!$C:$C,AGGREGATE(15,6,ROW(database!$A$2:$A$166)/(database!$A$2:$A$166=$A2),COLUMNS($B2:B2))),"")

Enter > Copy ไปด้านขวาและลงด้านล่าง