Excel Forum

รบกวนครับ

ผมต้องการแยกข้อมูลวันที่จากคอลัมน์แปลงลงมาเป็นแถว สามารถใช้วิธีใดได้บ้างครับ

ลองตามนี้ครับ

1. แทรกคอลัมน์ E:F เพื่อใช้เป็นคอลัมน์ช่วย
2. ที่ E2 คีย์สูตรเพื่อหาจำนวนวัน
   =C2-B2+1
   Enter > Copy ไปจนถึง E4
3. เซลล์ E5 คีย์สูตรเพื่อหาผลรวมจำนวนวัน
   =SUM(E2:E4)
   Enter
4. ที่เซลล์ F2 คีย์สูตรเพื่อหาบรรทัดที่เริ่มรายการสำหรับแต่ละ No.
   =SUM(E$2:E2)-E2+1
   Enter > Copy ไปจนถึง F4
5. ที่เซลล์ H2 คีย์สูตรเพื่อแจกแจง No.
   =IF(ROWS(H$2:H2)>$E$5,"",LOOKUP(ROWS(H$2:H2),$F$2:$F$4,$A$2:$A$4))
   Enter > Copy ลงด้านล่าง
6. ที่เซลล์ I2 คีย์สูตรเพื่อแจกแจงวันที่
   =IF($H2<>"",LOOKUP(ROWS(K$2:K2),$F$2:$F$4,$B$2:$B$4)+COUNTIF($H$2:H2,H2)-1,"")
   Enter > Copy ลงด้านล่าง
7. ที่เซลล์ J2 คีย์สูตรเพื่อแจกแจงวันลา
   =IF($H2<>"",LOOKUP(ROWS(L$2:L2),$F$2:$F$4,$D$2:$D$4),"")
   Enter > Copy ลงด้านล่าง

1)ใช้คอลัมน์ E,F สองคอลัมน์ช่วยในการคำนวณ
E2 พิมพ์สูตร
=SUM(($C$2:C2)-($B$2:B2)+1)
F2 พิมพ์สูตร
=MATCH(1,--(ROW()-1<=$E$2:$E$4),0)
เป็นสูตร Array ต้องกด Ctrl+Shift+Enter แล้ว copy ลงด้านล่าง

2)
หา No. ใช้สูตร
G2=INDEX(A$2:A$4,$F2)

หา Date ใช้สูตร
H2=INDEX(B$2:B$4,$F2)+COUNTIF($F$2:F2,F2)-1

หาการลา ใช้สูตร
I2=INDEX(D$2:D$4,$F2)

เป็นสูตรธรรมดา Enter > copy ลงด้านล่างทั้งสามสูตร

ขอบพระคุณครับ