Excel Forum

เรียนสมาชิกทุกท่าน
สอบถามการสร้าง Drop-Down List หลายเงื่อนไข
ผมสร้าง drop-down list มา4ตัวครับ ระหว่าง C3:C6
ถ้าเซลล์ C3 เลือกคำว่าองุ่น แล้วเซลล์ C4:C6 จะไม่มีคำว่าองุ่นให้เลือก
หรือเซลล์ C6 เลือกคำว่าส้ม แล้วเซลล์ C5:C3 จะไม่มีคำว่าส้มให้เลือก
ประมาณว่าหากเลือกชื่อผลไม้ใดไปแล้ว เซลล์ที่เหลือจะไม่สามารถเลือกชื่อผลไม้นั้นซ้ำกันได้ครับ
พอจะมีวิธีไหมครับ

ขอบคุณครับ

หากไม่ได้เลือกตามลำดับ เช่นเลือก C6 ก่อนเลือกค่าเป็น ส้ม ไปแล้ว C3 จะเลือก ส้ม อีกไม่ได้ ใช่หรือไม่ครับ

หากใช่จะเป็นการตรวจสอบร่วมกันทั้งหมดทุกเซลล์ งานลักษณะนี้ต้องอาศัย VBA ครับ

M12 ใส่สูตร ลากลงถึง M24
=IFERROR(INDEX($L$12:$L$24,AGGREGATE(15,6,(ROW($L$12:$L$24)-ROW($L$11))/NOT(COUNTIF($C$3:$C$15,$L$12:$L$24)),ROWS(M$12:M12))),"")

เลือก C3:C15 กด Alt A V V เลือก List ใส่สูตร
=OFFSET($M$12,,,ROWS($M$12:$M$24)-COUNTBLANK($M$12:$M$24))

snasui wrote: Wed Sep 05, 2018 9:03 pm หากไม่ได้เลือกตามลำดับ เช่นเลือก C6 ก่อนเลือกค่าเป็น ส้ม ไปแล้ว C3 จะเลือก ส้ม อีกไม่ได้ ใช่หรือไม่ครับ

ใช่ครับ แต่ขอสูตรแบบเลือกตามลำดับก็ได้ครับ เช่นเลือกC3ก่อน แล้วค่อยเลือกC4 C5 C6 ตามลำดับ

snasui wrote: Wed Sep 05, 2018 9:03 pm หากใช่จะเป็นการตรวจสอบร่วมกันทั้งหมดทุกเซลล์ งานลักษณะนี้ต้องอาศัย VBA ครับ

หากเลือกตามลำดับ จำเป็นต้องใช้ VBA ไหมครับ

ตัวอย่างสูตรตามด้านล่างครับ

1. เซลล์ J4:J4 เขียนหัวคอลัมน์เป็น การใช้งาน1-การใช้งาน4 เพื่อเป็นหัวคอลัมน์
2. เซลล์ G4:G16 ให้ลอก List เดิมมาวาง
3. ที่ H4 คีย์
   =IFERROR(INDEX($G$4:$G$16,SMALL(IF(ISNA(MATCH($G$4:$G$16,OFFSET($C$3,0,0,COLUMNS($H4:H$4)),0)),ROW($G$4:$G$16)-ROW($G$4)+1),ROWS(H$4:H4))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง > คัดลอกไปด้านขวา
4. C3:C6 ใช้ Data Validation ด้วย List แยกคอลัมน์ของใครของมันที่ได้จากสูตรในข้อ 3

Bo_ry wrote: Wed Sep 05, 2018 9:12 pm M12 ใส่สูตร ลากลงถึง M24
=IFERROR(INDEX($L$12:$L$24,AGGREGATE(15,6,(ROW($L$12:$L$24)-ROW($L$11))/NOT(COUNTIF($C$3:$C$15,$L$12:$L$24)),ROWS(M$12:M12))),"")

เลือก C3:C15 กด Alt A V V เลือก List ใส่สูตร
=OFFSET($M$12,,,ROWS($M$12:$M$24)-COUNTBLANK($M$12:$M$24))

ใช้แบบนี้ได้เลยครับ ผมคิดเยอะไปนิด

snasui wrote: Wed Sep 05, 2018 11:16 pm

Bo_ry wrote: Wed Sep 05, 2018 9:12 pm M12 ใส่สูตร ลากลงถึง M24
=IFERROR(INDEX($L$12:$L$24,AGGREGATE(15,6,(ROW($L$12:$L$24)-ROW($L$11))/NOT(COUNTIF($C$3:$C$15,$L$12:$L$24)),ROWS(M$12:M12))),"")

เลือก C3:C15 กด Alt A V V เลือก List ใส่สูตร
=OFFSET($M$12,,,ROWS($M$12:$M$24)-COUNTBLANK($M$12:$M$24))

ใช้แบบนี้ได้เลยครับ ผมคิดเยอะไปนิด

ตอนนี้ผมใช้ของคุณ Bo_ry อยู่ครับ ได้ตามที่ต้องการเลยครับ และเดี๋ยวจะขอลองของอาจารย์ด้วยครับ
ขอบคุณทั้ง2ท่านครับ