Page 1 of 1
สอบถามเกี่ยวกับการหาวันที่สิ้นเดือนครับ
Posted: Thu Aug 01, 2013 7:08 pm
by niwat2811
ต้องการหาวันที่สิ้นเดือน เช่น ถ้าตรงกับวันเสาร์ วันอาทิตย์และวันหยุด ให้เลื่อนเป็นวันทำการถัดไป
ถ้าวันที่สิ้นเดือนตรงกับวันทำการก็ให้ใช้วันทำการ
ข้อมูลอยู่ในไฟล์แนบ Sheet1 ครับ
Re: สอบถามเกี่ยวกับการหาวันที่สิ้นเดือนครับ
Posted: Thu Aug 01, 2013 7:34 pm
by ysamroeng
แล้วจะให้เอาคำตอบไปใส่ตรงไหน? อย่างไรครับ?
เพราะในตัวอย่าง ก็เห็นตารางทั้งปี ซึ่งก็รู้อยู่แล้วว่าวันไหนหยุด หรือทำการ
Re: สอบถามเกี่ยวกับการหาวันที่สิ้นเดือนครับ
Posted: Thu Aug 01, 2013 7:52 pm
by niwat2811
ตรง เซล H4 ไล่เรียงกันลงไปตามตัวอย่างเลยครับ
Re: สอบถามเกี่ยวกับการหาวันที่สิ้นเดือนครับ
Posted: Thu Aug 01, 2013 9:17 pm
by snasui
ลองตามนี้ครับ
- ที่ D1:E1 คีย์คำว่า LastMonth และ Workday ตามลำดับ
- ที่ D2 คีย์สูตร เพื่อหาเดือนที่แล้วซึ่งจะนำไปใช้เป็นส่วนประกอบหนึ่งของสูตรใน E2
=TEXT(EOMONTH(A2,-1),"mmyyyy")
Enter > Copy ลงด้านล่าง
- ที่ E2 คีย์สูตรเพื่อหาว่าเป็นวันที่เข้าเงื่อนไขหรือไม่
=IF(C2="วันหยุด",FALSE,IF(DAY(A2)=DAY(EOMONTH(A2,0)),TRUE,IF(AND(DAY(A2)<=5,C1="วันหยุด",SUMPRODUCT(--(D$2:D2=TEXT(EOMONTH(A2,-1),"mmyyyy")),--(E$1:E1=TRUE))=0),TRUE,FALSE)))
Enter > Copy ลงด้านล่าง
- ที่ H4 คีย์สูตรเพื่อ List วันที่เข้าเงื่อนไข
=IFERROR(INDEX($A$2:$A$366,SMALL(IF($E$2:$E$366,ROW($A$2:$A$366)-ROW($A$2)+1),ROWS(H$4:H4))),"")
Ctrl+Shift+Enter > Copy ลงด้านล่างแล้วปรับใช้กับคอลัมน์ I และ J
Re: สอบถามเกี่ยวกับการหาวันที่สิ้นเดือนครับ
Posted: Thu Aug 01, 2013 10:29 pm
by niwat2811
สูตรที่ท่านอาจารย์ให้มาใช้ได้ตรงตามความต้องการครับ ขอบพระคุณเป็นอย่างสูงครับ
Re: สอบถามเกี่ยวกับการหาวันที่สิ้นเดือนครับ
Posted: Fri Aug 02, 2013 6:14 pm
by tahc
MS-Office 2003 ใช้สูตรนี้ได้มั้ยครับอาจารย์ (เอาไปลองแล้วได้คำตอบ #NAME?)
มีวิธีสำหรับMS-Office 2003ไหมครับอาจารย์
Re: สอบถามเกี่ยวกับการหาวันที่สิ้นเดือนครับ
Posted: Fri Aug 02, 2013 6:50 pm
by bank9597
tahc wrote:MS-Office 2003 ใช้สูตรนี้ได้มั้ยครับอาจารย์ (เอาไปลองแล้วได้คำตอบ #NAME?)
มีวิธีสำหรับMS-Office 2003ไหมครับอาจารย์
เปลี่ยนจากการใช้สูตร IFERROR เป็นสูตร ISNA ดูครับ หากไม่ได้ยัง ลองถามมาอีกครั้งครับ
Re: สอบถามเกี่ยวกับการหาวันที่สิ้นเดือนครับ
Posted: Fri Aug 02, 2013 7:38 pm
by bank9597
ผมปรับสูตรให้ดังนี้ครับ
เปลี่ยนสูตร
=IFERROR(INDEX($A$2:$A$366,SMALL(IF($E$2:$E$366,ROW($A$2:$A$366)-ROW($A$2)+1),ROWS(H$4:H4))),"")
เป็น
=IF(ISNA(INDEX($A$2:$A$366,SMALL(IF($E$2:$E$366,ROW($A$2:$A$366)-ROW($A$2)+1),ROWS(H$4:H4)))),"",INDEX($A$2:$A$366,SMALL(IF($E$2:$E$366,ROW($A$2:$A$366)-ROW($A$2)+1),ROWS(H$4:H4))))
กด Ctrl+Shift+Enter
Re: สอบถามเกี่ยวกับการหาวันที่สิ้นเดือนครับ
Posted: Sun Aug 04, 2013 10:37 am
by tahc
ขอบคุณมากมายครับ