Snasui Excel Forum

ต้องการดึงข้อมูลจาก Sheet Data แบบมีเพียงเงื่อนไขเดียว 2 เงื่อนไข 3 เงื่อนไข เป็นต้น เหมือนเป็นการ Sort ไล่ลำดับเงื่อนไขเพิ่มขึ้นไป
เช่น ตารางที่ 1 ต้องการให้ดึงรายละเอียดตามเงื่อนไขเดียว Issuer "SME" ให้โชว์ข้อมูลตามคอลัมที่เลือก
ตารางที่ 2 ต้องการให้ดึงรายละเอียดตามเงื่อนไขเดียว Secured Type "Unsecured" ให้โชว์ข้อมูลตามคอลัมที่เลือก
ตารางที่ 3 ต้องการให้ดึงรายละเอียดตาม เงื่อนไข 2 เงื่อนไข Secured Type "Unsecured" และ Issuer "SME" ให้โชว์ข้อมูลตามคอลัมที่เลือก
ตารางที่ 4 ต้องการให้ดึงรายละเอียดตาม เงื่อนไข 2 เงื่อนไข Issuer "SME" และ Issue Term (Yrs.) "3" ให้โชว์ข้อมูลตามคอลัมที่เลือก
ตารางที่ 5 ต้องการให้ดึงรายละเอียดตาม เงื่อนไข 3 เงื่อนไข Secured Type "Unsecured" และ Issuer "SME" และ Issue Term (Yrs.) "3" ให้โชว์ข้อมูลตามคอลัมที่เลือก

ปัจจุบันทำใน Office 365 โดยใช้สูตร FILTER แต่พบปัญหา คือถ้าหาเงื่อไขแบบ "และ" โดยใช้ "*" ต้องใส่เงื่อนไขให้ครบ ไม่อย่างนั้นสูตรจะไม่ดึงข้อมูลขึ้นมาให้ แต่หากให้หาเงื่อนไขแบบ "หรือ" โดยใช้ "+" สูตรจะดึงข้อมูลมาได้ไม่ตรงตามที่ต้องการ หากทำใน Excel ปกติ ก็ไม่ทราบว่าต้องใช้สูตรไหน เพราะ Vlookup หาตัวอ้างอิงเพียงแค่ตัวเดียว และส่งข้อมูลกลับมาเพียงตัวเดียว ขอบคุณครับ

...

พบว่ามีคอลัมน์ ที่มีข้อมูล คล้ายกัน

ช่วยอ้างอิง ตำแหน่ง ของข้อมูลที่ต้องการดึงมาแสดง ที่สัมพันธ์กัน

ที่มาจาก "ชีท Data" ว่ามาจากคอลัมน์ใด

1.Issuer มาจากคอลัมน์ ...........?

2.Secured Type "Unsecured มาจากคอลัมน์ ...........?

3.Secured Type "Unsecured" และ Issuer "SME" มาจากคอลัมน์ ...........?

4.Issuer "SME" และ Issue Term (Yrs.) "3" มาจากคอลัมน์ ...........?

5.Secured Type "Unsecured" และ Issuer "SME" และ Issue Term (Yrs.) "3"
มาจากคอลัมน์ ...........?

Norkaz

เงื่อนไขในการหา Issuer, Secured Type, Issue Term (Yrs.) ใช้การพิมพ์ หรือ Drop Down list ใน Sheet ผลที่ต้องการ
โดย Issuer ให้ไปหาข้อมูล Sheet Data คอลัมน์ D ครับ
Secured Type ให้ไปหาจากคอลัมน์ K ครับ
Issue Term (Yrs.) ให้ไปหามาจากคอลัมน์ BI ครับ

