Excel Forum

Posted: **Sat Sep 15, 2018 11:04 am**

ขอสูตร รวมข้อมูลจากหลายคอลัมน์ไว้คอลัมน์เดียว โดยไม่ซ้ำกัน

Posted: **Sat Sep 15, 2018 1:26 pm**

ตัวอย่างสูตรตามด้านล่างครับ

ที่ K3, L3 คีย์ Name และ List ตามลำดับ
ที่ K4 คีย์
=IF(ROWS(K$4:K4)>COUNTA($G$4:$I$23),"",INDEX($F$4:$F$23,INT((ROWS(K$4:K4)-1)/3)+1))
Enter > Copy ลงด้านล่าง
ที่ L4 คีย์
=IF(K4="","",INDEX($G$4:$I$23,INT((ROWS(K$4:K4)-1)/3)+1,MOD((ROWS(K$4:K4)-1),3)+1))
Enter > Copy ลงด้านล่าง
ที่ B4 คีย์
=IFERROR(INDEX($L$4:$L$100,SMALL(IF(FREQUENCY(IF($K$4:$K$100=$B$1,IF($L$4:$L$100<>"N/A",MATCH($L$4:$L$100,$L$4:$L$100,0))),ROW($L$4:$L$100)-ROW($L$4)+1),ROW($L$4:$L$100)-ROW($L$4)+1),ROWS(B$4:B4))),"")
Ctrl+Shift+Enter > Copy ลงด้านล่าง

!

Note: Ctrl+Shift+Enter
เป็นการสร้างสูตร Array โดยสามารถเลือกดำเนินการตามข้อ 1 หรือ 2 ด้านล่าง

กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น
Ctrl และ Shift พร้อมกันค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array
กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน
จากนั้นกดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วตามด้วย Enter เพื่อสร้างเป็นสูตร Array
หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)}
ปีกกานี้ไม่สามารถคีย์เข้าไปเอง จะต้องมาด้วยการกดแป้น Ctrl+Shift+Enter เท่านั้น
ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง
การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง

Posted: **Sat Sep 15, 2018 1:48 pm**

ถ้าจะให้เรียงตามลำดับต้องใช้สูตรอะไรครับ

Posted: **Sat Sep 15, 2018 2:30 pm**

แนบไฟล์ล่าสุดมาด้วยจะได้ตอบต่อไปจากนั้นครับ

Posted: **Sat Sep 15, 2018 2:43 pm**

ไฟล์แนบครับ

Posted: **Sat Sep 15, 2018 3:11 pm**

ย้ายผลลัพธ์ในคอลัมน์ B ไปไว้ในคอลัมน์ M จากนั้นทำตามด้านล่างครับ

ที่ N4 คีย์
=IF(M4="","",(SUMPRODUCT(--(M4>$M$4:$M$23)))-COUNTIF($M$4:$M$23,"")+1)
Enter > Copy ลงด้านล่าง
ที่ B4 คีย์
=IFERROR(INDEX($M$4:$M$23,MATCH(A4,$N$4:$N$23,0)),"")
Enter > Copy ลงด้านล่าง

Posted: **Sat Sep 15, 2018 3:36 pm**

ได้แล้วครับ ขอบคุณมากครับ

ขอสูตร รวมข้อมูลจากหลายคอลัมน์ไว้คอลัมน์เดียว โดยไม่ซ้ำกัน