Snasui Excel Forum

คือผมดึงข้อมูลมาจากระบบ ERP แล้วนำมาจัดเรียงใหม่ โดยการพยายามจะรวมข้อความในส่วนของ description เข้าด้วยกัน แต่ติดตรงที่ว่า จำนวน row ของแต่ละ description มีจำนวน row ที่แตกต่างกัน ครับ รบกวน อาจารย์ หรือ ท่านผู้รู้แนะนำครับ ว่าผมต้องไปเพิ่มเงี่อนไขอะไรได้บ้างครับ

ลองดูตัวอย่างตามไฟล์แนบครับ

1. ที่เซลล์ D2 คีย์สูตรเพื่อเป็นคอลัมน์ช่วยในการ List Tooling Code
   =IF(LEFT(A4,2)="T-","",LOOKUP(2,1/(LEFT(A$4:A4,2)="T-"),A$4:A4))
   Enter > Copy ลงด้านล่าง
2. ที่เซลล์ F2 คีย์สูตรเพื่อนับว่าพบ Tooling Code จำนวนเท่าใด
   =COUNTIF(A4:A19,"T-*")
   Enter
3. ที่เซลล์ F4 คีย์สูตรเพื่อ List รายการ Tooling Code
   =IF(ROWS(F$4:F4)>$F$2,"",INDEX($A$4:$A$20,SMALL(IF(LEFT($A$4:$A$20,2)="T-",ROW($A$4:$A$20)-ROW($A$4)+1),ROWS(F$4:F4))))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
4. ที่เซลล์ H4 คีย์สูตรเพื่อ List รายการ UN และ Status
   =IF($F4="","",INDEX(B$4:B$20,MATCH($F4,$A$4:$A$20,0)))
   Enter > Copy ไปทางขวาและลงด้านล่าง
5. ที่ J4 คีย์สูตรเพื่อ List Description
   =LOOKUP(CHAR(255),CHOOSE({1,2},"",INDEX($A$4:$A$20,SMALL(IF($D$4:$D$20<>"",IF($D$4:$D$20=$F4,ROW($A$4:$A$20)-ROW($A$4)+1)),COLUMNS($J4:J4)))))
   Ctrl+Shift+Enter > Copy ไปทางขวาและลงด้านล่าง
6. ที่เซลล์ G4 คีย์สูตรเพื่อนำDescription มาเชื่อมต่อกัน
   =TRIM(J4&" "&K4&" "&L4)
   Enter > Copy ลงด้านล่าง

snasui wrote: ลองดูตัวอย่างตามไฟล์แนบครับ

1. ที่เซลล์ D2 คีย์สูตรเพื่อเป็นคอลัมน์ช่วยในการ List Tooling Code
   =IF(LEFT(A4,2)="T-","",LOOKUP(2,1/(LEFT(A$4:A4,2)="T-"),A$4:A4))
   Enter > Copy ลงด้านล่าง
2. ที่เซลล์ F2 คีย์สูตรเพื่อนับว่าพบ Tooling Code จำนวนเท่าใด
   =COUNTIF(A4:A19,"T-*")
   Enter
3. ที่เซลล์ F4 คีย์สูตรเพื่อ List รายการ Tooling Code
   =IF(ROWS(F$4:F4)>$F$2,"",INDEX($A$4:$A$20,SMALL(IF(LEFT($A$4:$A$20,2)="T-",ROW($A$4:$A$20)-ROW($A$4)+1),ROWS(F$4:F4))))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
4. ที่เซลล์ H4 คีย์สูตรเพื่อ List รายการ UN และ Status
   =IF($F4="","",INDEX(B$4:B$20,MATCH($F4,$A$4:$A$20,0)))
   Enter > Copy ไปทางขวาและลงด้านล่าง
5. ที่ J4 คีย์สูตรเพื่อ List Description
   =LOOKUP(CHAR(255),CHOOSE({1,2},"",INDEX($A$4:$A$20,SMALL(IF($D$4:$D$20<>"",IF($D$4:$D$20=$F4,ROW($A$4:$A$20)-ROW($A$4)+1)),COLUMNS($J4:J4)))))
   Ctrl+Shift+Enter > Copy ไปทางขวาและลงด้านล่าง
6. ที่เซลล์ G4 คีย์สูตรเพื่อนำDescription มาเชื่อมต่อกัน
   =TRIM(J4&" "&K4&" "&L4)
   Enter > Copy ลงด้านล่าง

ขอบคุณครับ ผมขอเวลาไปทำความเข้าใจกับสูตรก่อนครับ ขอบคุณมากครับ