Page 1 of 1
รบกวนขอสูตรที่ช่วยจับข้อความที่เป็นตัวย่อ ให้แสดงข้อความเต็มค่ะ
Posted: Fri May 03, 2019 8:39 am
by rachada77
ต้องการให้จับตัวอย่าง ในคอลัมภ์แรก และแสดงผลเป็นชื่อเต็มในอีกคอมลัมภ์นึงค่ะ
รบกวนหน่อยนะคะ
Re: รบกวนขอสูตรที่ช่วยจับข้อความที่เป็นตัวย่อ ให้แสดงข้อความเต็มค่ะ
Posted: Fri May 03, 2019 8:48 am
by Supachok
G4
=LOOKUP("z",(IF(LEFT(C4,2)=LEFT($C$14:$C$16,2),MID($C$14:$C$16,4,222))))
Array formula {}
copy down
Re: รบกวนขอสูตรที่ช่วยจับข้อความที่เป็นตัวย่อ ให้แสดงข้อความเต็มค่ะ
Posted: Fri May 03, 2019 9:12 am
by rachada77
Supachok wrote: Fri May 03, 2019 8:48 am
G4
=LOOKUP("z",(IF(LEFT(C4,2)=LEFT($C$14:$C$16,2),MID($C$14:$C$16,4,222))))
Array formula {}
copy down
ลองแล้วขึ้น #VALUE! ไม่ทราบว่าต้องแก้ตรงไหนคะ
Re: รบกวนขอสูตรที่ช่วยจับข้อความที่เป็นตัวย่อ ให้แสดงข้อความเต็มค่ะ
Posted: Fri May 03, 2019 10:04 am
by parakorn
rachada77 wrote: Fri May 03, 2019 9:12 am
Supachok wrote: Fri May 03, 2019 8:48 am
G4
=LOOKUP("z",(IF(LEFT(C4,2)=LEFT($C$14:$C$16,2),MID($C$14:$C$16,4,222))))
Array formula {}
copy down
ลองแล้วขึ้น #VALUE! ไม่ทราบว่าต้องแก้ตรงไหนคะ
Array Formulas ต้องกด Ctrl+Shift+Enter ครับ
Re: รบกวนขอสูตรที่ช่วยจับข้อความที่เป็นตัวย่อ ให้แสดงข้อความเต็มค่ะ
Posted: Fri May 03, 2019 5:03 pm
by Bo_ry
อีกแบบ
F4
=MID(LOOKUP(1,FIND(LEFT(C4,2),$C$14:$C$16),$C$14:$C$16),4,20)
Re: รบกวนขอสูตรที่ช่วยจับข้อความที่เป็นตัวย่อ ให้แสดงข้อความเต็มค่ะ
Posted: Fri May 03, 2019 8:04 pm
by puriwutpokin
อีกแบบครับที่
F4=MID(VLOOKUP(LEFT(C4,2)&"*",$C$14:$C$16,1,),4,99) คัดลอกลงครับ
Re: รบกวนขอสูตรที่ช่วยจับข้อความที่เป็นตัวย่อ ให้แสดงข้อความเต็มค่ะ
Posted: Wed May 15, 2019 11:47 pm
by phumiphach
ในกรณีที่มี 3 ชื่ออยู่ในแถวเดียวกัน ตัวอย่างเช่น ML4485,LL5244,BS9632 ผลลัพธ์ออกมาจะต้องเป็น Michelin,LINGLONG,Bridgestone ควรใช้สูตรไหนครับ ขอบคุณครับ
Re: รบกวนขอสูตรที่ช่วยจับข้อความที่เป็นตัวย่อ ให้แสดงข้อความเต็มค่ะ
Posted: Thu May 16, 2019 5:00 am
by snasui
ใน O365 สามารถใช้ TextJoin มาช่วยได้ตามด้านล่างครับ
สมมุติว่า C3 คือค่า ML4485,LL5244,BS9632
=TEXTJOIN(",",TRUE,INDEX(MID($C$14:$C$16,4,20),MATCH(LEFT(TRIM(MID(SUBSTITUTE(C3,",",REPT(" ",20)),20*(ROW(INDIRECT("1:"&LEN(C3)-LEN(SUBSTITUTE(C3,",",""))+1))-1)+1,20)),2)&"*",$C$14:$C$16,0)))
Enter
ส่วน Version ต่ำกว่านี้คงต้องอาศัย VBA มาช่วยซึ่งต้องเขียนมาเองก่อน ติดแล้วค่อยถามกันต่อ หรือหากใช้สูตรก็ต้องใช้คอลัมน์ช่วยเพื่อกระจายค่าออกเป็นหลายเซลล์แล้วค่อยนำมาเชื่อมกันใหม่ครับ
Re: รบกวนขอสูตรที่ช่วยจับข้อความที่เป็นตัวย่อ ให้แสดงข้อความเต็มค่ะ
Posted: Thu May 16, 2019 11:13 am
by phumiphach
อาจารย์ครับผมใส่สูตรตามอาจารย์แล้วมันยังไม่ขึ้นอะครับ ไม่ทราบว่ามันผิดพลาดตรงไหนเหมือนกันครับ
Re: รบกวนขอสูตรที่ช่วยจับข้อความที่เป็นตัวย่อ ให้แสดงข้อความเต็มค่ะ
Posted: Thu May 16, 2019 11:53 am
by snasui
สูตรนั้นใช้กับ Excel ใน Office 365 ครับ