โดยถ้าข้อมูลที่ให้หาตรงตามเงื่อนไขที่ใส่เข้าไป ให้ทำการดึงรายละเอียดของตัวนั้นๆมาแสดงตามคอลัมน์ที่ต้องการ ใน Sheet ผลที่ต้องการ
ตามตัวอย่างในไฟล์
ตารางที่ 1 ใส่เงื่อนไข Issuer "SME" ก็ให้ไปหาในคอลัมน์ D ว่า SME อยู่ตรงไหน แล้วดึงข้อมูลรายละเอียดต่างๆมาแสดงครับ
ตารางที่ 4 ใส่เงื่อนไข Issuer "SME" และ Issue Term (Yrs.) "3" ก็จะไปหาใน คอลัมน์ D ว่า SME อยู่ตรงไหน พร้อมทั้ง ดูเงื่อนไข ที่ 2 ในคอลัมน์ BI ว่า เป็น 3 ด้วยหรือเปล่า ถ้าใช่ ก็นำรายละเอียดที่ต้องการของตัวนั้นมาแสดงครับ

โดยข้อมูลที่ต้องการให้ดึงจาก Sheet Data มาโชว์ใน Sheet ผลที่ต้องการ ได้แก่
Secured Type = คอลัมน์ K
Issuer = คอลัมน์ D
ThaiBMA Symbol = คอลัมน์ A
Issue Size (THB mln) = คอลัมน์ U
Issue Term (Yrs.) = คอลัมน์ W
Coupon (%) = คอลัมน์ AG
Yield curve = คอลัมน์ BJ
Spread = คอลัมน์ BG
Issue Date = คอลัมน์ Y
Distribution Type = คอลัมน์ AL
Distribution Type= คอลัมน์ AM

ขอบคุณครับผม

...

A5
=IFERROR(INDEX(Data!K:K,AGGREGATE(15,6,ROW($A$4:$A$145)/($B$2=Data!$D$4:$D$145),ROWS(A$5:A5))),"")

