Excel Forum

จุดประสงค์ต้องการสรุปผลรวม ปริมาณการเบิกของ 3 อย่างได้แก่ BOX SUPPORT, CONT. BOX, EQ.SADDLE ของแต่ละ MODEL NO.
โดยนำค่าที่ได้จาก sheet DATA มาสรุปที่ชีท SUMMARY MODEL 1 R
โดยแยกตาม TYPE ,SIZE และ THK MM เหมือนกัน ให้รวมจำนวน (EA) และ จำนวนตารางเมตร (M2)
ซึ่งผมได้ใส่ค่าสรุปผลรวมตัวอย่างไว้ในชีท SUMMARY MODEL 1 R
ทั้งนี้ อยากให้เวลาที่คีย์ ข้อมูลที่ชีท DATA แล้วสามารถสรุปที่ชีท SUMMARY MODEL 1 R ได้เลยอ่ะครับ
ขอบคุณมากครับ

ช่วยชี้ให้เห็นว่าข้อมูลจากชีท DATA ไปแสดงในชีท SUMMARY MODEL 1 R ด้วยเงื่อนไขใด คือสังเกตจากช่องไหน อย่างไร เพื่อที่จะดึงเฉพาะข้อมูลทีต้องการมาแสดงครับ

เงื่อนไขคือ TYPE (COLUMN E), SIZE (COLUMN F), และ THK. MM. (COLUMN G) เป็นค่าเหมือนกันแล้ว ให้รวมจำนวน ของ BOX SUPPORT,CONT. BOX,EQ. SADDLE

จาก ชีท DATA , MODEL NO. 1 D
เมื่อ
E14 เป็น TYPE เดียวกับ E15
F14 เป็น SIZE เดียวกับ F15
F14 เป็น SIZE THK. MM. F15

ซึ่งจะแสดงรายการที่ชีท SUMMARY MODEL 1 D!D10,E10,F10 (TYPE=C,SIZE=6,THK.MM.=120)
ให้รวมจำนวนชิ้นของ BOX SUPPORT (O14+O15) = 2 แสดงที่ชีท SUMMARY MODEL 1 D !G10
และรวมจำนวนตารางเมตรของ AE14+AD14 ของชีท DATA แสดงที่ ชีท SUMMARY MODEL 1 D !K10

ทั้งนี้อยากให้ข้อมูลที่ใส่ในชีท DATA แสดงที่ชีทSUMMARY MODEL 1 D โดยอัตโนมัติ ถ้ามีรายการที่ซ้ำากันตามเงื่อนไขข้างต้นแล้ว

ลองตามนี้ครับ

ที่ชีท SUMMARY MODEL 1 D

1. เซลล์ D5 คีย์
   =SUM(IF(FREQUENCY(MATCH(DATA!$E$13:$E$35&DATA!$F$13:$F$35&DATA!$G$13:$G$35,DATA!$E$13:$E$35&DATA!$F$13:$F$35&DATA!$G$13:$G$35,0),ROW(DATA!$D$13:$D$35)-ROW(DATA!$D$13)+1),1))
   Ctrl+Shift+Enter
2. ที่เซลล์ D7 คีย์
   =IF(ROWS(D$7:D7)>$D$5,"",INDEX(DATA!E$13:E$35,SMALL(IF(FREQUENCY(MATCH(DATA!$E$13:$E$35&DATA!$F$13:$F$35&DATA!$G$13:$G$35,DATA!$E$13:$E$35&DATA!$F$13:$F$35&DATA!$G$13:$G$35,0),ROW(DATA!$D$13:$D$35)-ROW(DATA!$D$13)+1),ROW(DATA!$D$13:$D$35)-ROW(DATA!$D$13)+1),ROWS(D$7:D7))))
   Ctrl+Shift+Enter > Copy ไปด้านขวาถึงคอลัมน์ F แล้ว Copy ลงด้านล่าง
3. ที่เซลล์ G7 คีย์
   =SUMIFS(DATA!O$13:O$35,DATA!$E$13:$E$35,$D7,DATA!$F$13:$F$35,$E7,DATA!$G$13:$G$35,$F7)
   Enter > Copy ไปด้านขวาถึงคอลัมน์ I แล้ว Copy ลงด้านล่าง
