Excel Forum

รบกวนช่วยหน่อยค่ะ

พอดีต้องสรุปรายงานการลาของพนักงาน แต่ดึงข้อมูลในระบบออกมาโชว์เป็นทุกวันยาวเลยค่ะไม่แยกวันสรุปให้ค่ะ
ต้องการทำสรุปวันที่ Start - End วันลาของพนักงานแต่ละคน โดยแยกตามประเภทการลา , และคำนวณยอดรวมวันลาออกมา ค่ะ
ขอสอบถามวิธีด้วยค่ะ ใช้สูตรไหนได้บ้าง ได้แนบไฟล์ตัวอย่างที่ต้องการมาด้วยค่ะ

ขอบคุณล่วงหน้านะคะ

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ G3 คีย์
   =B3&I3
   Enter > Copy ลงด้านล่าง
2. ที่ M3 คีย์
   =IFERROR(INDEX(LEFT($G$3:$G$46,5),SMALL(IF(FREQUENCY(MATCH($G$3:$G$46,$G$3:$G$46,0),ROW($G$3:$G$46)-ROW($G$3)+1),ROW($G$3:$G$46)-ROW($G$3)+1),ROWS(M$3:M3))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
3. ที่ T3 คีย์
   =IFERROR(INDEX($I$3:$I$46,SMALL(IF(FREQUENCY(MATCH($G$3:$G$46,$G$3:$G$46,0),ROW($G$3:$G$46)-ROW($G$3)+1),ROW($G$3:$G$46)-ROW($G$3)+1),ROWS(M$3:M3))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
4. ที่ R3 คีย์
   =IF(M3="","",MIN(IF($B$3:$B$46=M3,IF($I$3:$I$46=T3,$H$3:$H$46))))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
5. ที่ S3 คีย์
   =IF(M3="","",MAX(IF($B$3:$B$46=M3,IF($I$3:$I$46=T3,$H$3:$H$46))))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
6. ที่ U3 คีย์
   =IF(M3="","",COUNTIFS($B$3:$B$46,M3,$I$3:$I$46,T3))
   Enter > Copy ลงด้านล่าง
7. ที่ V3 คีย์
   =IF(M3="","",VLOOKUP(T3,$I$3:$K$46,2,0))
   Enter > Copy ลงด้านล่าง

!

Note: Ctrl+Shift+Enter เป็นการสร้างสูตร Array โดยสามารถเลือกดำเนินการตามข้อ 1 หรือ 2 ด้านล่าง กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน จากนั้นกดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วตามด้วย Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้ไม่สามารถคีย์เข้าไปเอง จะต้องมาด้วยการกดแป้น Ctrl+Shift+Enter เท่านั้น ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง

ทำได้แล้วค่ะ ขอบคุณมากๆ นะคะ
ช่วยประหยัดเวลาได้เยอะเลยค่ะ^^