Copy สูตรไปคอลัมน์ ที่เกี่ยวข้อง โดยแก้ INDEX(Data!K:K ตามคอลัมน์ ในชีท Data

A17
=IFERROR(INDEX(Data!K:K,AGGREGATE(15,6,ROW($A$4:$A$145)/($A$14=Data!$K$4:$K$145),ROWS(A$17:A17))),"")

Copy สูตรไปคอลัมน์ ที่เกี่ยวข้อง โดยแก้ INDEX(Data!K:K ตามคอลัมน์ ในชีท Data

A100
=IFERROR(INDEX(Data!K:K,AGGREGATE(15,6,ROW($A$4:$A$145)/($A$97&$B$97=Data!$K$4:$K$145&Data!$D$4:$D$145),ROWS(A$100:A100))),"")

Copy สูตรไปคอลัมน์ ที่เกี่ยวข้อง โดยแก้ INDEX(Data!K:K ตามคอลัมน์ ในชีท Data

A109
=IFERROR(INDEX(Data!K:K,AGGREGATE(15,6,ROW($A$4:$A$145)/($B$106&$C$106=Data!$D$4:$D$145&Data!$BI$4:$BI$145),ROWS(A$109:A109))),"")

Copy สูตรไปคอลัมน์ ที่เกี่ยวข้อง โดยแก้ INDEX(Data!K:K ตามคอลัมน์ ในชีท Data

A118
=IFERROR(INDEX(Data!K:K,AGGREGATE(15,6,ROW($A$4:$A$145)/($A$115&$B$115&$C$115=Data!$K$4:$K$145&Data!$D$4:$D$145&Data!$BI$4:$BI$145),ROWS(A$118:A118))),"")

Copy สูตรไปคอลัมน์ ที่เกี่ยวข้อง โดยแก้ INDEX(Data!K:K ตามคอลัมน์ ในชีท Data

Norkaz

ขอบคุณมากนะครับสำหรับสูตรข้างล่าง
ผมลองก๊อปสูตรไปแล้วแต่ไม่มีอะไรขึ้น รบกวนตรวจให้ทีครับ

แต่ขอสอบถามเพิ่มเติม อาจจะเพราะผมยังบอกความต้องการไม่ละเอียด ต้องขอโทษด้วยครับ
เช่น ถ้าใส่เงื่อนไขเดียว ก็จะดึงตัวที่มีเงื่อนไขตรงกับเงื่อนไขเดียวขึ้นมา แต่หากใส่ 2 เงื่อนไข ก็จะหาข้อมูลที่มี 2 เงื่อนไขนั้นขึ้นมา และหากใส่ 3 ก็จะดึงข้อมูลที่ตรง 3 เงื่อนไขขึ้นมา
คือตามSheet ผลที่ต้องการ ตาราง 1 ถึง 5 ยุบให้เหลือเพียงตารางเดียว แต่ใส่เงื่อนไข สลับไปมา แบบใส่ 1 เงื่อนไขบ้าง 2 เงื่อนไขบ้างบ้าง สามารถทำได้หรือเปล่าครับ
ขอบคุณครับ

...

สูตรที่ให้ไป นั้น ถูกต้องตรงตามตัวอย่างเดิมที่ให้มาทุกประการ

กรณีที่แจ้งมาว่ายังไม่ใช่ รบกวนช่วยทำตัวอย่าง คำตอบที่ต้องการ มาดูครับ

Norkaz

ผมใส่สูตรไปแล้วแต่ไม่มีข้อมูลไรขึ้นมาเลยไม่แน่ใจว่าผมใส่ผิดหรือเปล่า
ตามไฟล์ ใน Sheet Norkaz จึงไม่สามารถแจ้งได้ว่าใช่ที่ต้องการหรือเปล่า

ดังนั้นจึงขอบอกในส่วนคำตอบที่ต้องการคือ ใน Sheet ผลที่ต้องการ ผมอยากได้เพียงแค่ ตารางเดียวครับ
พอเราใส่เงื่อนไข เหมือนตารางที่ 1 ก็จะได้ คำตอบที่ให้หามาเหมือนตารางที่ 1
พอเราใส่เงื่อนไข เหมือนตารางที่ 2 ก็จะได้คำตอบมาเหมือนตารางที่ 2
พอเราใส่เงื่อนไขเหมือนตารางที่ 3 ก็จะได้คำตอบออกมาเหมือนตารางที่ 3
ตารางที่ 4 และ 5 ก็เหมือนกันครับ
ดังนั้นผมจึงไม่สามารถทำคำตอบแบบเปลี่ยนเงื่อนไข สลับไปมา ใน cell A2, B2, C2 ในตารางเดียวได้
จึงได้แยกออกมาเป็นตารางที่ 1 ถึง 5 ออกมาให้เห็นแทน
ต้องขออภัยหากไม่สามารถอธิบายความต้องการให้เข้าใจได้ครับ
ขอบคุณสำหรับความช่วยเหลือนะครับ

...

A5:Kxx
=IFERROR(INDEX(Data!$A:$BJ,AGGREGATE(15,6,ROW($A$4:$A$145)/(($A$2=Data!$K$4:$K$145)+($B$2=Data!$D$4:$D$145)+($C$2=Data!$BI$4:$BI$145)=COUNTA($A$2:$C$2)),ROWS(A$5:A5)),MATCH(A$4,Data!$A$2:$BJ$2,0)),"")


Copy ลงล่าง และไปทางขวา

** ที่ชีท ผลที่ต้องการ-2 แถวที่ 4 ให้ Copy หัวตาราง จากชีท Data มาวางเพื่อให้เหมือนกันเป๊ะ

*** และที่ชีท Data หัวตารางต้อง ไม่ซ้ำกัน --ถ้าซ้ำกัน ให้แก้ไขใส่หมายเลขลงไป เพื่อให้หัวตารางแตกต่าง เช่น Issue Term (Yrs.)-1


Norkaz

เรียน คุณ Norkaz
ได้คำตอบแบบที่ต้องการแล้วครับ
ขอกราบขอบพระคุณในความกรุณาไว้ ณ ที่นี้ ด้วยครับ