Snasui Excel Forum

เรียนอาจารย์ทุกท่าน

ต้องการเรียงข้อมูลใหม่ และหาผมรวมของ ITEM ครับ
ตัวอย่าง ต้องใช้สูตรอย่างไรครับ

แบบไม่เรียง
L3:N3 copy ลง
=INDEX(B:B,AGGREGATE(15,6,ROW($C$3:$C$18)/(FREQUENCY(MATCH($B$3:$B$18&$C$3:$C$18&$D$3:$D$18,$B$3:$B$18&$C$3:$C$18&$D$3:$D$18,),ROW($C$1:$C$18))>0),ROWS(L$3:L3)))

O3
=SUMIFS($E:$E,$D:$D,N3,$C:$C,M3,$B:$B,L3)

แบบเรียง ITEM > QLT ยาวมาก ขอ column ช่วย
F3
=SUMIFS($E:$E,$D:$D,D3,$C:$C,C3,$B:$B,B3)

V3:X3
=INDEX(B$3:B$18,MATCH(AGGREGATE(15,6,(COUNTIF($B$3:$B$18,"<"&$B$3:$B$18)*10^9+ROW($C$3:$C$18)/10^5-$F$3:$F$18)/(FREQUENCY(MATCH($B$3:$B$18&$C$3:$C$18&$D$3:$D$18,$B$3:$B$18&$C$3:$C$18&$D$3:$D$18,),ROW($C$1:$C$18))>0),ROWS(V$3:V3)),INDEX(COUNTIF($B$3:$B$18,"<"&$B$3:$B$18)*10^9+ROW($C$3:$C$18)/10^5-$F$3:$F$18,),))

liveday wrote: Fri Dec 21, 2018 4:56 pm เรียนอาจารย์ทุกท่าน

ต้องการเรียงข้อมูลใหม่ และหาผมรวมของ ITEM ครับ
ตัวอย่าง

Code: Select all

						        ตัวอย่างผลลัพท์			
No.	ITEM	PA	COLOR	QLT.		ITEM	PA	COLOR	QLT.
1	A-001	1 S	BBBB	1		A-001	2 S	BBBB	3
2	A-001	1 S	CCCC	1		A-001	1 S	BBBB	1
3	A-001	2 S	BBBB	1		A-001	3 S	AAAA	1
4	A-001	4 S	DDDD	1		A-001	1 S	CCCC	1
5	A-001	3 S	AAAA	1		A-001	4 S	DDDD	1
6	A-001	2 S	BBBB	1		A-001	5 S	EEEE	        1
7	A-001	2 S	BBBB	1					
8	A-001	5 S	EEEE	        1					

ต้องใช้สูตรอย่างไรครับ

มีหลักการเรียงอย่างไรกรุณาอธิบายมาใหม่ให้ละเอียด เพื่อน ๆ จะได้เข้าใจด้วยครับ

เรียนอาจารย์
ผมต้องการหาผลรวมจำนวนของสินค้าครับ ซึ่งจะมีรายละเอียดแยกข้อมูลออกมาตั้งแต่ A5 - F5 ซึ่งจะเป็น 1 รายการ
แล้วนำไปรวมใหม่ที่ J5 - N5 แล้วให้เเสดงผมรวมจำนวนที่ O5 ครับ ดังตัวอย่างไฟล์แนบและผลลัพท์ที่ได้ J5 - N5 และ O5 ครับ

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ H5 คีย์
   =B5&C5&D5&E5&F5
   Enter > Copy ลงด้านล่าง
2. ที่ J5 คีย์
   =IFERROR(INDEX(B$5:B$30,SMALL(IF(FREQUENCY(MATCH($H$5:$H$30,$H$5:$H$30,0),ROW($H$5:$H$30)-ROW($H$5)+1),ROW($H$5:$H$30)-ROW($H$5)+1),ROWS(I$5:I5))),"")
   Ctrl+Shift+Enter > Copy ไปด้านขวาถึง N5 > Copy ลงด้านล่าง
3. ที่ O5 คีย์
   =IF(J5="","",SUMPRODUCT($G$5:$G$30,--($B$5:$B$30=J5),--($C$5:$C$30=K5),--($D$5:$D$30=L5),--($E$5:$E$30=M5),--($F$5:$F$30=N5)))
   Enter > Copy ลงด้านล่าง

!

Note: Ctrl+Shift+Enter เป็นการสร้างสูตร Array โดยสามารถเลือกดำเนินการตามข้อ 1 หรือ 2 ด้านล่าง กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน จากนั้นกดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วตามด้วย Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้ไม่สามารถคีย์เข้าไปเอง จะต้องมาด้วยการกดแป้น Ctrl+Shift+Enter เท่านั้น ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง