Excel Forum

ฟอรัม Excel, VBA และอื่นๆ ของคนไทยเพื่อประโยชน์ของทุกคนในจักรวาล (Forum Excel, VBA and others of Thai people for everyone in the universe.)
https://snasui.com/

ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

https://snasui.com/viewtopic.php?t=10105

Page 1 of 1

ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Thu Jun 09, 2016 3:13 pm
by kaikungzaa
ผมทำตารางคะแนนฟุตบอล แล้วต้องหาสูตรหรือวิธีทำ ดังนี้

1. ต้องการหาอันดับของทีมหลังจากจบการแข่งในแต่ละนัดว่า ทีมอยู่อันดับที่เท่าไหร่ โดยต้องการให้ขึ้นอัตโนมัติ ไม่ต้องคีย์เอง ทำเช่นนี้จนครบ 38 นัด เพื่อจะได้เอาไปสร้างเป็นกราฟเส้น

2. ต้องการใส่รูปโลโก้ของแต่ละทีมลงไปในเซลล์ เวลาคีย์ผลการแข่ง ต้องการให้ทีมและรูป ขยับขึ้นลงตามอันดับ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Thu Jun 09, 2016 3:29 pm
by DhitiBank
ลองศึกษาดูจากลิ้งค์ด้านล่างนี้ครับ

viewtopic.php?f=3&t=8541

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Thu Jun 09, 2016 4:57 pm
by kaikungzaa
DhitiBank wrote:ลองศึกษาดูจากลิ้งค์ด้านล่างนี้ครับ

viewtopic.php?f=3&t=8541
มีวิธีอื่นอีกมั้ยครับ อ่านแล้วยังไม่ค่อยเข้าใจ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Thu Jun 09, 2016 7:01 pm
by snasui
:D ลองถามมาทีละขั้นที่อ่านแล้วไม่เข้าใจครับ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Fri Jun 10, 2016 9:11 am
by kaikungzaa
snasui wrote::D ลองถามมาทีละขั้นที่อ่านแล้วไม่เข้าใจครับ
ข้อ 1
ต้องการสูตรหรือวิิธีเพื่อหาอันดับของแต่ละทีมหลังจากการแข่งแต่ละนัดว่าอยู่อันดับที่เท่าไหร่ครับ

ตัวอย่างเช่น
แมนยู - หลังแข่งนัดที่ 1 ---> อยู่อันดับที่ 4 / หลังแข่งนัดที่ 2 ---> อยู่อันดับ 3
แมนซิ - หลังแข่งนัดที่ 1 ---> อยู่อันดับที่ 1 / หลังแข่งนัดที่ 2 ---> อยู่อันดับ 2

ทำแบบนี้จนถึงนัดที่ 38

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Fri Jun 10, 2016 7:47 pm
by snasui
:D ควรมีตารางสรุปคะแนนของแต่ละแมทช์ก่อนที่จะนำมาจัดลำดับ หากทำไว้แล้วช่วยแจ้งว่าอยู่ในพื้นที่ใดของ Worksheet ครับ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Sat Jun 11, 2016 9:17 am
by snasui
:D ด้านล่างนี้เป็นตัวอย่างการทำข้อมูลรายแมทช์และแมทช์สะสม ซึ่งมีการแทรกคอลัมน์เข้ามาช่วยในการแสดงผลครับ

ภาพการแทรกคอลัมน์รายแมทช์
EachMatch.png
โดยมีลำดับดังนี้
  1. เซลล์ S8 คีย์สูตร
    =IF(T8="","",COUNTIF(T$8:T8,T8))
  2. เซลล์T8 คีย์สูตร
    =IFERROR(INDEX(CHOOSE({1,2},$F$8:$F$387,$L$8:$L$387),INT((ROWS(T$8:T8)-1)/2)+1,MOD((ROWS(T$8:T8)-1),2)+1),"")
  3. เซลล์U8 คีย์สูตร
    =IF($T8="","",(X8>Y8)+0)
  4. เซลล์ V8 คีย์สูตร
    =IF($T8="","",(X8=Y8)+0)
  5. เซลล์ W8 คีย์สูตร
    =IF($T8="","",(X8<Y8)+0)
  6. เซลล์ X8 คีย์สูตร
    =IFERROR(INDEX(CHOOSE({1,2},$H$8:$H$387,$J$8:$J$387),INT((ROWS(X$8:X8)-1)/2)+1,MOD((ROWS(X$8:X8)-1),2)+1),"")
  7. เซลล์ Y8 คีย์สูตร
    =IFERROR(INDEX(CHOOSE({1,2},$J$8:$J$387,$H$8:$H$387),INT((ROWS(Y$8:Y8)-1)/2)+1,MOD((ROWS(Y$8:Y8)-1),2)+1),"")
  8. เซลล์ Z8 คีย์สูตร
    =IF($T8="","",X8-Y8)
  9. เซลล์ AA8 คีย์สูตร
    =IFERROR(INDEX(CHOOSE({1,2},$P$8:$P$387,$Q$8:$Q$387),INT((ROWS(AA$8:AA8)-1)/2)+1,MOD((ROWS(AA$8:AA8)-1),2)
  10. Copy สูตรทั้งหมดลงด้านล่างจนเห็นเป็นเซลล์ว่าง
ภาพการแทรกคอลัมน์แมทช์สะสม
AccumMatch.png
โดยมีลำดับดังนี้
  1. เซลล์ AC8 คีย์สูตร
    =S8
    Enter > Copy ไป AD8
  2. เซลล์ AF8 คีย์สูตร
    =IF($T8<>"",SUMIF($T$8:$T8,$T8,U$8:U8),"")
    Enter > Copy ด้านขวาจนถึง AL8
  3. เซลล์ AN8 คีย์สูตร
    =IF(T8<>"",SUM(AL8*1000000+AK8*10000+AI8*100+AF8*10),"")
    Enter
  4. เซลล์ AE8 คีย์สูตร
    =IF(AD8="","",MATCH(AN8,LARGE(IF($AC$8:$AC$1000=AC8,$AN$8:$AN$1000),ROW(INDIRECT("1:20"))),0))
    สูตรนี้กดแป้นให้รับสูตรเพียง Enter เหมือนสูตรทั่วไปไม่ได้ ต้องกด 3 แป้นคือ Ctrl+Shift+Enter เพื่อทำเป็นสูตร Array
  5. Copy สูตรทั้งหมดลงด้านล่างจนเห็นเซลล์ว่าง
ภาพการแสดงลำดับรายแมทช์
PerMatchRanking.png
โดยคีย์สูตรที่ BE8 ตามด้านล่าง

=SUMIFS($AE$8:$AE$1000,$AD$8:$AD$1000,$BD8,$AC$8:$AC$1000,BE$7)

Enter แล้ว Copy ไปด้านขวาและลงด้านล่าง

สำหรับการแทรกภาพ ให้ลองทำมาเองก่อนตาม Link ที่คุณ DhitiBank แนะนำไป ติดตรงไหนแล้วค่อยถามกันต่อครับ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Mon Jun 13, 2016 9:36 am
by kaikungzaa
snasui wrote::D ด้านล่างนี้เป็นตัวอย่างการทำข้อมูลรายแมทช์และแมทช์สะสม ซึ่งมีการแทรกคอลัมน์เข้ามาช่วยในการแสดงผลครับ

ภาพการแทรกคอลัมน์รายแมทช์

EachMatch.png


เซลล์ Y8 คีย์สูตร
=IFERROR(INDEX(CHOOSE({1,2},$J$8:$J$387,$H$8:$H$387),INT((ROWS(Y$8:Y8)-1)/2)+1,MOD((ROWS(Y$8:Y8)-1),2)+1),"")

เซลล์ AA8 คีย์สูตร
=IFERROR(INDEX(CHOOSE({1,2},$P$8:$P$387,$Q$8:$Q$387),INT((ROWS(AA$8:AA8)-1)/2)+1,MOD((ROWS(AA$8:AA8)-1),2)
AA8
=IFERROR(INDEX(CHOOSE({1,2},$P$8:$P$387,$Q$8:$Q$387),INT((ROWS(AA$8:AA8)-1)/2)+1,MOD((ROWS(AA$8:AA8)-1),2)

ลองคีย์แล้วมันไม่ได้ ต้องมี +1),"") ปิดท้ายเหมือน Y8 ด้วยเปล่าครับ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Mon Jun 13, 2016 10:59 am
by kaikungzaa
snasui wrote:
ภาพการแทรกคอลัมน์แมทช์สะสม

AccumMatch.png

โดยมีลำดับดังนี้
  1. เซลล์ AC8 คีย์สูตร
    =S8
    Enter > Copy ไป T8
จริงๆ ต้อง Copy ไป D8 ใช่หรือเปล่าครับ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Mon Jun 13, 2016 6:32 pm
by snasui
kaikungzaa wrote:AA8
=IFERROR(INDEX(CHOOSE({1,2},$P$8:$P$387,$Q$8:$Q$387),INT((ROWS(AA$8:AA8)-1)/2)+1,MOD((ROWS(AA$8:AA8)-1),2)

ลองคีย์แล้วมันไม่ได้ ต้องมี +1),"") ปิดท้ายเหมือน Y8 ด้วยเปล่าครับ
:D เข้าใจถูกแล้วครับ สูตรมี 2 บรรทัด ผมปรับ Font ใหม่ให้เห็นชัดขึ้นแล้ว
kaikungzaa wrote:ภาพการแทรกคอลัมน์แมทช์สะสม

AccumMatch.png

โดยมีลำดับดังนี้
  1. เซลล์ AC8 คีย์สูตร
    =S8
    Enter > Copy ไป T8

    จริงๆ ต้อง Copy ไป D8 ใช่หรือเปล่าครับ
ต้อง Copy ไปเซลล์ด้านขวาคือ AD8 ผมย้อนกลับไปแก้ข้อความในโพสต์เดิมแล้วครับ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Tue Jun 14, 2016 9:15 am
by kaikungzaa
ขอบคุณมากครับ ตอนนี้ได้แล้ว เหลือตรงโลโก้ ของลองศึกษาก่อนครับ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Tue Jun 14, 2016 5:18 pm
by kaikungzaa
snasui wrote::D ด้านล่างนี้เป็นตัวอย่างการทำข้อมูลรายแมทช์และแมทช์สะสม ซึ่งมีการแทรกคอลัมน์เข้ามาช่วยในการแสดงผลครับ
ถ้าต้องการแบบนี้ จะแก้สูตรยังไงครับ

1.ใส่ผลการแข่งนัดที่1 ของแต่ละทีม

2.กรณีที่ยังไม่ใส่ผลการแข่ง ต้องการให้ คอลัมน์ V เป็น 0 ครับ

3.ต้องการให้ sum เฉพาะนัดที่ใส่ผลการแข่งแล้วครับ ถ้ายังไม่ได้แข่งต้องการให้เป็น 0 ครับ

4.ต้องการให้อันดับที่ของแต่ละทีมขึ้นมาทีละนัดครับ แต่ในนี้ขึ้นมาทีเดียวเลย กรณีที่ยังไม่ใส่ผลการแข่ง ต้องการให้เซล์ว่างๆครับ เพราะผมจะเอาไปสร้างกราฟครับ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Wed Jun 15, 2016 6:44 pm
by snasui
:D ช่วยแนบตัวอย่างไฟล์ล่าสุดมาด้วยจะได้ช่วยตอบต่อไปจากนั้น ปกติผมไม่ Save ไฟล์ที่ใช้ตอบกระทู้เลยไม่มีไฟล์ล่าสุดเก็บไว้ครับ

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Thu Jun 16, 2016 9:44 am
by kaikungzaa
snasui wrote::D ช่วยแนบตัวอย่างไฟล์ล่าสุดมาด้วยจะได้ช่วยตอบต่อไปจากนั้น ปกติผมไม่ Save ไฟล์ที่ใช้ตอบกระทู้เลยไม่มีไฟล์ล่าสุดเก็บไว้ครับ
ไฟล์มันใหญ่ครับ ก็เลยต้องอัพแบบนี้ ถ้าผิดกฎขออภัยด้วยครับ
ไฟล์ ตารางคะแนนพรีเมียร์ลีก 2016-17
http://www.mediafire.com/download/iku0e ... 16-17.xlsx

Re: ต้องการหาสูตร/วิธีหาอันดับทีมในตารางคะแนนฟุตบอล ดังนี้

Posted: Fri Jun 17, 2016 6:45 pm
by snasui
:D ตัวอย่างสูตรครับ
  1. เซลล์ S8 คีย์
    =IF(INDEX(CHOOSE({1,2},$H$8:$H$387,$J$8:$J$387),INT((ROWS(T$8:T8)-1)/2)+1,MOD((ROWS(T$8:T8)-1),2)+1),COUNTIF(T$8:T8,T8),"")
    Enter > Copy ลงด้านล่าง
  2. เซลล์ U8 คีย์
    =IF($S8="","",(X8>Y8)+0)
    Enter > Enter > Copy ลงด้านล่างและปรับสูตรการแสดงค่าว่างเช่นสูตรนี้ไปใช้กับเซลล์อื่นๆ ในทุกพื้นที่
  3. เซลล์ AD8 คีย์
    =T8
    Enter > Copy ลงด้านล่าง
  4. เซลล์ AE8 คีย์
    =IF(AC8="","",MATCH(AN8,LARGE(IF($AC$8:$AC$1000=AC8,$AN$8:$AN$1000),ROW(INDIRECT("1:20"))),0))
    Ctrl+Shift+Enter > Copy ลงด้านล่าง
  5. เซลล์ AQ8 คีย์
    =IF(COUNTIF($S$8:$S$767,AQ$7),SUMIFS($AE$8:$AE$1000,$AD$8:$AD$1000,$AP8,$AC$8:$AC$1000,AQ$7),"")
    Enter > Copy ไปด้านขลาและลงด้านล่าง
All times are UTC+07:00
Page 1 of 1

Powered by phpBB® Forum Software © phpBB Limited