Page 1 of 1
ขอสูตร small
Posted: Mon May 04, 2015 2:14 pm
by Supachok
เรียน ท่านอาจารย์ และผู้รู้ครับ
คือผมทำสูตรหาย
ตามไฟล์แนบ ใน sheet label
ต้องการลิงค์ข้อมูล B5 จาก sheet SOE detail
โดยมีเงื่อนไขว่า A4 ต้องมีข้อมูลตรงกับ sheet SOE detail
จึงจะโชว์ข้อมูล
จริงๆผมได้ข้อมูลทั้งหมด แต่ต้องการตัดบรรทัดเลข 0 ที่เงื่อนไขไม่ตรงออกไป
เคยเห็นสูตร ว่าใช้ Small ถ้าจำไม่ผิด
อย่างไรรบกวนด้วยครับ.
Re: ขอสูตร small
Posted: Mon May 04, 2015 3:19 pm
by godman
ไม่แน่ใจว่าตรงความต้องการไหม
Re: ขอสูตร small
Posted: Mon May 04, 2015 3:54 pm
by Supachok
ยังไม่ตรงครับ
ที่ต้องการคือให้มีข้อมูล ที่ตรงเงื่อนไขเท่านั้น
ไม่ตรงเงื่อนไขไม่โชว์ครับ
ปล
ถ้ามีข้อมูลตามเงื่อนไข 2 ตัวโชว์ 2 บรรทัด
ถ้ามีข้อมูลตามเงื่อนไข 4 ตัวโชว์ 4 บรรทัด
ขอบคุณครับ
Re: ขอสูตร small
Posted: Mon May 04, 2015 3:55 pm
by Supachok
แนบไฟล์ตัวอย่างผลลัพธ์ที่ต้องการครับ
Re: ขอสูตร small
Posted: Mon May 04, 2015 8:34 pm
by snasui
Supachok wrote:เรียน ท่านอาจารย์ และผู้รู้ครับ
คือผมทำสูตรหาย
ตามไฟล์แนบ ใน sheet label
ต้องการลิงค์ข้อมูล B5 จาก sheet SOE detail
โดยมีเงื่อนไขว่า A4 ต้องมีข้อมูลตรงกับ sheet SOE detail
จึงจะโชว์ข้อมูล
จริงๆผมได้ข้อมูลทั้งหมด แต่ต้องการตัดบรรทัดเลข 0 ที่เงื่อนไขไม่ตรงออกไป
เคยเห็นสูตร ว่าใช้ Small ถ้าจำไม่ผิด
อย่างไรรบกวนด้วยครับ.
ที่ชีท Label เซลล์ I4 คีย์สูตร
=IFERROR(INDEX(A$4:A$28
&"",SMALL(IF($E$4:$E$28+$F$4:$F$28>0,ROW(A$4:A$28)-ROW(A$4)+1),ROWS(I$4:I4))),"")
Ctrl+Shift+Enter > Copy ไปทางขวาและลงด้านล่าง
สำหรับคอลัมน์ใดที่ต้องการให้แสดงเป็นตัวเลขให้ลบ
&"" หลัง Index ออกไปครับ
Re: ขอสูตร small
Posted: Tue May 05, 2015 8:52 am
by Supachok
ขอบคุณครับ อาจารย์
จะลองประยุกต์ดึงจากอีกsheet ดู
Re: ขอสูตร small
Posted: Tue May 05, 2015 10:48 am
by snasui
Supachok wrote:ต้องการลิงค์ข้อมูล B5 จาก sheet SOE detail
โดยมีเงื่อนไขว่า A4 ต้องมีข้อมูลตรงกับ sheet SOE detail
จึงจะโชว์ข้อมูล
กรณีต้องการดึงจากชีท SOE details นั้น ที่ชีท Label ทำตามด้านล่างครับ
- เซลล์ A4 คีย์สูตร
=IFERROR(IF(COUNTIF(A$3:A3,"")=SUM(COUNTIFS('SOE details'!$E$7:$E$16,$A$3:$A3,'SOE details'!$E$7:$E$16,"<>"))+1,INDEX('SOE details'!$E$7:$E$16,SMALL(IF(ISERROR(MATCH("~"&'SOE details'!$E$7:$E$16,$A$3:$A3&"",0)),ROW('SOE details'!$E$7:$E$16)-ROW('SOE details'!$E$7)+1),1)),""),"")
Ctrl+Shift+Enter > Copy สูตรลงด้านล่าง
- เซลล์ B4 คีย์สูตร
=IFERROR(INDEX('SOE details'!$C$7:$C$13,SMALL(IF(LOOKUP(2,1/(A$4:A4<>""),A$4:A4)='SOE details'!$E$7:$E$13,ROW('SOE details'!$A$7:$A$13)-ROW('SOE details'!$A$7)+1),COUNTIF(A4:INDEX(A$4:A4,MATCH(2,1/(LEN(A$4:A4)>0))),""))),"")
Ctrl+Shift+Enter > Copy สูตรลงด้านล่าง
- เซลล์ E4 คีย์สูตร
=IF(B4<>"",SUMIFS('SOE details'!$H$7:$H$13,'SOE details'!$E$7:$E$13,LOOKUP(2,1/(A$4:A4<>""),A$4:A4),'SOE details'!$C$7:$C$13,B4),"")
Enter > Copy สูตรลงด้านล่าง
- เซลล์ F4 คีย์สูตร
=IF(A4<>"",SUMIF('SOE details'!$E$7:$E$13,$A4,'SOE details'!$H$7:$H$13),"")
Enter > Copy สูตรลงด้านล่าง