Excel Forum

รบกวนสอบถามท่านผู้รู้ครับ

ปัญหา
1.ต้องการรวบรวมข้อมูลจากชีทที่ทีมงานส่งมา มารวมในชีทเดียวเพื่อสรุป แต่ใช้เวลานาน และบางชีทหัวตารางไม่เท่ากัน ทำให้ยากต่อการ Copy แล้ววางครับ

ความต้องการ
1.ต้องการรวมข้อมูลจากชีท 1 2 3 4 5มารวมที่ชีท Summary ให้ตรงกับหัวตาางครับ

กรณีหัวคอลัมน์ไม่ตรงกันเช่นนี้คงต้องอาศัย VBA เข้ามาช่วย ลองเขียนมาเองก่อนตามกฎการใช้บอร์ดข้อ 5 ด้านบน ติดตรงไหนค่อยนำมาถามกันต่อครับ

หรืออาจลองใช้คอลัมน์ช่วยมากหน่อยครับ ลองแบบนี้

1. ที่ R1:Y1 คัดลอกหัวตารางจาก C1:J1 มาวาง

2. N2:N6 คีย์เลขชื่อชีท 1 - 5 ตามลำดับ

3. O2 คีย์
=LOOKUP(CHAR(255),INDIRECT("'"&$N2&"'!B1:B10000"),ROW(INDIRECT("'"&$N2&"'!B1:B10000")))
Enter

4. P2 คีย์
=LOOKUP(9.99999999E+307,INDIRECT("'"&$N2&"'!B1:B10000"),ROW(INDIRECT("'"&$N2&"'!B1:B10000")))-O2
Enter

5. Q2 คีย์
=SUM(P$2:P2)-P2+1
Enter

6. R2 คีย์
=MATCH(R$1,INDIRECT("'"&$N2&"'!"&ADDRESS($O2,2)&":"&ADDRESS($O2,26)),0)
Enter -> คัดลอกไปทางขวาถึง Y2

7. คัดลอกสูตรที่ 3 - 6 ลงล่างถึงแถวที่ 6

8. M1 คีย์ (ถึงข้อ 8 นี่เป็นการสร้างคอลัมน์ช่วย)
=SUM(P:P)
Enter

9. K2 คีย์
=IF(ROWS(K$2:K2)>$M$1,"",LOOKUP(ROWS(K$2:K2),$Q$2:$Q$6,$N$2:$N$6))
Enter

10. A2 คีย์
=IF($K2="","",INDIRECT("'"&$K2&"'!"&ADDRESS(COUNTIF($K$2:$K2,$K2)+LOOKUP(ROWS(A$2:A2),$Q$2:$Q$6,$O$2:$O$6),COLUMNS($A2:A2)+1)))
Enter -> คัดลอกไป B2

11. C2 คีย์
=IF($K2="","",IF(ISNA(LOOKUP(ROWS(C$2:C2),$Q$2:$Q$6,R$2:R$6)),0,INDIRECT("'"&$K2&"'!"&ADDRESS(COUNTIF($K$2:$K2,$K2)+LOOKUP(ROWS(C$2:C2),$Q$2:$Q$6,$O$2:$O$6),LOOKUP(ROWS(C$2:C2),$Q$2:$Q$6,R$2:R$6)+1))))
Enter -> คัดลอกไปทางขวาถึง J2

12. คัดลอกสูตรข้อ 9-11 ลงล่างจนเห็นว่าสูตรแสดงค่าว่างครับ

เวลาใช้งาน ก็เพิ่มชีทใหม่ -> เอาข้อมูลมาวางให้ตำแหน่งเริ่มต้นเหมือนกับชีทอื่นๆ (เริ่มที่ B7) -> มาเพิ่มชื่อชีทใหม่ในชีทดึงข้อมูล -> คัดลอกสูตรตามข้อ 7 ลงมาถึงแถวที่มีชื่อชีทใหม่ -> คัดลอกสูตรตามข้อ 12 ลงล่างจนเห็นค่าว่างครับ

อีกตัวอย่างสูตรกรณีใช้คอลัมน์ช่วยครับ

1. เซลล์ M2 คีย์สูตรเพื่อ List ยอดขาย
   =INDEX($C$1:$J$1,ROWS(M$2:M2))
   Enter > Copy จนถึง M9
2. เซลล์ N1:R1 คีย์รายชื่อชีต (กรณีนี้คีย์ 1-5)
3. เซลล์ N2 คีย์สูตร
   =IFERROR(MATCH($M2,INDIRECT("'"&N$1&"'!d7:k7"),0),20)
   Enter > Cooy ไปทางขวาและลงด้านล่าง
4. เซลล์ C2 คีย์สูตร
   =SUMPRODUCT(SUMIFS(OFFSET(INDIRECT("'"&$N$1:$R$1&"'!c8:c100"),0,INDEX($N$2:$R$9,MATCH(C$1,$M$2:$M$9,0),0)),INDIRECT("'"&$N$1:$R$1&"'!b8:b100"),$A2,INDIRECT("'"&$N$1:$R$1&"'!c8:c100"),$B2))

ขอบคุณอาจารย์ทั้งสองท่านนะครับ ผมขอเวลาอ่านทำความเข้าใจทั้งหมดก่อนนะครับ
พึ่งเริ่มต้นศึกษา จะได้รบกวนเฉพาะที่ติดขัดจริงๆ
ปล.ที่อาจารย์ทำให้มาใช้ได้ผลตามต้องการดีเลยครับ