Excel Forum

ช่วยทำตัวอย่างคำตอบในชีท SMC มาด้วยจะได้เข้าใจตรงกันว่าผลลัพธ์ที่ต้องการเป็นเช่นไรครับ

การจะแยกข้อมูลออกมาเป็นอย่างใดก็ตาม จะต้องให้สัมพันธ์กับข้อมูลที่มีใน Database เช่นกรณีที่ผมถามไปก่อนหน้านี้ ต้องการแยก SMC1, SMC2 ออกมา แต่ใน Database ไม่สามารถระบุได้ว่าบรรทัดใดเป็นเป็น SMC1 บรรทัดใดเป็น SMC2

หากสามารถระบุเพิ่มในชีท LINE ได้ว่าบรรทัดใดเป็น SMC1, SMC2 ก็ย่อมจะใช้งานได้เช่นกัน หรือกรณีตามไฟล์แนบล่าสุดก็สามารถใช้งานได้เช่นกันเนื่องจากไม่ได้แยกชีตออกเป็น SMC1, SMC2 ครับ

ตัวอย่างคำตอบที่ต้องการครับ

ขอบคุณสำหรับความรู้ที่อธิบายมาครับ เข้าใจมากขึ้นเลยครับ

ตัวอย่างสูตรครับ

1. ที่ชีต SMC เซลล์ G4:L4 คีย์ค่าต่อไปนี้ตามลำดับ Name, JobNo, ไส้แบบ, Cycle, Line, Start
2. เซลล์ G5 คีย์
   =IFERROR(INDEX(database!$D$4:$D$13,SMALL(IF($B$2=database!$G$4:$G$13,ROW(database!$D$4:$D$13)-ROW(database!$D$4)+1),ROWS(G$5:G5))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
3. เซลล์ H5 คีย์
   =IF(G5="","",INDEX(database!$B$4:$B$13,MATCH(G5,database!$D$4:$D$13,0)))
   Enter > Copy ลงด้านล่าง
4. เซลล์ I5 คีย์
   =IF(G5="","",SUMIFS(LINE!$G$5:$G$28,LINE!$I$5:$I$28,$B$2,LINE!$C$5:$C$28,G5))
   Enter > Copy ลงด้านล่าง
5. เซลล์ J5 คีย์
   =IF(G5="","",SUMIFS(database!$H$4:$H$13,database!$G$4:$G$13,$B$2,database!$D$4:$D$13,G5))
   Enter > Copy ลงด้านล่าง
6. เซลล์ K5 คีย์
   =ROUNDUP(I5/J5,0)
   Enter > Copy ลงด้านล่าง
7. เซลล์ K7 คีย์
   =SUM(K5:K6)
   Enter
8. เซลล์ L5 คีย์
   =SUM(K$5:K5)-K5+1
   Enter > Copy ลงด้านล่าง
9. เซลล์ C5 คีย์
   =IF(ROWS(C$5:C5)>$K$7,"",LOOKUP(ROWS(C$5:C5),$L$5:$L$6,$H$5:$H$6))
   Enter > Copy ลงด้านล่าง

ขอรบกวนอีกครั้งนะครับ

ไม่ทราบว่ามีสูตรแบบพิจารณาจาก Job No. ไหมครับ
ที่สูตรให้มา คือพิจารณาจาก Name ใช่ไหมครับ

พอไปประยุกต์ใช้จริงๆ จะมีบาง Job ที่มีชื่อเหมือนกันครับ

ขอบคุณครับ

แนบไฟล์ที่ได้ปรับสูตรตามที่ผมตอบไปแล้วมาด้วยจะได้ตอบต่อไปจากนั้นครับ

ผมได้ลองเปลี่ยน Name ของ Job A08 ให้ซ้ำกับ A04
ผลทำให้ Job A08 ไม่แสดงข้อมูลครับ

ขอถามเพิ่มเติมครับ คอลัมน์ M,N คือค่าอะไรครับ

ผมลองทำแค่ ชีต SMC ชีตเดียวนะครับ
ขอบคุณครับ

สูตรทั้งหลายที่ผมแนะนำไปนั้นมีถึงคอลัมน์ L เท่านั้นครับ

สูตรใน L5 และ C5 ยังไม่ตรงกับที่ผมแจ้งไป กรุณาทบทวนใหม่ทั้งหมดแล้วคีย์ให้ตรงตามนั้น ส่วนปัญหาว่าต้องการจะให้แสดงผลอย่างไร ให้เขียนอธิบายแยกออกมาต่างหากครับ

แก้ไขแล้วครับ ขอประทานโทษด้วยครับที่ดูไม่ละเอียด

ดูโดยรวมแล้ว ใกล้จะได้อย่างที่ต้องการแล้ว
แต่ยังมีเรื่อง Job ที่มี Name ซ้ำกันครับ ทำให้ค่า Job ที่มี Name อีกค่าไม่ขึ้นแสดงครับ
ต้องการให้แสดงค่า Name ที่ซ้ำกันด้วยครับ

ตัวอย่างอยู่ที่ ชีต SMC ครับ
Job A04 และ A08 มีชื่อที่เหมือนกันทำให้ ข้อมูลของ A08 ไม่แสดงผลขึ้นมาครับ

แต่ผมคิดว่าอยากให้การพิจารค่า โดยดึงข้อมูลจาก Job No. ได้ไหมครับ

ขอบคุณครับ

ตัวอย่างการปรับสูตรตามด้านล่าง เซลล์ใดที่ไม่ได้ปรับคือสูตรเดิมที่แจ้งไปแล้วครับ

1. G5 คีย์
   =IF(H5="","",INDEX(database!$D$4:$D$13,MATCH(H5,database!$B$4:$B$13,0)))
   Enter > Copy ลงด้านล่าง
2. H5 คีย์
   =IFERROR(INDEX(database!$B$4:$B$13,SMALL(IF($B$2=database!$G$4:$G$13,ROW(database!$D$4:$D$13)-ROW(database!$D$4)+1),ROWS(H$5:H5))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
3. I5 คีย์
   =IF(H5="","",SUMIFS(LINE!$G$5:$G$28,LINE!$I$5:$I$28,$B$2,LINE!$D$5:$D$28,H5))
   Enter > Copy ลงด้านล่าง
4. J5 คีย์
   =IF(H5="","",SUMIFS(database!$H$4:$H$13,database!$G$4:$G$13,$B$2,database!$B$4:$B$13,H5))
   Enter > Copy ลงด้านล่าง
5. C5 คีย์
   =IF(ROWS(C$5:C5)>$K$7,"",LOOKUP(ROWS(C$5:C5),$L$5:$L$6,$H$5:$H$6))
   Enter > Copy ลงด้านล่าง

ขอบคุณครับ เดี๋ยวต้องลองมาประยุกต์ใช้ในงานจริงก่อน

ถ้าติดปัญหาอะไรอีก เดี๋ยวขอมาสอบถามเพิ่มเติมนะครับ

ขอขอบพระคุณอีกทีครับ ที่สละเวลามาตอบคำถามให้หลายวัน