Page 1 of 1
ขอความช่วยเหลือในการรวมสูตร
Posted: Mon Oct 28, 2019 8:45 am
by phoopha13
ขอความช่วยเหลือท่านอาจารย์ทุกท่านและท่านผู้รู้ เนื่องจากผมมีข้อมูล และทำสูตรแล้ว แต่ติดที่ว่าไม่สามารถรวมสูตรให้รวบรัดได้ และทำให้การคำนวณช้าไป จึงขอท่านอาจารย์ช่วยแนะนำ ชี้แนะด้วยครับ
Re: ขอความช่วยเหลือในการรวมสูตร
Posted: Mon Oct 28, 2019 8:48 am
by phoopha13
ตค62_241062_ลองสูตรหาdx_new.xlsx
Re: ขอความช่วยเหลือในการรวมสูตร
Posted: Mon Oct 28, 2019 11:51 am
by Bo_ry
B20
=IF(ROWS(B$20:B20)>$A$21,"",INDEX($A$2:$A$18,SMALL(IF(FREQUENCY(IF($E$2:$E$18=$A$20,$A$2:$A$18),$A$2:$A$18),ROW($A$2:$A$18)),ROWS(B$20:B20))-ROW($A$1)))
Ctrl+Shift+Enter
C20:E20
=IF($B20="","",VLOOKUP($B20,$A$2:B$18,COLUMNS($A$1:B$1),0))
F20:H20
=IF($B20="","",LOOKUP(1,1/($B20=$A$2:$A$18)/($A$20=$E$2:$E$18),E$2:E$18))
A21
=COUNT(1/FREQUENCY(IF($E$2:$E$18=$A$20,$A$2:$A$18),$A$2:$A$18)) Ctrl+Shift+Enter
Re: ขอความช่วยเหลือในการรวมสูตร
Posted: Mon Oct 28, 2019 12:05 pm
by phoopha13
ขอบคุณท่านอ.Bo_ry ครับ ผมขอลองทำตามที่ท่านแนะนำดูก่อนนะครับ ว่าได้ตามต้องการหรือไม่ ขอบคุณครับ
Re: ขอความช่วยเหลือในการรวมสูตร
Posted: Mon Oct 28, 2019 12:50 pm
by puriwutpokin
อีกตัวอย่างที่ B20=IFERROR(INDEX(A$2:A$18,AGGREGATE(15,6,(ROW(A$2:A$18)-ROW(A$2)+1)/(E$2:E$18=A$20)/(FREQUENCY(MATCH(A$2:A$18,A$2:A$18,0),ROW(A$2:A$18)-ROW(A$2)+1)>0),ROWS(B$20:B20))),"") คัดลอกลงครับ
ที่ C20=IFERROR(INDEX(A$2:A$18,AGGREGATE(15,6,(ROW(A$2:A$18)-ROW(A$2)+1)/(E$2:E$18=A$20)/(FREQUENCY(MATCH(A$2:A$18,A$2:A$18,0),ROW(A$2:A$18)-ROW(A$2)+1)>0),ROWS(B$20:B20))),"") คัดลอกไปถึง H20 และคัดลอกลงครับ
Re: ขอความช่วยเหลือในการรวมสูตร
Posted: Mon Oct 28, 2019 3:05 pm
by phoopha13
ผมทดลองของท่านอ.Bo_ry และของท่านอ.puriwutpokin แล้ว ของท่านBo_ry ใช้ได้ดีครับ ของท่านอ.puriwutpokin ไม่แน่ใจว่าผมได้ทำผิดขั้นตอนไหนนะครับ ข้อมูลไม่ขึ้น เป็นค่าว่างครับ ขอท่านอ.puriwutpokin ช่วยแนะนำด้วยครับ ขอบคุณอ.ทั้ง 2 ท่านมากๆครับ
Re: ขอความช่วยเหลือในการรวมสูตร
Posted: Mon Oct 28, 2019 3:27 pm
by puriwutpokin
ใช้ Excel ต่ำกว่า 2010 ให้ใช้ที่ B20=IFERROR(INDEX(A$2:A$18,SMALL(IF(FREQUENCY(IF(E$2:E$18=A$20,A$2:A$18),A$2:A$18),ROW(A$2:A$18)-ROW(A$2)+1),ROWS(B$20:B20))),"")กด Ctrl+Shift+Enter คัดลอกลงครับ
Re: ขอความช่วยเหลือในการรวมสูตร
Posted: Mon Oct 28, 2019 3:35 pm
by phoopha13
แล้ว C20 ที่ท่านอาจารย์อ.puriwutpokinให้มาต้องเปลี่ยนสูตรด้วยหรือเปล่าครับ ขอบคุณครับ พอดีผมลองใส่สูตรตามที่ท่านอ.อ.puriwutpokin บอก ข้อมูลขึ้นมาแสดง แต่C20 ไม่ขึ้นครับ
Re: ขอความช่วยเหลือในการรวมสูตร
Posted: Mon Oct 28, 2019 3:52 pm
by puriwutpokin
phoopha13 wrote: Mon Oct 28, 2019 3:35 pm
แล้ว C20 ที่ท่านอาจารย์อ.puriwutpokinให้มาต้องเปลี่ยนสูตรด้วยหรือเปล่าครับ ขอบคุณครับ พอดีผมลองใส่สูตรตามที่ท่านอ.อ.puriwutpokin บอก ข้อมูลขึ้นมาแสดง แต่C20 ไม่ขึ้นครับ
ไม่ต้องครับ ใช้สูตรที่ตอนแรกให้ไปครับ C20=IFERROR(INDEX(B$2:B$18,MATCH($B20,$A$2:$A$18,0)),"")
Re: ขอความช่วยเหลือในการรวมสูตร
Posted: Mon Oct 28, 2019 3:54 pm
by phoopha13
ขอบคุณท่านอ.puriwutpokin และท่านอ.bo_ry ครับ