Page 1 of 1
หาตัวเลข 2 หลักกับ 3 หลัก ตามจำนวน โดยรวมรายชื่อไว้หน้าตัวเลข
Posted: Mon Apr 04, 2022 5:15 pm
by wisit
รบกวนอาจารย์และผู้รู้ครับ
ผมต้องการหาตัวเลข 2 หลักกับ 3 หลัก ตามจำนวน โดยรวมรายชื่อไว้หน้าตัวเลข ถ้าข้อมูลนั้นมีเซลล์ว่างหรือศูนย์ ไม่ต้องแสดง
ซึ่งผลลัพธ์ผมได้แนบไฟล์มาด้วยครับ
Re: หาตัวเลข 2 หลักกับ 3 หลัก ตามจำนวน โดยรวมรายชื่อไว้หน้าตัวเลข
Posted: Tue Apr 05, 2022 12:29 am
by Bo_ry
A2
=IFERROR(INDEX(LOOKUP(ROW(ข้อมูล!$A$3:$A$24),ROW(ข้อมูล!$A$3:$A$24)/(ข้อมูล!$A$3:$A$24>0),ข้อมูล!$A$3:$A$24)&" "&ข้อมูล!$B$3:$B$24,AGGREGATE(15,6,ROW(ข้อมูล!$C$3:$C$24)/(ข้อมูล!$C$3:$C$24>=A$2),ROWS(A$3:A3))-ROW($A$2)),"")
B2
=IFERROR(FILTERXML("<x><m>"&TEXTJOIN("</m><m>",,REPT(LOOKUP(ROW(ข้อมูล!$A$3:$A$24),ROW(ข้อมูล!$A$3:$A$24)/(ข้อมูล!$A$3:$A$24>0),ข้อมูล!$A$3:$A$24)&" "&ข้อมูล!$E$3:$E$24,ข้อมูล!$F$3:$F$24>=B$2))&"</m></x>","//m["&ROWS(B$3:B3)&"]"),"")
Re: หาตัวเลข 2 หลักกับ 3 หลัก ตามจำนวน โดยรวมรายชื่อไว้หน้าตัวเลข
Posted: Tue Apr 05, 2022 5:24 pm
by wisit
ได้ตามต้องการเลยครับ
ขอบคุณมากครับคุณ Bo_ry
Re: หาตัวเลข 2 หลักกับ 3 หลัก ตามจำนวน โดยรวมรายชื่อไว้หน้าตัวเลข
Posted: Tue Apr 05, 2022 9:35 pm
by wisit
รบกวนเพิ่มเติมครับ
สูตรที่คุณ Bo_ry แนะนำมาใช้ได้ดีเลยครับ แต่เนื่องจากต้องใช้สูตรคำนวณประมาณ 25,000 แถว ไฟล์จะคำนวณช้ามาก พอจะมีสูตรที่คำนวณแล้วไฟล์ทำงานไม่ช้าไหมครับ
รบกวนท่านผู้รู้ทุกท่านด้วยครับ
Re: หาตัวเลข 2 หลักกับ 3 หลัก ตามจำนวน โดยรวมรายชื่อไว้หน้าตัวเลข
Posted: Tue Apr 05, 2022 10:46 pm
by Bo_ry
ข้อมูล
D3
=IF(C3>=ผลลัพธ์!$A$2,ROWS(D$3:D3),"")
G3
=IF(F3>=ผลลัพธ์!$B$2,ROWS(G$3:G3),"")
H3
=IF(A3="",H2,A3)
ผลลัพธ์
A3
=IFERROR(INDEX(ข้อมูล!$H$3:$H$24&" "&ข้อมูล!$B$3:$B$24,SMALL(ข้อมูล!$D$3:$D$24,ROWS(A$3:A3))),"")
B3
=IFERROR(INDEX(ข้อมูล!$H$3:$H$24&" "&ข้อมูล!$E$3:$E$24,SMALL(ข้อมูล!$G$3:$G$24,ROWS(B$3:B3))),"")
Re: หาตัวเลข 2 หลักกับ 3 หลัก ตามจำนวน โดยรวมรายชื่อไว้หน้าตัวเลข
Posted: Tue Apr 05, 2022 11:39 pm
by wisit
ไฟล์คำนวณได้เร็วตามต้องการเลยครับ
ขอบคุณมากครับคุณ Bo_ry