Page 1 of 1
รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sat May 25, 2019 11:18 pm
by golfgto2527
ในช่อง B2==INDEX('ICR HMBRI'!A:H,SMALL(IF('ICR HMBRI'!A:H=D3,ROW('ICR HMBRI'!A:H)),ROW(1:1)),2)
ต้องการจะหาเงื่อนไขเพิ่มเข้าไปโดยอีกเงื่อนไขอยู่ที่ช่อง A2 ครับ
รบกวนด้วยนะครับ
ขอบคุณครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 5:51 am
by puriwutpokin
ควรแนบไฟล์ตัวอย่างมาดุ้วยครับ จะได้เข้าใจตรงกันครับว่าเงื่อนไขมาจากชีทไหน
แล้วคำตอบนั้นคืออะไร ลองอธิบายพร้อมไฟล์แนบมาดูครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 10:03 am
by golfgto2527
ครับ รบกวนด้วยนะครับ ขอบคุณครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 10:13 am
by snasui
ตัวอย่างสูตรครับ
=LOOKUP(2,1/((OrderID!$G$2:$G$17=$D3)*(OrderID!$A$2:$A$17=$A3)*(OrderID!$E$2:$E$17=$E$1)),OrderID!$B$2:$B$17)
Enter
กรณีไม่ได้คำตอบ กรุณาระบุคำตอบที่ถูกต้องพร้อมทั้งชี้ให้เห็นว่าค่านั้นได้มาจากเซลล์ไหน คิดอย่างไรจึงได้ค่าเท่านั้น จะได้สะดวกในการทำความเข้าใจครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 11:05 am
by golfgto2527
คำตอบ คือ OrderID ทั้งหมด ของ วันที่ 25-05-2019 ของ LM1 ของคนชื่อ ยศพนธ์ วงค์สมัน
ค่า OrderID มาจาก Sheet OrderID Colum B ครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 12:12 pm
by snasui
ตัวอย่างการปรับสูตรครับ
=IFERROR(INDEX(OrderID!$B$2:$B$17,SMALL(IF(OrderID!$G$2:$G$17=$D$3,IF(OrderID!$A$2:$A$17=$A$3,IF(OrderID!$E$2:$E$17=$E$1,ROW(OrderID!$A$2:$A$17)-ROW(OrderID!$A$2)+1))),ROWS(E$7:E7))),"")
Ctrl+Shift+Enter > Copy ลงด้านล่าง
ควรคีย์คำตอบที่ต้องการด้วยมือลงในเซลล์เป้าหมายแล้วแนบไฟล์นั้นมาด้วยจะได้คำนวณเปรียบเทียบได้
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 12:22 pm
by puriwutpokin
ที่e7=IFERROR(INDEX(OrderID!$B$2:$B$17,AGGREGATE(15,6,(ROW(G$2:$G$17)-ROW(G$2)+1)/((OrderID!$G$2:$G$17=$D$3)*(OrderID!$A$2:$A$17=$A$3)*(OrderID!$E$2:$E$17=$E$1)),ROWS(E$7:E7))),"")
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 2:00 pm
by golfgto2527
snasui wrote: Sun May 26, 2019 12:12 pm
ตัวอย่างการปรับสูตรครับ
=IFERROR(INDEX(OrderID!$B$2:$B$17,SMALL(IF(OrderID!$G$2:$G$17=$D$3,IF(OrderID!$A$2:$A$17=$A$3,IF(OrderID!$E$2:$E$17=$E$1,ROW(OrderID!$A$2:$A$17)-ROW(OrderID!$A$2)+1))),ROWS(E$7:E7))),"")
Ctrl+Shift+Enter > Copy ลงด้านล่าง
ควรคีย์คำตอบที่ต้องการด้วยมือลงในเซลล์เป้าหมายแล้วแนบไฟล์นั้นมาด้วยจะได้คำนวณเปรียบเทียบได้
ได้แล้วครับ ขอบคุณมากครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 2:00 pm
by golfgto2527
puriwutpokin wrote: Sun May 26, 2019 12:22 pm
ที่e7=IFERROR(INDEX(OrderID!$B$2:$B$17,AGGREGATE(15,6,(ROW(G$2:$G$17)-ROW(G$2)+1)/((OrderID!$G$2:$G$17=$D$3)*(OrderID!$A$2:$A$17=$A$3)*(OrderID!$E$2:$E$17=$E$1)),ROWS(E$7:E7))),"")
ขอบคุณมากครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 2:17 pm
by golfgto2527
snasui wrote: Sun May 26, 2019 12:12 pm
ตัวอย่างการปรับสูตรครับ
=IFERROR(INDEX(OrderID!$B$2:$B$17,SMALL(IF(OrderID!$G$2:$G$17=$D$3,IF(OrderID!$A$2:$A$17=$A$3,IF(OrderID!$E$2:$E$17=$E$1,ROW(OrderID!$A$2:$A$17)-ROW(OrderID!$A$2)+1))),ROWS(E$7:E7))),"")
Ctrl+Shift+Enter > Copy ลงด้านล่าง
ควรคีย์คำตอบที่ต้องการด้วยมือลงในเซลล์เป้าหมายแล้วแนบไฟล์นั้นมาด้วยจะได้คำนวณเปรียบเทียบได้
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 5:37 pm
by golfgto2527
snasui wrote: Sun May 26, 2019 12:12 pm
ตัวอย่างการปรับสูตรครับ
=IFERROR(INDEX(OrderID!$B$2:$B$17,SMALL(IF(OrderID!$G$2:$G$17=$D$3,IF(OrderID!$A$2:$A$17=$A$3,IF(OrderID!$E$2:$E$17=$E$1,ROW(OrderID!$A$2:$A$17)-ROW(OrderID!$A$2)+1))),ROWS(E$7:E7))),"")
Ctrl+Shift+Enter > Copy ลงด้านล่าง
ควรคีย์คำตอบที่ต้องการด้วยมือลงในเซลล์เป้าหมายแล้วแนบไฟล์นั้นมาด้วยจะได้คำนวณเปรียบเทียบได้
รบกวนสอบถามอีกหน่อยครับ แล้วถ้าเราจะเพิ่มSheet เป็น อีกSheet ชื่อ OrderID2 แล้วเราจะต้องแก้ไขสูตรยังไงครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Sun May 26, 2019 8:14 pm
by puriwutpokin
กด ctrl+h แล้ว ช่องบนใส่ OrderID
แล้วช่องล่างใส่ OrderID2 แล้วreplace all ครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Mon May 27, 2019 7:42 am
by golfgto2527
puriwutpokin wrote: Sun May 26, 2019 8:14 pm
กด ctrl+h แล้ว ช่องบนใส่ OrderID
แล้วช่องล่างใส่ OrderID2 แล้วreplace all ครับ
ไม่ใช้แบบนั้นครับ คือต้องการเพิ่มอีก Sheet เข้าไปในสูตรเลยครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Mon May 27, 2019 10:39 am
by puriwutpokin
golfgto2527 wrote: Mon May 27, 2019 7:42 am
puriwutpokin wrote: Sun May 26, 2019 8:14 pm
กด ctrl+h แล้ว ช่องบนใส่ OrderID
แล้วช่องล่างใส่ OrderID2 แล้วreplace all ครับ
ไม่ใช้แบบนั้นครับ คือต้องการเพิ่มอีก Sheet เข้าไปในสูตรเลยครับ
เพิ่มชีทในความหมายนี้คือเป็น 2 ชีทหรือครับถ้าใช่ ต้องเปลี่ยนสูตรครับ แนบไฟล์ตัวอย่างมาดูครับว่าเป็นแบบไหนครับ สูตรนั้นใช้ได้ 1 ชีทครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Mon May 27, 2019 12:44 pm
by golfgto2527
puriwutpokin wrote: Mon May 27, 2019 10:39 am
golfgto2527 wrote: Mon May 27, 2019 7:42 am
puriwutpokin wrote: Sun May 26, 2019 8:14 pm
กด ctrl+h แล้ว ช่องบนใส่ OrderID
แล้วช่องล่างใส่ OrderID2 แล้วreplace all ครับ
ไม่ใช้แบบนั้นครับ คือต้องการเพิ่มอีก Sheet เข้าไปในสูตรเลยครับ
เพิ่มชีทในความหมายนี้คือเป็น 2 ชีทหรือครับถ้าใช่ ต้องเปลี่ยนสูตรครับ แนบไฟล์ตัวอย่างมาดูครับว่าเป็นแบบไหนครับ สูตรนั้นใช้ได้ 1 ชีทครับ
แนบให้แล้วครับ รบกวนด้วยครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Mon May 27, 2019 1:53 pm
by puriwutpokin
golfgto2527 wrote: Mon May 27, 2019 12:44 pm
puriwutpokin wrote: Mon May 27, 2019 10:39 am
golfgto2527 wrote: Mon May 27, 2019 7:42 am
ไม่ใช้แบบนั้นครับ คือต้องการเพิ่มอีก Sheet เข้าไปในสูตรเลยครับ
เพิ่มชีทในความหมายนี้คือเป็น 2 ชีทหรือครับถ้าใช่ ต้องเปลี่ยนสูตรครับ แนบไฟล์ตัวอย่างมาดูครับว่าเป็นแบบไหนครับ สูตรนั้นใช้ได้ 1 ชีทครับ
แนบให้แล้วครับ รบกวนด้วยครับ
ยังไม่เข้าใจครับ เพราะจากสูตรเดิม ก็ได้คำตอบ ตามที่แสดงไว้อยู่แล้ว จริงๆ คำตอบต้องมีมากกว่าที่แสดงมาหรือเปล่าครับ
ลองชี้แจ้ง ให้ชัดหรือแสดงคำตอบที่ ต้องการจากเงื่อนไขใหม่ด้วยครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Mon May 27, 2019 7:13 pm
by golfgto2527
คือคำตอบอันแรกคือ หาจาก Sheet OrderID แต่ผมจะเพิ่ม Sheet OrderID2 เข้าไป เพื่อหาค่าใน Sheet OrderID2 ด้วยครับ
แต่จะใช้ช่องเติมตำแหร่งเดิมในการหา ใน Sheet OrderID2 ครับ
Re: รบกวนสอบถามต้องการหาแบบหลายเงื่อนไข
Posted: Mon May 27, 2019 8:40 pm
by puriwutpokin
ถ้าเป็นการหาค่าจากหลายชีท มารวมต่อกันให้ทำตามนี้ครับ
1.ที่ I7:I8 คีย์ชื่อชีท OrderID,OrderID2
2.ที่ J7=IFERROR(SUMPRODUCT(--(INDIRECT(I7&"!G2:G17")=D$3),--(INDIRECT(I7&"!A2:A17")=A$3),--(INDIRECT(I7&"!E2:E17")=E$1)),"") คัดลอกลงมาถึง J15
3.ที่ J16=SUM(J7:J15)
4.ที่ K7=IFERROR(SUM(J$7:J7)-J7+1,"") คัดลอกลงมาถึง K15
5.ที่ H7=IF(ROWS(H$7:H7)>J$16,"",LOOKUP(ROWS(H$7:H7),K$7:K$15,I$7:I$15)) คัดลอกลงมาถึง H15
6.ที่ E7=IFERROR(INDEX(INDIRECT($H7&"!$B$2:$B$17"),AGGREGATE(15,6,(ROW(G$2:$G$17)-ROW(G$2)+1)/((INDIRECT($H7&"!$G$2:$G$17")=$D$3)*(INDIRECT($H7&"!$A$2:$A$17")=$A$3)*(INDIRECT($H7&"!$E$2:$E$17")=$E$1)),COUNTIF(H$7:H7,H7))),"") คัดลอกลงจนเป็นค่าว่างครับ ทั้งหมดนี้จะหาจากชีทเพิ่มจาก 2 ชีทได้ครับแค่เพิ่มชื่อชีทต่อไปที่ I8 ครับ