4. ที่เซลล์ K7 คีย์
   =SUMIFS(DATA!$AE$13:$AE$35,DATA!$E$13:$E$35,$D7,DATA!$F$13:$F$35,$E7,DATA!$G$13:$G$35,$F7)
   Enter > Copy ลงด้านล่าง

โทษทีครับอาจารย์ ที่ชีท SUMMARY MODEL 1 D! ผมดันไปซ่อน column C , ที่อยากได้คือ ผลรวมของแต่ละ MODEL NO. โดยแยกชีท(ตัวอย่างMODEL NO.1 D) ซึ่งมีเงื่อนไขเหมือนเดิม โดยคียแค่ 1D ที่ C7 ถึงC11 ของชีทSUMMARY MODEL 1 D! แล้วให้โปรแกรม list รายการออกมาเลย ว่ามีกี่รายการ พร้อมผลรวม ซึ่งผมได้คีย์ค่าที่ต้องการไว้ในชีทSUMMARY MODEL 1 D!แล้วครับ ขอบคุณเป็นอย่างยิ่งเลยครับ

ขออภัยครับ ปกติตัวอย่างจะต้องเหมือนกับไฟล์จริงและเมือผมตอบไปแล้วจำเป็นต้องปรับมาเองเสมอ ติดตรงไหนค่อยมาถามกันครับ

ผมลองใส่สูตรที่อาจารย์ให้จะได้คำนวณผลรวมทั้งหมด ของวัสดุแต่ละประเภทตามเงื่อนไข ขอเพิ่มเติมนิดนึงครับคือ แยกแต่ละ MODEL NO. (ในชีท SUMMARY MODEL 1Dคือผลรวมของ MODEL NO. 1D ) ซึ่งผมดันไป hide column C ของชีท SUMMARY MODEL 1D ไว้ ..ขอบคุณครับ

ลองตามด้านล่างครับ

ที่ชีท SUMMARY MODEL 1 D

1. เซลล์ C5 คีย์ Model No. ที่ต้องการเช่น 1 D
2. เซลล์ D5 คีย์
   =SUM(IF(FREQUENCY(IF(DATA!$D$13:$D$35=$C$5,MATCH(DATA!$E$13:$E$35&DATA!$F$13:$F$35&DATA!$G$13:$G$35,DATA!$E$13:$E$35&DATA!$F$13:$F$35&DATA!$G$13:$G$35,0)),ROW(DATA!$D$13:$D$35)-ROW(DATA!$D$13)+1),1))
   Ctrl+Shift+Enter
3. เซลล์ C7 คีย์
   =IF(ROWS(C$7:C7)>$D$5,"",$C$5)
   Enter > Copy ลงด้านล่าง
4. เซลล์ D7 คีย์
   =IF(ROWS(D$7:D7)>$D$5,"",INDEX(DATA!E$13:E$35,SMALL(IF(FREQUENCY(IF(DATA!$D$13:$D$35=$C$5,MATCH(DATA!$E$13:$E$35&DATA!$F$13:$F$35&DATA!$G$13:$G$35,DATA!$E$13:$E$35&DATA!$F$13:$F$35&DATA!$G$13:$G$35,0)),ROW(DATA!$D$13:$D$35)-ROW(DATA!$D$13)+1),ROW(DATA!$D$13:$D$35)-ROW(DATA!$D$13)+1),ROWS(D$7:D7))))
   Ctrl+Shift+Enter > Copy ไปถึง F7 แล้ว Copy ลงด้านล่าง
5. เซลล์ G7 คีย์
   =IF(ROWS(G$7:G7)>$D$5,"",SUMIFS(DATA!O$13:O$35,DATA!$D$13:$D$35,$C$5,DATA!$E$13:$E$35,$D7,DATA!$F$13:$F$35,$E7,DATA!$G$13:$G$35,$F7))
   Enter > Copy ไปถึง I7 แล้ว Copy ลงด้านล่าง
6. เซลล์ K7 คีย์
   =IF(ROWS(K$7:K7)>$D$5,"",SUMIFS(DATA!$AE$13:$AE$35,DATA!$D$13:$D$35,$C$5,DATA!$E$13:$E$35,$D7,DATA!$F$13:$F$35,$E7,DATA!$G$13:$G$35,$F7))
   Enter > Copy ลงด้านล่าง

ขอบคุณมากครับ อาจารย์ ขอโทษที่ตอบช้า