Page 1 of 1
สูตรตารางแปะหน้ากล่อง
Posted: Mon May 15, 2023 7:21 pm
by monoza2019
ต้องการสั่งปริ้นเอกสารแปะหน้ากล่อง โดยดึงข้อมูลจาก Sheet Data เขียนสูตรอย่างไรบ้างครับ
Re: สูตรตารางแปะหน้ากล่อง
Posted: Mon May 15, 2023 8:25 pm
by norkaz
...
ลองปรับไปแบบนี้ดูครับ
B2
=INDEX(Data!$B$3:$B$8,MATCH(A1,Data!$C$3:$C$8,0))
A3
="จำนวน "&COUNTIF($A$1:A1,A1)&"/"&INDEX(Data!$D$3:$D$8,MATCH(A1,Data!$C$3:$C$8,0))&" กล่อง"
**สนับสนุนฟอรั่ม กรุณาคลิกโฆษณาหน้าเพจ ครับ**
Norkaz
Re: สูตรตารางแปะหน้ากล่อง
Posted: Mon May 15, 2023 8:57 pm
by monoza2019
เลข TRB ใน Sheet print เขียนสูตรเพิ่มเติมได้ไหมครับให้ขึ้น Auto
Re: สูตรตารางแปะหน้ากล่อง
Posted: Mon May 15, 2023 9:13 pm
by norkaz
...
Sheet Data
H3
=INDEX(C:C,AGGREGATE(15,6,ROW($D$3:$D$99)/(COLUMN($A$3:$Z$3)<=$D$3:$D$99),ROWS(H$3:H3)))
Sheet Print
A1
=INDEX(Data!$H$3:$H$99,INT(ROWS(D$1:D3)/3))
B2
=INDEX(Data!$B$3:$B$8,MATCH(A1,Data!$C$3:$C$8,0))
A3
="จำนวน "&COUNTIF($A$1:A1,A1)&"/"&INDEX(Data!$D$3:$D$8,MATCH(A1,Data!$C$3:$C$8,0))&" กล่อง"
Copy A1:B3 ไปวางชุดล่างๆ ๆ ๆ
**สนับสนุนฟอรั่ม กรุณาคลิกโฆษณาหน้าเพจ ครับ**
Norkaz
Re: สูตรตารางแปะหน้ากล่อง
Posted: Mon May 15, 2023 9:16 pm
by monoza2019
ขอบคุณมากครับ ตรงกับที่ต้องการและใช้งานได้จริง
Re: สูตรตารางแปะหน้ากล่อง
Posted: Wed Jul 15, 2026 3:43 pm
by monoza2019
แก้ไขสูตรตรงไหนครับ ต้องใช้ทั้งหมด 50 กล่อง หรือมากกว่านั้นครับ
Re: สูตรตารางแปะหน้ากล่อง
Posted: Thu Jul 16, 2026 5:51 pm
by snasui
ลองดูว่าใช่ที่ต้องการหรือไม่ครับ
ที่ชีต Data เซลล์ H4 ปรับสูตรเป็น
=INDEX(C:C,AGGREGATE(15,6,ROW($D$3:$D$99)/(COLUMN($A$3:$AX$3)<=$D$3:$D$99),ROWS(H$3:H3)))
Enter > Copy ลงด้านล่าง
Re: สูตรตารางแปะหน้ากล่อง
Posted: Thu Jul 16, 2026 10:15 pm
by monoza2019
มากกว่า 50 กล่องไม่ได้ครับ สูตรที่เซลล์ H53 ขึ้นไป จะเป็น 0 ครับอาจารย์
Re: สูตรตารางแปะหน้ากล่อง
Posted: Fri Jul 17, 2026 2:33 am
by snasui
สูตรเดิมจำนวนบรรทัดจะขึ้นอยู่กับข้อมูลใน D3 ตอนนี้มี 50 หากเปลี่ยนเป็นเลขอื่นข้อมูลจะขยายไปตามนั้น
สูตรจะมองเผื่อไปว่าหากมีเอกสารอื่นเข้ามา (เพิ่มบรรทัด) ก็จะแสดงรายการต่อจากของเดิมให้ด้วย เช่นรายการแรก 50 รายการที่ 2 มี 10 สูตรจะแสดงมา 60 รายการ เป็นต้น
ตอนนี้มีรายการแค่ 50 เพราะ D3 คือ 50
หากต้องการให้แสดงรายการมากกว่า 50 สามารถคูณ 2 เข้าไปเพื่อให้รองรับเป็น 2 เท่า ดังสูตรด้านล่างครับ
=INDEX(C:C,AGGREGATE(15,6,ROW($D$3:$D$99)/(COLUMN($A$3:$CV$3)<=$D$3:$D$99*2),ROWS(H$3:H3)))
สังเกตผมปรับ AX เป็น CV เพิ่มให้ด้วยครับ