Snasui Excel Forum

รบกวนสอบถามครับ ต้องการดึงข้อมูลจากคอลัมน์ A B C มาเรียงต่อกันใน คอลัมน์ D โดยตัดข้อมูลที่ซ้ำกันออก รายละเอียดตามตัวอย่างครับ
ขอบคุณครับ

กรุณา Update Profile โดยระบุ Version ของ Excel ที่ใช้อยู่จริงตาม Link นี้ด้วยครับ viewtopic.php?t=17480

ตัวอย่างสูตร Version O365 ครับ

เซลล์ F2 คีย์

UNIQUE(TOCOL(A2:C9,1))

Enter

Update Profile เรียบร้อยครับ
สอบถามเพิ่มเติมครับ ถ้า Excel 2010 สามารถใช้สูตรเดียวกันได้ใช่ไหมครับ

...

Excel 2010 ลองใช้คอลัมน์ มาช่วยครับ

E2 ( Helper)
=INDEX($A$2:$C$9,MOD(ROWS($A$2:A9),8)+1,INT(ROWS($A$2:A9)/8))

Copy ลงไป

D2
=IFERROR(AGGREGATE(15,6,$E$2:$E$99/(MATCH($E$2:$E$99,$E$2:$E$99,0)/($E$2:$E$99<>0)=ROW($E$2:$E$99)-ROW($E$2)+1),ROWS($D$2:D2)),"")

Copy ลงไป


**เพื่อนสมาชิก กรุณาช่วยกดโฆษณาหน้าเพจ เพื่อเป็นการสนับสนุนฟอรั่ม**

Norkaz

ขอบคุณทั้งสองท่านมากครับ

รบกวนสอบถามครับ ถ้าข้อมูลที่ต้องการดึงมาเป็นข้อความไม่ใช่ตัวเลข ต้องเขียนสูตรอย่างไรครับ ขอบคุณครับ

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ E2 คีย์
   =IFERROR(INDEX($A$2:$C$9,MOD(ROWS($A$2:A9),8)+1,INT(ROWS($A$2:A9)/8))&"","")
   Enter > Copy ลงด้านล่าง
2. ที่ D2 คีย์
   =IFERROR(INDEX(E:E,AGGREGATE(15,6,ROW($E$2:$E$30)/(0<FREQUENCY(MATCH($E$2:$E$30,$E$2:$E$30,0),ROW($E$2:$E$30)-ROW($E$2)+1))/($E$2:$E$30<>""),ROWS(D$2:D2))),"")
   Enter > Copy ลงด้านล่าง

...

Excel 365

D2
=UNIQUE(TOCOL(VSTACK(A2:A9,B2:B9,C2:C9),3))

**เพื่อนสมาชิก กรุณาช่วยกดโฆษณาหน้าเพจ เพื่อเป็นการสนับสนุนฟอรั่ม**

Norkaz

ขอบคุณทั้งสองท่านมากครับ